# Stiffy Makane: Apocolocyntosis — 165 of 235

## One of the Bruces and Drunken Bastard

Release 1

- Home page
- Beginning
- Previous
- Next

Volume Sixteen - "Stiffy Harrows Hell"

Book One - "Preliminaries"

Stiffy Harrows Hell is a scene. Stiffy Harrows Hell begins when Cheating Fate ends. Stiffy Harrows Hell ends falsely when the location is End_Of_Road. Stiffy Harrows Hell ends truly when the location is Inside_the_Cavern.

When Stiffy Harrows Hell begins:

move the player to the Land of the Dead;

now cockglow is 1;

move Madame Sosostris to the couch;

if no garment is worn by the player

begin;

if no garment is carried by the player

begin;

now the burial shroud is worn by the player;

remove the stiffycock from play;

otherwise;

let G be a random garment carried by the player;

now G is worn by the player;

remove the stiffycock from play;

end if;

end if;

now the description of Madame Sosostris is "[if Madame Sosostris is on the couch]Madame Sosostris, a little the worse for wear, rests on the couch, a martini[9 as a footnote] in her hand[otherwise]Madame Sosostris, looking a bit battered, is here, martini[9 as a footnote] clutched in one shaky hand[end if]." ;

now Madame Sosostris is unboinked;

now the default reply of Madame Sosostris is "'Not now, darling. Auntie is hung.'".

The Underworld is a region. The Unreal City, the Garden, the Plaza, the Land of the Dead, Little Thebes, Rats' Alley, the Slough of Despond, the Apartment, the Bloody Wood, the Riverbank, the Northern_riverbank, the Circular Ruins, the Olive Grove, the Muddy Field, and Persephone's Palace are in the Underworld.

The burial shroud is a garment. The description is "A coarse, brown, woolen burial shroud." Understand "coarse", "brown", and "woolen" as the burial shroud. The warmth of the burial shroud is 3.

The Cerberus_turn_count is a number that varies. The Cerberus_turn_count is 0. The Cerberus_taunt_thing is a thing that varies. The Cerberus_taunt_thing is the real_sausage. A cerberus_state is a kind of value. The cerberus_states are guarding, intrigued, and infighting. Cerberus has a cerberus_state. Cerberus is guarding.

The daytime_text is text that varies. The daytime_text is "noon". The daytime_citation is text that varies. The daytime_citation is "III.208". The phlebas_turn_count is a number that varies. The phlebas_turn_count is 0.

Every turn during Stiffy Harrows Hell:

if Cerberus is guarding or Cerberus is intrigued

begin;

if Cerberus is intrigued

begin;

if the location is the Apartment

begin;

say "Cerberus snuffles and moans outside the apartment. Madame Sosostris seems unruffled.";

otherwise;

if Cerberus is not in the location

begin;

now the Cerberus_turn_count is 0;

let R be the best route from the location to the location of Cerberus, using doors;

say "Cerberus comes galumphing in from [the R][if the location is the Unreal City], scattering the men in suits like bowling pins[end if][if the location is Little Thebes], prompting a collective sigh from the denizens[end if].";

if the location is the Unreal City

begin;

if the location of the umbrella is not a room

begin;

say "[line break]A black umbrella pirouettes to the ground.";

move the umbrella to the Unreal City;

remove the scenery_umbrella from play;

end if;

end if;

move Cerberus to the location;

otherwise;

now the Cerberus_turn_count is the Cerberus_turn_count + 1;

if the Cerberus_turn_count is 1, say "Cerberus, drooling violently, stares at [the Cerberus_taunt_thing] and whines.";

if the Cerberus_turn_count is 2, say "Cerberus paws at [the Cerberus_taunt_thing], nearly knocking it from your grasp, as you dance backward hurriedly.";

if the Cerberus_turn_count is 3

begin;

say "Cerberus lunges for [the Cerberus_taunt_thing]. He gets it, and, unfortunately, you with it.";

end the story saying "You have been devoured";

end if;

end if;

end if;

end if;

if Cerberus is in the location of the player

begin;

if no garment is worn by the player

begin;

if Cerberus is not warned_about

begin;

now Cerberus is warned_about;

say "The right head begins frenetically sniffing and licking at your exposed navel, nearly knocking you off your feet.";

otherwise;

say "The right head lunges for your navel. Unfortunately, it does so rather too enthusiastically, and inadvertently eviscerates you.";

end the story saying "You have been schnorfled to death";

end if;

end if;

end if;

otherwise;

choose a random row in the Table of Fighting Cerberus Descriptions;

now the description of Cerberus is the fighting_description entry;

end if.

Every turn during Stiffy Harrows Hell: if the location is the garden

begin;

if the location of Cerberus is the garden

begin;

if the location of Stetson is the garden

begin;

