# Stiffy Makane: Apocolocyntosis — 107 of 235

## One of the Bruces and Drunken Bastard

Release 1

- Home page
- Beginning
- Previous
- Next

Chapter Two - "Rachel"

Rachel is a woman in the Judaean Brothel. The description of Rachel is "She's not a bad-looking woman. Shoulder-length light-brown hair, full lips, blue eyes, slightly-too-big nose, medium-sized firm tits, trim belly[if the mezuzah is worn by Rachel] with a small gold cylinder dangling from a chain around her waist[end if], shapely thighs, nice calves, dainty feet[if Rachel is boinked]. She lies on her back, fast asleep, emitting stentorian snores[end if]." The default reply of Rachel is "Rachel glares at you. 'I'm not here for chit-chat,' she snaps. [dirty request]". The conversation of Rachel is the Table of Rachel's Chatter. Instead of doing anything other than examining or searching or waking with Rachel when Rachel is boinked, say "You might wake her up, and then she'd start talking again." The initial appearance is "A naked woman [if rachel is boinked]snores loudly[otherwise]sits upright[end if] in the narrow bed." Understand "woman", "slut", "jewish", "Rabinowitz" as Rachel.

Instead of waking Rachel when Rachel is boinked, say "If you did that, she'd start talking again, and no one wants that."

Instead of smelling Rachel, say "She smells of sweat and sexual excitement."

Instead of kissing Rachel, say "'I'd rather kiss a pig[74 as a reference]!' she growls. [dirty request]"

Instead of touching, rubbing, sucking, blowing, or wanking off Rachel, try touching Rachel's tits.

Instead of fucking Rachel, consider the Rachel-fucking rule.

Instead of attacking Rachel, say "Tempting as it is, violence isn't the answer to this one."

Instead of searching Rachel, say "Rachel is completely nude[if the mezuzah is worn by Rachel] except for a gold pendant around her waist[end if]."

Rachel's hair is part of Rachel. The description is "Shoulder-length brownish hair frames her face." Understand "shoulder-length", "brownish", "brown", and "light-brown" as Rachel's hair. Instead of smelling Rachel's hair, try smelling Rachel.

Rachel's lips are part of Rachel. The description is "Rachel's lips are full and red. They're [if Rachel is boinked]blessedly only emitting snores right now[otherwise]also constantly in motion as she hurls imprecations[end if]." Understand "full", "red", "lip", and "mouth" as Rachel's lips. Instead of kissing or sucking Rachel's lips, try kissing Rachel. Instead of fucking Rachel's lips, try fucking Rachel's tits.

Rachel's eyes are part of Rachel. The description is "Rachel has ice-blue eyes, and perhaps a bit much mascara." Understand "eye", "blue", "ice-blue", and "mascara" as Rachel's eyes.

Rachel's nose is part of Rachel. The description is "Rachel's nose is a little large, and slightly hooked." Understand "large" and "hooked" as Rachel's nose. Instead of fucking, sucking, or blowing Rachel's nose, say "'Is that the kind of perversion they teach in Rome?' she asks, recoiling. [dirty request]".

Rachel's tits are part of Rachel. The description is "Her breasts are medium-sized, but firm and shapely." Understand "chest", "bosom", "medium", "medium-sized", "breast", "tit", "breasts", "hooter", "hooters", "boob", and "boobs" as Rachel's tits. Instead of fucking Rachel's tits:

if the stiffycock is not visible, instead say "You are not undressed for the occasion.";

say "'What's in it for me?' Rachel bats you away. [dirty request]".

Instead of touching, rubbing, sucking, or blowing Rachel's tits, say "Rachel moans perfunctorily before snarling, 'Get to the main event.'"

Instead of smelling Rachel's tits, try smelling Rachel.

Rachel's belly is a part of Rachel. The description is "Her waist and belly are trim." Understand "waist" and "trim" as Rachel's belly. Instead of touching, rubbing, sucking, or blowing Rachel's belly, try touching Rachel's tits. Instead of fucking Rachel's belly, try fucking Rachel's tits.

Rachel's pussy is a vagina. It is part of Rachel. The description is "Her pussy is covered in thick, dark brown, curly pubic hair[if the mezuzah is worn by Rachel], with a small golden cylinder dangling just to one side[end if]." Instead of touching, rubbing, sucking, kissing, wanking off, or blowing Rachel's pussy, try touching Rachel's tits. Instead of smelling Rachel's pussy, try smelling Rachel. Understand "thick", "dark", "brown", "curly", "pubic", "pubes", "public hair", "brisket", and "lox" as Rachel's pussy.

Rachel's asshole is an anus. It is part of Rachel. The description is "Her anus is tucked away underneath her. You can't reach it." Instead of doing anything other than examining with Rachel's asshole, try examining Rachel's asshole.

Rachel's legs are part of Rachel. The description is "Her legs are quite shapely." Understand "thigh", "thighs", "calf", "calves", "feet", "foot", "shapely", "nice", and "dainty" as Rachel's legs. Instead of kissing, touching, rubbing, sucking, or blowing Rachel's legs, try fucking Rachel's tits. Instead of smelling Rachel's legs, try smelling Rachel.

