# Stiffy Makane: Apocolocyntosis — 160 of 235

## One of the Bruces and Drunken Bastard

Release 1

- Home page
- Beginning
- Previous
- Next

Part One - "The Great Table"

The Great Table is a supporter in the Game Room. The description is "The Great Table's surface is a somewhat-schematic map of the world. It is a painstakingly-constructed relief map, with little mountains, rivers, and seas (full, indeed, of water). Cities are represented slightly larger-than-life, with the architectural features exaggerated; for instance, the Pharos in Alexandria is much larger than it would be were it proportional. An annex, of sorts, slightly lower than the main surface of the table and off to the side a bit, represents Hades. Figurines, each representing a hero or monster, dot the map." Understand "painstaking", "painstakingly", "painstakingly-constructed", "constructed", "little", "map", "world", "game", "relief", "surface", "mountain", "mountains", "rivers", "river", "sea", "water", "ocean", "seas", "oceans", "basin", "city", "cities", "living", "game", and "board" as the Great Table. Instead of pushing or pulling the Great Table, say "If you try shifting the table, you're going to knock over a bunch of figurines, and that will make you extremely unpopular." Check taking the Great Table: instead try pushing the Great Table. The Great Table can be drinkable. It is drinkable. Instead of sucking, drinking or tasting the Great table, say "Realistically, the seas on the table are very salty. Ick."

Rule for supplying a missing noun when drinking and the location is the atrium: now the second noun is the Great Table.

Instead of looking under the Great Table:

if the player is Divine Eris

begin;

now the last place checked is 2;

say "You crouch down and glare under the table. Nothing is down there.";

now the Great Table is handled;

end if.

Before inserting something into the Great Table:

instead try putting the noun on the Great Table.

Rule for writing a paragraph about the Great Table:

say "The Great Table nearly fills the room. Its surface is dotted with dozens of lead figurines[run paragraph on]";

if the Stiffy Makane figurine is on the Great Table

begin;

if the player is Divine Eris

begin;

say ", including, notably, Stiffy Makane, face-down in a lake in the north of Scotland[run paragraph on]";

now the Stiffy Makane figurine is mentioned;

otherwise;

say ", including, notably, yourself, atop Olympus, the Golden Banana clenched in your fist.";

end if;

end if;

say ". A collection of dice in many shapes and sizes are scattered across its surface."

This is the fancy examine supporters rule:

if the noun is the Great Table, continue the action;

if the noun is Model_olympus, continue the action;

if the noun is Model_hades, continue the action;

abide by the examine supporters rule.

The fancy examine supporters rule is listed instead of the examine supporters rule in the carry out examining rulebook.

Instead of putting a figurine on the Great Table:

say "You will have to be more specific: which part of the table do you want to put it onto?";

stop the action.

A map_locale is a kind of container. It is always open. It is never openable.

Before putting something (called the thingy) on a map_locale (called the map_city), instead try inserting thingy into map_city.

Before inserting something that is not a figurine into a map_locale:

say "Unless it's a figurine, it doesn't belong in [second noun] on the game board.";

stop the action.

Model_rome is a map_locale. It is part of the Great Table. The printed name is "Rome". The description is "Here's Rome, sure enough[if the player is Divine Eris]. And there, on the forum steps, lies Caesar. It looks like his lifestyle finally caught up with him[end if]." Understand "Rome", "Forum", "step", "steps", "stair", and "stairs" as Model_rome.

Model_carthage is a map_locale. It is part of the Great Table. The printed name is "Carthage". The description is "Carthage includes a large cemetery, a fortune-teller's tent, and a doctor's office." Understand "Carthage", "cemetery", "tent", "fortune-teller's", "necropolis", "office", and "doctor's" as Model_carthage.

Model_ostia is a map_locale. It is part of the Great Table. The printed name is "Ostia". The description is "There's a little model Ostia, exactly where you would expect it. Nothing interesting is happening there." Understand "Ostia" as Model_ostia.

Model_alexandria is a map_locale. It is part of the Great Table. The printed name is "Alexandria". The description is "The model of Alexandria is dominated by the Pharos." Understand "Alexandria" and "Pharos" as Model_alexandria.

Model_scotland is a map_locale. It is part of the Great Table. The printed name is "Scotland". The description is "Far to the north, Scotland is a soggy and cold land of barbarians and haggis[if the Stiffy Makane figurine is on the Great Table and the player is Divine Eris]. Also the drowned form of Stiffy Makane in his watery grave[end if]." Understand "scotland", "grave", "watery", "haggis", "barbarians", "gostakia", "loch", "ness", and "lake" as Model_scotland. Model_scotland can be drinkable. It is drinkable. Instead of sucking, tasting or drinking Model_scotland, say "The water tastes nastily of peat moss, and there's no way you could force all of it down[if the player is Divine Eris]. Anyway, Stiffy has already drowned. Draining the lake won't help now[end if]."

Model_mongolia is a map_locale. It is part of the Great Table. The printed name is "Mongolia". The description is "Mongolia is a windswept steppe." Understand "Mongolia", "steppe", and "windswept" as Model_mongolia.

Model_styx is a map_locale. It is part of the Great Table. The printed name is "River Styx". The description is "Styx separates Hades from the living world." Understand "styx" and "river" as Model_styx. Model_styx can be drinkable. It is drinkable. Instead of sucking, tasting or drinking Model_styx, say "You touch the tip of your tongue to the Styx. It is overpoweringly bitter. Yuck."

Model_hades is a map_locale. It is part of the Great Table. The printed name is "Hades". Understand "hades", "annex", "hell", "underworld", "land of the dead", and "lower" as Model_hades. The description is "Hades is represented by its own portion of the board, isolated from the rest by the River Styx, and set at a slightly lower level."

Model_olympus is a map_locale. It is part of the Great Table. The printed name is "Olympus". Understand "Thessalonica", "Thessaly", "Litochoro", "Prionia", "Olympus", "Mount", and "Olympia" as Model_olympus. The description is "Olympus is visible, but there are no miniatures of the residents. The temptation for the gods to mess with one another through their figurines was just too great, so a rule was implemented: manifesting deities are placed in the spot of their mortal manifestation, but are out of play when they're at home on Olympus. This rule does not apply to the occasional mortal visiting Olympus[if no figurine is in Model_Olympus], of which there currently are none[otherwise], represented by: [list of all figurines in Model_Olympus][end if]."

A figurine is a kind of thing. A figurine has some text called a name. The name of a figurine is usually "some random peasant". A figurine can be male or female. A figurine is usually male. The description is "This is a finely-detailed lead figurine of [name]." A figurine has a truth state called mine. The mine of a figurine is false. A figurine can be edible. It is not edible. A figurine can be drinkable. It is not drinkable.

Check taking a figurine:

if the mine of the noun is false

begin;

say "[The noun] belongs to someone else's game. [if the player is Stiffy Makane]Even mortals know that i[otherwise]I[end if]t's considered very poor form to interfere in other games uninvited; it's the sort of thing that myths and legends end up being written about, and everyone involved gets pissy for decades.";

stop the action;

end if.

Understand "miniature" and "mini" as a figurine.

A scenery_figurine is a kind of figurine. It is scenery.

This is the fancy can't take scenery rule:

if the noun is a scenery_figurine, continue the action;

abide by the can't take scenery rule.

The fancy can't take scenery rule is listed instead of the can't take scenery rule in the check taking rulebook.