# Stiffy Makane: Apocolocyntosis — 137 of 235

## One of the Bruces and Drunken Bastard

Release 1

- Home page
- Beginning
- Previous
- Next

Part Two - "Hippo"

Test hippo with "z/z/z/z/z/z/z/z/z/z".

Riverhorse Rambling is a recurring scene. Riverhorse Rambling begins when the location is Hippopotamus Interior. Riverhorse Rambling ends when the location is not Hippopotamus Interior.

Hippopotamus Interior is a room. The description is "This is a rather tastefully-decorated little room, especially for something that's inside a hippopotamus. The wallpaper is delightful. Not much of a view, though."

Hippo_scenery is scenery in Hippopotamus Interior. The printed name is "wallpaper". The description is "Delightful!" Understand "delightful", "wallpaper", "tasteful", "decorated", "tastefully", "tastefully-decorated", "hippo", "hippopotamus", "little", "room", and "small" as the hippo_scenery. Instead of fucking the hippo_scenery, say "The wallpaper is delightful, but not quite [italic type]that[roman type] delightful."

Hippo_scenery2 is scenery. The printed name is "wallpaper". The description is "Delightful!" Understand "delightful", "interior", "wallpaper", "charming", "decorated", "charmingly", and "charmingly-decorated" as the hippo_scenery2.

Hippo_view is scenery in Hippopotamus Interior. The description is "The view is nonexistent, to be frank." Instead of doing anything other than examining with the hippo_view, try examining the hippo_view. Understand "view" as the hippo_view. The printed name is "view".

Every turn during Riverhorse Rambling:

if the Golden Banana is not held by the player

begin;

if the time since Riverhorse Rambling began is two minutes, say "A piercing whistle splits the air outside the hippopotamus, and then Eris shouts, 'Hey! Over here! Yummy yummy blue hippo! Pollywannahippo?' You hear a hoarse and titanic caw, and then the beating of huge wings.";

if the time since Riverhorse Rambling began is three minutes, say "The hippopotamus lurches as it is snatched into the air by the bird.";

otherwise;

if the time since Riverhorse Rambling began is one minute, say "You are thrown to the floor as the Mweru bird strikes the hippopotamus and, straining, pulls out of its dive.";

if the time since Riverhorse Rambling began is three minutes, say "There is a burst of static in your ears, and then Eris's voice: 'Nice going, Stiffy. Now get the Banana unwrapped, and then bring it to me on Olympus.'";

end if;

if the time since Riverhorse Rambling began is six minutes, say "The hippopotamus shakes violently as you encounter some turbulence.";

if the time since Riverhorse Rambling began is nine minutes, say "Your ears pop as the hippopotamus and you begin a steep descent.";

if the time since Riverhorse Rambling began is ten minutes

begin;

say "As the Mweru bird dips the hippopotamus into the ocean to salt it, you tumble out of the mouth, fortuitously tumbling directly onto the deck of the [italic type]Golden Ass[roman type]. Palinurus applauds.";

now the fake beard is not_warned_about;

move the player to Poop Deck;

end if.

The blue hippo is a male animal. He is in Hidden Valley. The initial appearance is "A shiny blue hippopotamus stands, looking dazed, in a small pond." The description is "This hippopotamus doesn't look very naturalistic. It's about the right size, but it's bright blue with black line drawings of lotus blossoms on its head and sides, and unnaturally shiny[39 as a footnote]." Understand "William", "shiny", "dazed", "hippopotamus", "faience", "lotus", "head", "side", "sides", "blossom", "blossoms", "black", "line", "blossoms", and "ceramic" as the blue hippo. Instead of entering the blue hippo, try entering the blue hippo's mouth. The default reply of the blue hippo is "The hippo stares at you uncomprehendingly from its little black eyes." The blue hippo is unspeakable. Rule for deciding the concealed possessions of the blue hippo: no.

The blue hippo's eyes are part of the blue hippo. The description is "The hippo's eyes are small and black." Understand "small", "little", "black", and "eye" as the blue hippo's eyes.

The blue hippo's mouth is part of the blue hippo. The blue hippo's mouth can be openable. The blue hippo's mouth is openable. The blue hippo's mouth can be open. The blue hippo's mouth is not open. The blue hippo's mouth can be closed. It is closed. The description is "[if the blue hippo's mouth is open]The hippo's jaws gape wide, revealing, oddly, a cozy room with delightful wallpaper inside[otherwise]The hippo has a friendly smile[end if]." Understand "mouth", "jaw", "jaws", "friendly", and "smile" as the blue hippo's mouth. The blue hippo's mouth can be enterable. Instead of entering the blue hippo's mouth:

if the blue hippo's mouth is closed, instead say "The hippopotamus's mouth is closed.";

say "You clamber into the hippopotamus's mouth and slither down into the room. The jaws snap shut behind you.";

now the blue hippo's mouth is closed;

move the player to Hippopotamus Interior.

The small pond is carried by the blue hippo. The description is "The hippo entirely fills the small pond." Instead of swimming around in the small pond, try taking the small pond.

Instead of opening the blue hippo's mouth:

if the blue hippo's mouth is open, instead say "The hippo's mouth is open already.";

say "That, I am afraid, is under the hippo's control."

Instead of closing the blue hippo's mouth:

if the blue hippo's mouth is closed, instead say "The hippo's mouth is already closed.";

say "That's the hippo's decision to make, not yours."