# Stiffy Makane: Apocolocyntosis — 207 of 235

## One of the Bruces and Drunken Bastard

Release 1

- Home page
- Beginning
- Previous
- Next

Part Three - "Cellars"

Pantry is a room. It is east of Kitchen. The description is "Dim light trickles from the stairs and a few lightwells, barely illuminating this room, which is cluttered with barrels and boxes of supplies. Stairs, leading up to the kitchen, rise to the west. A shadowy nook is to the south behind a parapet of barrels, and the cellar continues north. A stout door [if stout door is open]stands open[otherwise]bars the way[end if] to the east." Instead of going up in the Pantry, try going west. Instead of going down in the Pantry, try going east.

Some lightwells are scenery in the pantry. They are ambiguously plural. Understand "lightwell", "well", "wells", "bar", "bars", "barred", "grate", and "light" as lightwells. The description is "A little light enters through barred grates in the floors of the rooms above."

Some foodstuffs are a backdrop in the pantry. They are in the Shadowy Nook. They are ambiguously plural. The description is "Boxes and barrels of foodstuffs: spices, flour, amphorae of olive oil, pickles, jam, all sorts of long-keeping comestibles." Understand "box", "barrel", "spice", "spices", "cinnamon", "supply", "supplies", "food", "foodstuff", "stuff", "boxes", "barrels", "parapet", "amphora", "amphorae", "pickle", "pickles", "olive", "olives", "comestible", "comestibles", "long-keeping", "preserved", "preserves", "jam", "jelly", "jellies", "jellied", "crate", and "crates" as foodstuffs. Instead of taking foodstuffs, say "Perhaps you ought to see what the chef makes out of them instead." Some foodstuffs can be edible. They are edible. Instead of eating foodstuffs, say "It would be the height of rudeness to nosh away in your host's pantry." Instead of smelling foodstuffs, say "Most of the food is dried or pickled, so it doesn't smell like much. You're pretty sure you found the cinnamon, though." Instead of touching or searching foodstuffs, say "You probably shouldn't paw through Vergil's food storage."

The stout door is a door. It is east of Pantry and west of Wine Cellar. It is closed and locked. It is scenery. The description is "It's a stout door of some dark, heavy wood[emdash]walnut, perhaps[emdash]with black iron bands and a small keyhole." Understand "oak", "barred", "keyhole", "thick", "heavy", "wood", "wooden", "small", "brown", "black", "dark", "walnut", "band", and "bands" as the stout door. The matching key of the stout door is the cellar key.

After closing the stout door:

now the Wine Cellar is dark;

now the Dim Alcove is dark;

continue the action.

After deciding the scope of the player when the location is the Wine Cellar:

place the stout door in scope.

After opening the stout door:

now the Wine Cellar is lit;

now the Dim Alcove is lit;

if the location is the Wine Cellar

begin;

say "As the door opens, a little light trickles through.";

now the stout door is open;

stop the action;

end if;

continue the action.

The cellar key is a thing. It is in Limbo. The description is "This is a small bronze skeleton key, with 'MARO' engraved on the shaft." Understand "small", "bronze", "skeleton", "shaft", and "maro" as the cellar key. The indefinite article is "the".

Shadowy Nook is a room. It is south of Pantry. The description is "This nook is nearly lightless, a small semicircular bit of floor half-hidden behind some barrels."

The filthy mattress is a supporter in Shadowy Nook. Understand "dirty", "dingy", "lumpy", "futon", "stain", "stained", "stinky", "smelly", "reeking", and "nasty" as the filthy mattress. The description is "It is just a dingy, dirty, lumpy mattress, streaked with filth and badly stained." Check taking the filthy mattress: instead say "It's too bulky to easily move." Instead of smelling the mattress, say "It reeks of sex and less-pleasant odors." Instead of looking under the filthy mattress, say "It appears to be stuck to the floor. Ick." The filthy mattress can be enterable. It is enterable. Before entering the filthy mattress when the player is not on the filthy mattress, say "It is with grave misgivings that you lower yourself onto the filthy mattress[if the scullery maid is on the filthy mattress]. [The scullery maid] obligingly scoots over to make room for you[end if]." Does the player mean doing something with the filthy mattress: it is unlikely.

