# Stiffy Makane: Apocolocyntosis — 149 of 235

## One of the Bruces and Drunken Bastard

Release 1

- Home page
- Beginning
- Previous
- Next

Part Two - "Galley Slave"

Galley is a room. The description is "About eighty men row the ship: twenty or so rows of benches, two men to an oar on each side. You are chained to a starboard oar on the center aisle, about two-thirds of the way to the front of the boat, next to a tough-looking Gaul."

Before going in the Galley:

say "You can't: your hands are manacled, and the manacles are chained to your oar, and your ankles are shackled to the bench.";

consider the you_fucked_up_rowing rule.

Before doing anything other than going, examining, pushing, pulling, asking, smelling, or taking during Durance Vile:

if the time since Durance Vile began is at least one minute and the location is the Galley

begin;

say "Alas, your options are rather limited right now, given your restricted range of movement and your somewhat strict supervision. Speaking of which...";

consider the you_fucked_up_rowing rule;

end if;

stop the action.

The rowing bench is a supporter in the Galley. It is scenery. The description is "You are chained to a rough wooden bench. On the same bench, to your right, is your benchmate, a tough-looking Gaul." Understand "rough", "wood", and "wooden" as the rowing bench.

The oar is a thing in the Galley. The description is "It's a heavy wooden oar, rubbed smooth by much hard work." Understand "heavy", "wood", "wooden", and "smooth" as the oar. Check taking the oar:

say "You pull the oar towards you.";

instead try pulling the oar.

The vile fart is a thing. It is scenery. The description is "Apparently, onions are a major component of the shipboard diet." Instead of taking the vile fart, say "Even if you could, you really, really would not want to."

Before taking something in the Galley:

if the noun is not the oar and the noun is not the vile fart

begin;

say "The fact that you are chained to the oar makes that a bit difficult. However, the attempt does earn you the notice of the coxswain.";

consider the you_fucked_up_rowing rule;

end if.

Before smelling something in the Galley:

if the vile fart is not in the location

begin;

say "You can't smell anything other than sweaty men, which is not as pleasant as you might imagine.";

otherwise;

say "There's really no way [italic type]not[roman type] to smell that fart.";

end if;

consider the you_fucked_up_rowing rule;

stop the action.

After doing anything other than pushing or pulling during Durance Vile, consider the you_fucked_up_rowing rule.

Some prisoners are men in the Galley. They are scenery. The description is "Your fellow slaves toil, as you do, under the lash of the coxswain." They are unspeakable. The default reply of the prisoners is "Between the exertion of the rowing and the omnipresent whip, this is really no time for conversation." Understand "men", "slave", "galley", "fellow", and "slaves" as the prisoners.

The coxswain is a man in the Galley. He is scenery. The description is "The coxswain is a fat man wearing brown pants. He carries a brutal whip, with which he is constantly tormenting the galley slaves." Understand "fat", "man", "brown", "pants" as the coxswain. He is unspeakable. The default reply of the coxswain is "The coxswain makes no reply, but cracks his whip; it would have taken out your eye if you hadn't flinched."

The brutal leather whip is a thing carried by the coxswain. The description is "It's a leather bulllwhip, stained with years of blood." Understand "bullwhip", "stained", "blood", and "bloody" as the brutal leather whip.

Some manacles are ornaments. They are ambiguously plural. The description is "Heavy iron manacles connect your wrists to the oar." Understand "wrist", "wrists", "heavy" and "iron" as the manacles.

Some shackles are ornaments. They are ambiguously plural. The description is "Pitted iron shackles fasten your ankles to the rowing bench." Understand "pitted", "iron", "ankle", and "ankles" as the shackles.

A tough-looking Gaul is a man in the Galley. He is scenery. The description is "A weather-beaten Gaul, with blonde hair, a droopy moustache, and piercing, though bloodshot, blue eyes, works the oar beside you." Understand "right", "yellow", "blonde", "tough", "looking", "droopy", "benchmate", "piercing", "blue", "bloodshot", "eye", and "eyes" as the tough-looking Gaul. He is unspeakable. The default reply of the tough-looking Gaul is "A Gallic shrug is your only reply."