say "The dog sniffs. Huge horrible ropes of drool trail from the center head's flews as it roots around in the garden. Suddenly it begins to dig in the mound from which the lilac bush grows, dirt flying in all directions.[paragraph break]";

say "Stetson turns as white as his hat. The dog makes snorting noises. The lilac bushes are uprooted. A horrible stench fills the air. The central head emerges from the hole it has dug, a greenish, rotten arm clutched in its teeth.[paragraph break]";

say "Stetson leaps astride the stone snail, shrieking obscenities, and kicks it in the side. It shudders and rises a few feet into the air. Then he pushes both horns forward. The snail shoots off into the distance in a contrail of twinkling slime. Stetson's hat drifts slowly to the ground.[paragraph break]";

say "The small right head snarls at the central head and bites its ear. The middle head yelps and drops the arm, which the left head smugly snatches. Then the right head attacks the left head, as the central head drops to the ground, whines, and covers its snout with its front paws. The left head drops the arm to reply in a flurry of teeth and growls. The central head begins to reach for the arm, but is quickly dissuaded by the other two.[paragraph break]";

Move the ten-gallon hat to the location;

Remove Stetson from play;

Now Cerberus is infighting;

now the printed name of Cerberus is "Cerberus (fighting with itself)";

Remove the lilac bush from play;

Remove the mound from play;

Remove the stone snail from play;

Move the scattered earth to the location;

Move the dead arm to the location;

If the Cerberus_taunt_thing is the real_sausage

begin;

let _T be a random number from 1 to 3;

say "In all the excitement, the sausage drops from your grasp, and the [if _T is 1]left[end if][if _T is 2]middle[end if][if _T is 3]right[end if] head slurps it down without breaking stride.";

otherwise;

say "In all the excitement, the kitten wriggles from your grasp and vanishes over the garden wall.";

end if;

remove the Cerberus_taunt_thing from play;

end if;

end if;

end if.

Every turn during Stiffy Harrows Hell: if the location is Persephone's palace

begin;

if the location of Cerberus is Persephone's palace

begin;

if the location of Persephone is Persephone's palace

begin;

say "[if Persephone is handled]Persephone[otherwise]The woman[end if] jumps to her feet. 'Bad dog!' she shouts. 'You go get back to your gate. Now!'[line break]";

say "The dog pauses in mid-drool. With a sheepish glance, it drops its chest and half-heartedly play-bows to [if Persephone is handled]Persephone[otherwise]the woman[end if]. She glares. It whines, and slinks off.[line break]";

say "[if Persephone is handled]Persephone[otherwise]The woman[end if] reseats herself on the throne and smiles. 'He don't mean no harm,' she explains. 'He just gets rambunctious, is all.'";

now Cerberus is guarding;

move Cerberus to the Plaza;

end if;

end if;

end if.

Every turn during Stiffy Harrows Hell: if Madame Sosostris is horny

begin;

if the the location is not Persephone's Palace and the location is not Little Thebes and the location is not the Bloody Wood

begin;

if Madame Sosostris is not in the location

begin;

choose a random row in Table of Sosostral Perambulation;

let d be the best route from the location to the location of Madame Sosostris;

if d is inside or d is outside

begin;

repeat with r running through directions

begin;

let dest be the room r from the location;

if dest is the location of Madame Sosostris

begin;

if r is not inside and r is not outside

begin;

now d is r;

end if;

end if;

end repeat;

end if;

if d is inside or d is outside

begin;

say "Madame Sosostris [mode entry] in from [the location of Madame Sosostris], martini clutched in her hand.";

otherwise;

say "Madame Sosostris [mode entry] in from [the d], martini clutched in her hand.";

end if;

move Madame Sosostris to the location;

if the location is the Garden and Cerberus is in the Garden, say "'Hello, puppy!' coos Madame Sosostris delightedly.";

end if;

end if;

end if.

[quell stupid disambiguation messages]

Every turn during Stiffy Harrows Hell: if the location of the umbrella is not the Unreal City and the umbrella is not held by Agamemnon

begin;

move the scenery_umbrella to the Unreal City;

otherwise;

remove the scenery_umbrella from play;

end if.

Every turn during Stiffy Harrows Hell: if the location is the Bloody Wood and the umbrella is not held by Agamemnon and a random chance of 1 in 3 succeeds

begin;

choose a random row in the Table of Agamemnon's Expletives;

let E be the epithet entry;

choose a random row in the Table of Agamemnon's Expletives;

let B be the body part entry;

say "'[E]!' exclaims [Agamemnon], as a shower of guano rains down onto his [B][if a random chance of 1 in 2 succeeds]. A nightingale chirps smugly[end if].";

end if.

Every turn during Stiffy Harrows Hell: if no garment is worn by the player

begin;

