# Stiffy Makane: Apocolocyntosis — 155 of 235

## One of the Bruces and Drunken Bastard

Release 1

- Home page
- Beginning
- Previous
- Next

Part Two - "Keep It Together"

Some woad is an ornament. The description is "You are painted from head to toe in a blue dye, as befits a warrior about to go into battle. You're told this dye is also mildly hallucinogenic, which might explain some other things." Understand "dye", "indigo", "glastum", "vitrum", "war", and "paint" as woad. Check taking off the woad: instead say "You're going to have to wait for the top layer of your skin to wear off. It's a permanent dye."

Check dropping the Golden Banana of Discord when the location is the Druidic Grove: instead say "You're really not planning on sticking around here, so therefore you continue to clutch the Banana." Check throwing the Golden Banana at something when the location is the Druidic Grove: instead try dropping the Golden Banana.

Check taking the simple white robe: instead say "That seems to belong to the Druidic priestess."

Druidic Grove is a room in Scotland. "This is a roughly-circular clearing in a dark forest, a crumbling stone altar before you. Enormous and ancient oaks stretch to the star-studded sky. Off to the west, you can see the occasional flicker of the Vikings[apostrophe] campfire through the trees."

Druidic_sky is a sky_scenery in Druidic Grove. The description is "The sky above is clear, dotted with innumerable stars peeking through the canopy of oak leaves. A crescent moon provides silvery illumination. It's still a couple hours before dawn." Understand "sky", "clear", "star", "stars", "dark", "night", "silver", "silvery", "crescent", "moon", "moonlight", and "innumerable" as druidic_sky.

A crumbling stone altar is a supporter in Druidic Grove. It is scenery. The description is "Old, old, crumbling stone, carved with Celtic knots, in whose crevices moss has grown[if the simple white robe is not worn by the Druidic priestess]. Atop the altar lies the Druidic priestess[end if]." Understand "old", "celtic", "knot", "knots", "knotwork", "crevice", "crevices", and "moss" as the crumbling stone altar. The crumbling stone altar can be enterable. It is enterable.

Some ancient oaks are scenery in Druidic Grove. The description is "Ancient oaks reach for the sky above; it must be fifty feet to even the first branch of these mighty trees." Understand "fifty", "grove", "feet", "branch", "first", "leaf", "tree", "trees", "leaves", "canopy", "reach", and "reaching" as the ancient oaks. Instead of doing anything other than examining or climbing with the ancient oaks, say "The oaks were here long before you, and will be here long after you're gone. There's no point in doing anything to them." Instead of climbing the ancient oaks, say "It's at least fifty feet before there's anything like a handhold." Instead of going up in Druidic Grove, try climbing the ancient oaks.

A grove_trip is a kind of thing. A grove_trip is always scenery. The printed name of a grove_trip is "hallucination". A grove_trip is privately-named. The description of a grove_trip is "You can no longer perceive any such thing." Instead of doing anything other than examining with a grove_trip, try examining the noun. Does the player mean doing something with a grove_trip: it is very unlikely.

Bat_trip is a grove_trip. Understand "giant", "bat", "bat-winged", "winged", "creature", "father", "father's", "cocky", "cocky's", "head", "razor", "talon", "talons", "curse", "curses", "silver", "silvery", "sparkle", and "sparkles" as the bat_trip.

Shroom_trip is a grove_trip. Understand "friend", "friendly", "little", "mushroom", "mushroom-folk", "folk", "wooden", "hunting", "spear", "spears", "harmony", "intricate", "chant", and "chanting" as the shroom_trip.

Pirate_trip is a grove_trip. Understand "pirate", "captain", "black", "blackened", "rot", "rotten", "tooth", "teeth", "toad", "toads", "wasp", "wasps", and "vomit" as the pirate_trip.

Tree_trip is a grove_trip. Understand "rainbow", "color", "colors", and "vibrant" as the tree_trip.

Eversion_trip is a grove_trip. Understand "inside-out" as the eversion_trip.

Bear_trip is a grove_trip. Understand "bear", "bears", "papa", "mama", "baby", "naked", "blonde", and "goldilocks" as the bear_trip.

Glub_trip is a grove_trip. Understand "great", "god", "glub", "polka", "bloink", "rabbit", and "stew" as the glub_trip.

The scenery_campfire is scenery in Druidic Grove. The printed name is "campfire". The description is "A flickering campfire is dimly visible through the trees to the west." Understand "campfire", "fire", "flicker", "flickering", "viking", "vikings", and "camp" as the scenery_campfire. Instead of doing anything other than examining with the scenery_campfire, say "The campfire is several hundred yards to your west."

Before going west in Druidic Grove:

if the stiffycolor of the stiffycock is not blue

begin;

say "The priestess stops you with a firm palm on your chest. 'No,' she says. 'Look at yourself. It's disgraceful. Are you blind? Can't you tell that [stiffycolor of the stiffycock] clashes with your blue woad?'";

stop the action;

otherwise;

say "The priestess smiles [if the Druidic priestess is boinked]languidly at you from the altar [end if]as you depart the grove and waves her hand. 'Have fun storming the castle[90 as a reference]!'";

remove the woad from play;

say "[paragraph break][bracket]There follows another lacuna in the text.[close bracket][paragraph break]";

consider the return to the game rule;

stop the action;

end if.