Some Gaul's teeth are things. They are ambiguously plural. They are scenery. The description is "The Gaul's teeth are cracked and yellowed." Understand "cracked", "yellowed", "yellow", and "tooth" as the Gaul's teeth.

A once-pretty Egyptian boy is a man. He is scenery. The description is "A once lithe and lissom walnut-skinned boy of perhaps fifteen, he now bears a haunted and defeated look." Understand "lithe", "lissom", "walnut", "walnut-skinned", "haunted", "once", "pretty", and "defeated" as the once-pretty Egyptian boy. He is unspeakable. The default reply of the once-pretty Egyptian boy is "He's too far away to talk to."

A handsome Scythian is a man. He is scenery. The description is "A strikingly handsome Scythian is gazing at you with undisguised lust." Understand "striking", and "strikingly" as the handsome Scythian. He is unspeakable. The default reply of the handsome Scythian is "Before you can address the Scythian, the coxswain shouts, 'No fraternization!' and slashes you with his whip."

An outlandishly-tall black man is a man. He is scenery. The description is "The back of the enormously-tall black man is a tapestry of pink keloid scars." Understand "pink", "keloid", "scar", "scars", "outlandish", "outlandishly", "outlandish", "tall", "enormous", "enormously", "African", and "Negro" as the outlandishly-tall black man. He is unspeakable. The default reply of the outlandishly-tall black man is "He's too far away to talk to."

A Parthian is a man. He is scenery. The description is "You can't even see the Parthian, but the shriek was unmistakable." He is unspeakable. The default reply of the Parthian is "You can't even see him, let alone talk to him."

Galley_scenery is scenery in the galley. The printed name is "ship's hull". The description is "The ship's hull is made of weathered and somewhat leaky wooden planks." Understand "plank", "planks", "hull", "galley", "weathered", "wood", "wooden", "leaky", "boat", and "ship" as galley_scenery.

This is the you_fucked_up_rowing rule:

if the location is the galley

begin; [ the scene machinery is a little broken ]

increase the rowing_fuckup_count by 1;

if the rowing_fuckup_count is 1

begin;

say "You gasp as a whip slices across your shoulders. 'You there, boy!' bellows the coxswain. 'There's just one very simple rule here. When I say [italic type]STROKE[roman type], you pull that oar, and when you're not pulling it, you're pushing it!'";

end if;

if the rowing_fuckup_count is 2

begin;

say "The whip strikes harder this time. 'On Carthaginian ships,' explains the coxswain, 'if you won't row, they tie your left nut to the oar, and your right one to the ship's bell. I don't know why. They won't let me do that here. But I can feed you to the sharks if you don't shape up!'";

end if;

if the rowing_fuckup_count is 3

begin;

say "This time, the whip tears chunks from your back. 'Final warning, douchebag!' shrieks the coxswain.";

end if;

if the rowing_fuckup_count is greater than 3

begin;

say "The ship briefly pauses as you are unchained from the oar and dumped overboard.";

end the story saying "You have been eaten by a shark";

end if;

stop the action;

end if.

After pulling during Durance Vile:

if the noun is not the oar or the stroke clock is not 1

begin;

consider the you_fucked_up_rowing rule;

end if.

After pushing during Durance Vile:

if the noun is not the oar or the stroke clock is not 0

begin;

consider the you_fucked_up_rowing rule;

end if.

Carry out pulling the oar:

if the location is the Galley

begin;

if the stroke clock is 0

begin;

say "You haul on the oar as your fellow benchmate tries to push it away. This earns you a muttered Gallic curse.";

otherwise;

say "You pull the oar towards your chest, in synchrony with your benchmates. [run paragraph on]";

increase the good_stroke_count by 1;

if the good_stroke_count is 1, say "The muscles of your fellow galley slaves ripple as they, too, strain at the oars.";