Rule for writing a paragraph about the filthy mattress:

if the scullery maid is on the filthy mattress

begin;

say "A tousled and dirty woman, wearing [if a garment is worn by the scullery maid][a random garment worn by the scullery maid][otherwise]not a stitch[end if], sprawls drunkenly on a filthy mattress.";

now the scullery maid is mentioned;

otherwise;

say "A filthy mattress lies here on the floor.";

now the filthy mattress is mentioned;

end if.

Root Cellar is a room. It is north of Pantry. The description is "The ceiling lowers here, and you have to stoop. This is a rougly-dug cave with a brick floor. Rough wooden bins hold mounds of tubers and roots. The cellar widens out to the south."

Some wooden bins are scenery in the Root Cellar. They are ambiguously plural. Understand "bin", "wood", "rough", "dried", "tuber", "tubers", "roots", "heap", "heaps", "mound", "mounds", "pile", "piles", "root", "dry" as the wooden bins. Instead of taking the wooden bins, say "Perhaps you ought to see what the chef makes out of them instead." The description is "Winter kept us warm, covering / Earth in forgetful snow, feeding / A little life with dried tubers[81 as a reference]."

Some potatos are scenery in the root cellar. They are ambiguously plural. Understand "potato", "potatos", and "potatoes" as the potatos. The printed name is "potatoes". ["Potatoes" is actually more correct for the plural, and sets up the singular for the following gag.] The description is "The potato is a New World food, and therefore not present in this root cellar." Instead of doing anything other than examining with the potatos, try examining the potatos. [ We also steal warned_about for whether or not we have ever heard the duck speak. ]

The potatoe is scenery in the Root Cellar. The description is "Nice spelling, Mister Quayle[48 as a footnote]." Instead of doing anything other than examining with the potatoe, try examining the potatoe. [ We use the potatoe's warned_about for the flag that gives us the more explicit moonmilk prayer hint. ]

Check searching the wooden bins:

if the wooden bins are not warned_about

begin;

now the wooden bins are warned_about;

say "With a clatter, an incongruous withered low-brass instrument topples to the floor.";

move the dried tuba to the location;

stop the action;

end if.

The dried tuba is a thing. The description is "This is a large, dessicated low-brass instrument, dehydrated, withered, and spotted. You can't for the life of you imagine what it's doing here." Does the player mean doing something with the dried tuba: it is very unlikely. Understand "incongruous", "large", "big", "withered", "dessicated", "brass", "low-brass", "dry", "low", "spotted", "instrument", and "musical" as the dried tuba. The printed name is "dessicated low-brass instrument".

Check taking the dried tuba:

say "Oh. My mistake. For 'dried tuba,' read 'dried tuber' throughout[82 as a reference].";

remove the dried tuba from play;

stop the action.

The rough_cellar_brick_floor is a floor_scenery in the Root Cellar. It is in the Pantry, the Wine Cellar, and the Shadowy Nook. The description is "Rough red bricks, set into the earth, form a serviceable if rustic floor." The printed name is "brick floor". Understand "brick", "floor", "rough", "red", "cellar", "bricks", and "earth" as the rough_cellar_brick_floor. Does the player mean doing something with the rough_cellar_brick_floor: it is unlikely. Instead of searching the rough_cellar_brick_floor, say "Although it it possible that some of the bricks are loose, and also possible that something interesting might be hidden under one or more of them, after a few moments of scraping your fingers trying to pull up the rather well-mortared floor, you desist."

The root_cellar_ceiling is a sky_scenery in the Root Cellar. The description is "The packed-earth ceiling is uncomfortably close." Instead of touching the root_cellar_ceiling, say "Cold and damp." Instead of smelling the root_cellar_ceiling, say "It smells of wet earth." Instead of doing anything other than examining, touching, or smelling with the root_cellar_ceiling, say "That proves unhelpful." Understand "ceiling", "wet", "earth", "damp", "dirt", "packed", and "packed-earth" as the root_cellar_ceiling. The printed name is "ceiling".