# Stiffy Makane: Apocolocyntosis — 132 of 235

## One of the Bruces and Drunken Bastard

Release 1

- Home page
- Beginning
- Previous
- Next

Chapter Two - "The Surly Guard"

The surly guard is a man in Great Harbor. He is scenery. The initial appearance of the surly guard is "A sour-faced guard stands by the gate, the sun glinting off the tip of his spear." Understand "looking", "surly-looking", "angry-looking", and "angry" as the surly guard. The description of the surly guard is "The guard [if the surly guard is handled]watches warily from inside his hut[otherwise]stands at attention by the gate. He looks fairly angry[end if]."

Instead of touching, rubbing, sucking, fucking, blowing, buggering, kissing, or wanking off the surly guard:

if the surly guard is handled

begin;

say "The guard yawns, 'No thanks, I'm good,' and pushes you away with the butt of his spear.";

otherwise;

say "The guard jabs his spear menacingly at you. 'Not a chance, pal,' he snarls. 'I have to turn down something like ten people a day who try to pull that shit. You'd have much better luck if you brought me breakfast. And, no, before you even [italic type]ask[roman type], semen doesn't count.'";

end if;

stop the action.

Before asking the guard about something:

if the topic understood matches "gate/palace/tomb/Alexander/Cleopatra", replace the topic understood with "#fake1";

if the topic understood matches "Alexander's tomb", replace the topic understood with "#fake1";

if the topic understood matches "Cleopatra's palace", replace the topic understood with "#fake1".

Table of Surly Guard's Chatter

topic | reply | summary | turn stamp
"#fake1" | "'My job is to keep people like you out.' His tone shifts to an ingratiating whine. 'However, I was in a hurry this morning, and I skipped breakfast. If you were to bring me something to eat....I might just look the other way while you entered.'" | "he might let you pass if you brought him some food" | --
"hunger/hungry/breakfast/food/currants/currant/fruit/dry/dried" or "dried fruit" | "'I missed breakfast, and I wish I hadn't missed it now. Have you got anything? Dried fruit would be favorite.'" | "he missed breakfast, and would love some dried fruit to make up for it" | --
"anger/angry/surly/surliness/cranky/crankiness" | "'Actually it's not part of the job. I'm just hungry and cranky today.'" | "he's just cranky because he's hungry" | --
"himself/guard/guarding" | "'Hey, it's a job. One where I had to skip breakfast to make it here on time, which sucks.'" | "he skipped breakfast today and regrets it" | --
"Metropole/hotel" or "hotel Metropole" or "Metropole hotel" | "'Total fleabag.'" | "he thinks the Metropole is a fleabag" | --
"Pharos/lighthouse" | "'Do I look like the Tourism Bureau to you? Go climb it yourself if you want to see it!'" | "you should climb the Pharos if you want to know more about it" | --
"Syra" | "The guard grins, and makes an obscene thrusting gesture with his spear." | "he apparently knows Syra" | --

The conversation of the surly guard is the Table of Surly Guard's Chatter. The default reply of the surly guard is "A shrug is your only reply."

Instead of giving the bag of currants to the surly guard:

remove the bag of currants from play;

say "'Hey, thanks!' says the guard, his face cracking into a broad smile. He seats himself in the guardhouse, and crams the currants into his mouth. When done, he belches contentedly, and leans lazily back against the wall. He waves his spear vaguely at the gate. 'G'wan,' he says. 'I didn't see a thing.'";

really have the parser notice the surly guard;

now the surly guard is handled.

Instead of giving something to the surly guard:

say "The guard shakes his head dubiously. 'If that's a bribe, it isn't a very good one,' he says."

Instead of showing the bag of currants to the surly guard:

say "The guard stares at the bag of currants. 'That looks mighty good,' he points out, and glances meaningfully at the gate."

Instead of showing something to the surly guard:

say "The guard shrugs."

Rule for deciding the concealed possessions of the surly guard:

if the particular possession is the spear, no; otherwise yes.

The pointy spear is held by the guard. The description is "The spear is about eight feet long, with a wooden shaft topped with a sharp iron point." Understand "wood", "wooden", "eight", "feet", "eight-foot", "long", "shaft", "sharp", "iron", "head", "spearhead", and "point" as the pointy spear. Before taking the pointy spear:

if the pointy spear is held by the guard, instead say "The guard jabs the spear menacingly in your direction. 'Mine,' he says, in a voice that brooks no discussion."

Instead of touching, rubbing, sucking, fucking, blowing, kissing, or wanking off the pointy spear:

if the guard is handled

begin;

say "The guard rolls his eyes and shakes his head.";

otherwise;

say "The guard rolls his eyes. 'Look,' he says gruffly. 'Plenty of people have tried the old pretend-the-spear-is-a-penis-and-propose-unspeakable-delights-if-you-let-me-in trick. Doesn't work.'";

end if;

stop the action.

Instead of throwing something at the surly guard, try attacking the surly guard.

Instead of attacking the surly guard for the first time:

If the guard is handled, instead try kissing the pointy spear;

say "'Don't do that,' snaps the guard."

Instead of attacking the surly guard:

if the guard is handled, instead try kissing the pointy spear;

say "The guard snarls and runs you through with his spear.";

end the story saying "You have been impaled".