if the good_stroke_count is 2

begin;

say "A once-pretty Egyptian boy two benches ahead of you and on the other side of the aisle lets the oar slip from his sweat-slickened grasp, and receives a shout and a flick of the whip from the coxswain.";

move the once-pretty Egyptian boy to the galley;

end if;

if the good_stroke_count is 3, say "Your shoulders scream in agony.";

if the good_stroke_count is 4

begin;

move the handsome Scythian to the galley;

say "A handsome Scythian is giving you the eye from across the aisle.";

end if;

if the good_stroke_count is 5

begin;

say "Your mind and body become numb beneath the soul-crushing and backbreaking work. Many weeks later, you, your toga, and the Golden Banana are all sold to a longboat full of vicious barbarians. They don't chain you up, but they do put you to work rowing.";

remove the shackles from play;

remove the rowing bench from play;

move the oar to the Viking Longboat;

remove the manacles from play;

move the player to the sea chest;

really have the parser notice the oar;

now the stroke clock is 0;

end if;

end if;

end if;

if the location is the Viking Longboat

begin;

if the good_stroke_count is less than 5

begin;

if the stroke clock is 0

begin;

say "You haul on the oar as Sven Spamson tries to push it away. He shakes his head.";

otherwise;

say "You pull the oar towards your chest, in synchrony with your seatmates. [run paragraph on]";

increase the good_stroke_count by 1;

if the good_stroke_count is 1, say "Sven Spamson, next to you, nods approvingly as the two of you smoothly pull the oar.";

if the good_stroke_count is 2

begin;

remove the Pillars of Hercules from play;

move the Gallic Coast to the location;

say "The coastline of Gaul slides past you, dotted with sheep.";

end if;

if the good_stroke_count is 3

begin;

consider the Scottish Playing rule;

end if;

end if;

otherwise;

stop the action;

end if;

end if.

Carry out pushing the oar:

if the location is the Galley

begin;

if the stroke clock is 1

begin;

say "You shove the oar away just as your benchmate hauls back on it. This does not make you popular with him, nor with the other rowers.";

otherwise;

say "With a grunt, all the rowers shove their oars forwards.[run paragraph on] ";

if the good_stroke_count is 0

begin;

say "You watch sweat trickle down the heavily-muscled and badly-scarred back of an outlandishly tall black man rowing ahead of you.";

move the outlandishly-tall black man to the galley;

end if;

if the good_stroke_count is 1

begin;

say "Your benchmate to the right snarls as he strains at the oar, revealing cracked and yellowed teeth.";

move the Gaul's teeth to the galley;

now the Gaul's teeth are a part of the tough-looking Gaul;

end if;

if the good_stroke_count is 2, say "The planks of the ship's hull creak alarmingly as it slaps through the waves.";

if the good_stroke_count is 3

begin;

say "A vile fart fills the galley, causing your eyes to water. An aggrieved groan rises from an oarsman. Must have been a wet one.";

move the vile fart to the galley;

end if;

if the good_stroke_count is 4

begin;

say "A Parthian shrieks as his manacles crush his fingers against the oar.";

move the Parthian to the galley;

end if;

end if;

end if;

if the location is the Viking Longboat

begin;

if the stroke clock is 1

begin;

say "You shove the oar away just as Sven Spamson pulls back on it. He rolls his eyes.";

otherwise;

say "With a grunt, all the rowers shove their oars forwards.[run paragraph on] ";

if the good_stroke_count is 0

begin;

say "Sven Spamson grins as the two of you heave away in unison.";

end if;

if the good_stroke_count is 1

begin;

say "The Viking ship glides between the Pillars of Hercules.";

move the Pillars of Hercules to the location;

end if;

if the good_stroke_count is 2

begin;

remove the Gallic Coast from play;

move the Caledonian Coast to the location;

move the scottish_sky_scenery to the Viking_region;

say "The ship skates through a bitterly cold rain across a sea the color of lead as Caledonia passes by on the port side.";

end if;

end if;

end if.