if the location of Madame Sosostris is the location and a random chance of 1 in 3 succeeds, say "You catch Madame Sosostris checking out your schlong. She smiles encouragingly at you.";

if the location of Persephone is the location and a random chance of 1 in 3 succeeds

begin;

if Persephone is horny

begin;

say "[Persephone] considers your penis and licks her lips.";

otherwise;

say "With a speculative look in her eye, [Persephone] considers your penis.";

end if;

end if;

if the location of the Dougs is the location and a random chance of 1 in 3 succeeds, say "The old men nudge each other and point at your exposed penis.";

if the location of Agamemnon is the location and a random chance of 1 in 3 succeeds, say "You notice [Agamemnon] shooting a nervous glance at your genitals.";

if the location of Stetson is the location and a random chance of 1 in 2 succeeds, say "Stetson growls at you: 'Cover up your pecker, bwah. T'ain't decent.'";

if the location of Apeneck Sweeny is the location and a random chance of 1 in 3 succeeds, say "Sweeny asks, 'Isn't that kind of drafty?'";

end if.

Every turn during Stiffy Harrows Hell:

If Madame Sosostris is in the Garden

and Cerberus is in the Garden

and the player is in the Garden

begin;

let C be a random number between 1 and 3;

if C is 1, say "Madame Sosostris simpers and addresses the dog in baby talk: 'Diddums dig up dat mean ol[apostrophe] Stetson's garden? Awwww, whadda [italic type]good dog[roman type]. Are you da bestest dog? I betchoo [italic type]aaaarrre[roman type].' Cerberus slowly oscillates his tail, but makes no other indication that he's heard her.";

if C is 2, say "Madame Sosostris makes kissy noises at Cerberus, but the dog is too preoccupied with the arm and its own infighting to pay her any attention.";

end if.

Every turn during Stiffy Harrows Hell:

If Madame Sosostris is in the Circular Ruins

and Apeneck Sweeny is in the Circular Ruins

and the player is in the Circular Ruins

and Madame Sosostris is unboinked

and Apeneck Sweeny is unaroused

begin;

now Madame Sosostris is boinked;

say "Madame Sosostris's eyes light up as they fall on [if Apeneck sweeny is handled]Sweeny[otherwise]the red-haired man[end if]. 'Oh, [italic type]hello[roman type],' she coos. She places a hand on [if Apeneck sweeny is handled]Sweeny[otherwise]the red-haired man[end if]'s muscular arm. 'Is all of you built to scale?' [paragraph break]";

say "He considers the question. 'No,' he says finally. 'It's all a little shrivelled, because I'm so parched. I don't suppose you'd...' He glances pointedly at her martini. [paragraph break]";

say "'No,' she snaps, 'Get your own drink. I may be horny but I'm not [italic type]that[roman type] horny.' [paragraph break]";

say "He nods. 'I know the feeling. Sure wish I had a drink.' [paragraph break]";

say "'I sure wish you had a drink too,' she murmurs. Both of them turn to glare at you.";

end if;

Every turn during Stiffy Harrows Hell:

If Madame Sosostris is in the Circular Ruins

and Apeneck Sweeny is in the Circular Ruins

and the player is in the Circular Ruins

and Apeneck Sweeny is horny

begin;

now Madame Sosostris is boinked;

now Apeneck Sweeny is boinked;

say "'Hel-[italic type]lo[roman type] sailor,' says Madame Sosostris, placing a hand on [if Apeneck Sweeny is handled]Sweeny[otherwise]the red-haired man[end if]'s chest. [paragraph break]";

say "'What's a nice girl like you doing in a place like this?' he asks. [paragraph break]";

say "'Just lucky, I guess,' she replies, taking his hand and dragging him behind a nearby pile of rubble. Sounds of passion ensue. After a few minutes, Madame Sosostris emerges from behind the rubble, looking considerably more relaxed.";

remove Apeneck Sweeny from play;

move sleeping_Sweeny to the Circular Ruins;

end if.

Every turn during Stiffy Harrows Hell:

if the location is Persephone's Palace for the first time

begin;

choose a row with a character of "Persephone" in the Table of Real Cast Members;

now the met entry is true;

end if;

if the location is the Plaza for the first time

begin;

choose a row with a character of "Cerberus" in the Table of Real Cast Members;

now the met entry is true;

end if;

if the location is the Muddy Field for the first time

begin;

choose a row with a character of "Tantalus" in the Table of Real Cast Members;

now the met entry is true;

end if;

If the remainder after dividing the turn count by 100 is 0

begin;

if the daytime_text is "dawn"

begin;

now the daytime_text is "noon";

if the location of the player is not the Unreal City, now the daytime_citation is "III.208";

otherwise;

now the daytime_text is "dawn";

if the location of the player is not the Unreal City, now the daytime_citation is "I.61";