The mezuzah is an ornament. It is worn by Rachel. The description is "The pendant is a small golden cylinder, with pointed caps at both ends. You can see a bit of parchment inside with what looks like Hebrew writing on it, but you can't make it out. It has a little eye on one end through which a delicate golden chain-and-clasp arrangement goes." Instead of opening the mezuzah, say "It seems to be soldered shut." Understand "gold", "golden", "cylinder", "cap", "caps", "pointed", "parchment", "klaf", "clasp", "chain", "chain-and-clasp", "delicate", "little", "eye", "Hebrew", "writing", "bit", "pendant", "jewelry", and "prayer" as the mezuzah. Instead of rolling the mezuzah, say "It probably would roll well enough, but why bother?"

The ten-drachma coin is a thing. The description is "It's a lightweight Greek coin, made of silver." Understand "money", "silver", "ten", "drachma", "drachmas", "drachmae", and "lightweight" as the ten-drachma coin. Instead of rolling the ten-drachma coin, say "Someone would probably steal it while it was rolling around."

This is the Rachel-fucking rule:

if the stiffycock is not visible, instead say "You are not undressed for the occasion.";

say "Rachel's pussy proves both hot and wet as you thrust into her waiting womb. She screams in pleasure and rakes at your back with her nails, screaming increasingly-incoherent ethnic slurs the while. As you're hitting your stride, there is a small cough from the doorway.[paragraph break]";

say "You stop and turn in horror to see a young girl, perhaps eight years old, watching you. 'Aunt Rachel,' she snaps, disapprovingly, 'my mother sent me to go fetch you. It's your turn to cook.'[paragraph break]";

say "Rachel groans. 'Tell Anna to go fuck herself.'[paragraph break]";

say "The child sneers. 'Better than rutting like an animal with yet another dirty goy, you repulsive slut. What are you going to do when one of those filthy, uncut barbarians knocks you up?'[paragraph break]";

say "Rachel laughs. 'Just say an angel did it, Miriam. It works every time. Someday you'll see for yourself [37 as a footnote].'[paragraph break]";

say "Miriam glares at Rachel, and then at you. 'Don't let the Gentile steal your jewelry this time,' she grumbles, glaring at you. 'You think we're made of mezuzahs?'[paragraph break]";

say "Rachel's only reply is a rude gesture. The child turns and stomps away.[paragraph break]";

say "Rachel slaps your ass hard. 'Don't lose your hard-on now!' she yells. 'Finish the job, you[run paragraph on]";

choose a random row in the Table of Bigoted Slurs;

say " [slur entry]!'[paragraph break]";

say "A few more minutes of thrusting on your part, and bellowed ecstatic bigotry on her part, later, Rachel comes with a shriek, and immediately falls asleep and begins snoring. Nonplussed, you grit your teeth and dribble out a disappointing orgasm of your own.[paragraph break]";

now Rachel is boinked;

record "Rachel" as achieved.

This is the fancy can't take people's possessions rule:

if the noun is the mezuzah and Rachel is boinked, continue the action;

if the noun is the grubby tunic, continue the action;

if the noun is the simple white tunic, continue the action;

if the noun is the golden sandals, continue the action;

abide by the can't take people's possessions rule.

The fancy can't take people's possessions rule is listed instead of the can't take people's possessions rule in the check taking rulebook.

Table of Rachel's Chatter

topic | reply | summary | turn stamp
"Syra" | "'Oooooh, she was a tasty shiksa. And that schnozz acted like an anchor, even.'" | "she really enjoyed both Syra's attentions and her nose" | a number
"mezuzah/pendant/cylinder/jewelry" | "'You goyim are so ignorant. That's a mezuzah. It confers blessings on those entering.'" | "the pendant is a mezuzah, which confers blessings" | --
"Rachel/herself" | "'Sometimes I need some meat that's not quite kosher.'" | "she has a thing for fucking Gentiles" | --

To say dirty request:

choose a random row in the Table of Bigoted Slurs;

say "'[pork entry],' [run paragraph on] ";

choose a random row in the Table of Bigoted Slurs;

say "[shout entry] Rachel, 'you [run paragraph on]";

choose a random row in the Table of Bigoted Slurs;

say "[slur entry]!'".

Table of Bigoted Slurs

pork | shout | slur
"Thrust your pork salami between my lox slices" | "shrieks" | "dirty uncircumcised pig"
"Bludgeon me with your uncircumcised bratwurst" | "shouts" | "filthy goy"
"Split me open with your giant greasy kielbasa" | "hollers" | "uncut colonialist oppressor"
"Ritually defile me with that juicy loin of pork" | "bellows" | "garlic-reeking wop"
"Batter apart my Ark" | "screams" | "no-covenant-having motherfucker"
"Stretch my brisket" | "yells" | "domus-eunting Romanis"
"Unload your goyishe sperm into a Chosen womb" | "ejaculates" | "vile polytheistic cocksucker"
"Mix meat and milk in me" | "hoots" | "beardless Hellenized pansy-boy"