end if;

end if;

[ * This is because the "look" to see the new description takes a turn, so if we don't lag the citation by a turn, we can end up with the reference appearing wrong to the player ]

if the remainder after dividing the turn count by 100 is 1

begin;

if the daytime_text is "dawn"

begin;

now the daytime_citation is "I.61";

otherwise;

now the daytime_citation is "III.208";

end if;

end if.

Every turn during Stiffy Harrows Hell:

if zombie_Phlebas is in the location and Charon is in the location and Madame Sosostris is not in the location

begin;

if a random chance of 1 in 3 succeeds

begin;

say "Pleadingly, [Zombie_Phlebas] clasps his hands towards [Charon], who shakes his bony head: no.";

otherwise;

if a random chance of 1 in 2 succeeds

begin;

say "Moodily kicking at the sand, [Zombie_Phlebas] takes a swallow of wine, which then pours from holes in his worm-raddled neck and chest.";

otherwise;

say "Stealthily, [Zombie_Phlebas] takes a step towards the dory, and [Charon] swats him with the pole.";

end if;

end if;

end if.

Every turn during Stiffy Harrows Hell:

if zombie_Phlebas is in the location and Charon is in the location and Madame Sosostris is in the location

begin;

say "Madame Sosostris stares at the walking corpse. 'Oh, Phlebas, you poor thing!' she cries. Then she wheels on Charon in a fury. 'Can't you see,' she shouts, 'that this man is dead? Why haven't you given him passage?' [paragraph break]";

say "Charon shifts uneasily from one foot to the other; he begins to make a gesture rather like a complicated shrug, but Madame Sosostris cuts him off. 'Fine. Yes, it's my fault. I accept full blame. I got [italic type]his[roman type]'[emdash]pointing to you";

say "[emdash]'and [italic type]his[roman type]'[emdash]indicating Phlebas[emdash]'fortunes mixed up. Now, take it from me: this man's dead. Give him a ride.' [paragraph break]";

say "Charon holds up one bony finger. 'Right!' snaps Madame Sosostris. 'Heaven forbid you should give a freebie to the poor man.' She produces a small iron coin, which she attempts to place under Phlebas's tongue. As he hasn't got much lower jaw left, this proves spectacularly unsuccessful, and she eventually simply flings the coin into the bottom of the boat. 'There's his fare. Now go. Go!'[paragraph break]";

say "Phlebas drops his wineskin on the riverbank and steps into the boat, pausing, unnervingly, to pat you on the shoulder in a pitying sort of way. Charon, shaking his head apologetically, poles off into the mist.";

now the phlebas_turn_count is the turn count + 4;

move the wineskin to the location;

move Charon to the Riverbank;

move the skiff to the Riverbank;

really have the parser notice the wineskin;

remove Zombie_Phlebas from play;

end if.

Every turn during Stiffy Harrows Hell:

if the phlebas_turn_count is not 0 and the location is the Northern_riverbank and the turn count is greater than the phlebas_turn_count

begin;

say "The skiff and its sepulchral ferryman loom out of the mist towards the shore.";

move Charon to the location;

move the skiff to the location;

now the phlebas_turn_count is 0;

end if.

Test to-Eris with "Test to-pirates / ask pal about thessalonica / test piracy / test rowing / test viking / test woad / test intro".

Test to-Vikings with "Test to-pirates / ask pal about thessalonica / test piracy / test rowing".

Test to-Hades with "Test to-Eris / Test Eris".

Test To-Pirates with "Test Intro / Test Rome / Test Ostia / test sb1 / test sb2 /test sb3 / test sbwhale / test africa / test hippo/ test sb4 ".

Test Hades1 with "n/ n/ w/ x old man/ x tiresias/ taste sausage/ e/ show sausage to dog".

Test Hades2 with "s/ w/ get hat/ e/ get umbrella/ e/ give hat/ fuck persephone".

Test Hades3 with "get toga / wear it / w / n / x obelisk/ x runes / e / get bone / w / n / w / give umbrella/ e/ n/ give bone".

Test Hades4 with "enter skiff/ w/ give wine/ get vinegar/ e / n".

Test Hades5 with "n/ pour vinegar on tree/ get olive/ s/ s/ enter skiff/ s/ s/ e/ n/give olive".

Test Hades6 with "s/w/n/n/enter skiff/ get wineskin / n /give wineskin to sweeny".

Test Hades with "Test Hades1 / Test Hades2 / Test Hades3 / Test Hades4 / Test Hades5 / Test Hades6".

Test min-hades with "n / n / w / x old man / taste sausage / e / show sausage to dog / s / w / e /get umbrella / n / e / get bone / w / n / w / give umbrella / e / n / give bone / test hades4 / test hades5 / test hades6 / e".