# Stiffy Makane: Apocolocyntosis — 201 of 235

## One of the Bruces and Drunken Bastard

Release 1

- Home page
- Beginning
- Previous
- Next

Volume Eighteen - "Bucolic Interlude"

Bucolic Interlude is a scene. Bucolic Interlude begins when the location is in Mantua. Bucolic Interlude ends when the location is not in Mantua.

A chef-fetch-quest-item is a kind of thing.

The Vergilian gripe counter is a number that varies. The Vergilian gripe counter is 0.

Every turn during Bucolic Interlude:

if Villa Peristyle is not warned_about

begin;

if Madame Sosostris is in the location

begin;

if a random chance of 1 in 3 succeeds

begin;

choose a random row in Table of Sosostral Action;

say "Madame Sosostris [drunken-action entry].";

end if;

otherwise;

choose a random row in Table of Sosostral Perambulation;

let R be the best route from the location to the location of Madame Sosostris, using doors;

say "Madame Sosostris [mode entry] in from [the R], martini clutched in her hand.";

move Madame Sosostris to the location;

end if;

end if.

Every turn during Bucolic Interlude:

if the duck is not in Limbo and the location of the duck is a room

begin;

if the duck is in the location

begin;

if a random chance of 1 in 3 succeeds

begin;

if the duck is not warned_about

begin;

say "[The duck] [if the moonmilk is not warned_about]quacks pathetically at you[otherwise]whimpers about the injustice of her cursed life[end if].";

otherwise;

say "[The duck] [if the moonmilk is not warned_about]quacks with grim determination[otherwise]mutters darkly about her plans for Juno, which seem to include nibbling to death[end if].";

end if;

end if;

otherwise;

choose a random row in Table of Duckly Perambulation;

let R be the best route from the location to the location of the duck, using doors;

say "[The duck] [mode entry] in from [the R], [if the moonmilk is not warned_about]quacking[otherwise]muttering[end if] under her breath.";

move the duck to the location;

end if;

end if.

Every turn during Bucolic Interlude:

if the duck is in the location and the duck is warned_about and some potatos are not warned_about, now the potatos are warned_about.

Every turn during Bucolic Interlude:

if the location is Cavern_Mouth or the location is Inside_the_Cavern

begin;

if Vergil is not handled

begin;

if the Table of Bucolic Observations is not empty

begin;

Choose a random row in the Table of Bucolic Observations;

say "From outside the cave, a declamation comes:[line break]'[observation entry]'[paragraph break]";

blank out the whole row;

otherwise;

say "Muttering and scratching can be heard outside the cave.";

end if;

end if;

end if.

Every turn during Bucolic Interlude:

if Vergil is handled and the location of Vergil is not the location and Villa Peristyle is not warned_about

begin;

choose a random row in the Table of Vergilian Perambulation;

let R be the best route from the location to the location of Vergil, using doors;

say "Vergil [mode entry] in from [the R], [run paragraph on]";

choose a random row in the Table of Vergilian Perambulation;

say "[poetic-action entry].";

move Vergil to the location;

end if.

Every turn during Bucolic Interlude:

if Vergil is handled and the location of Vergil is the location and a random chance of 1 in 4 succeeds

begin;

if the Table of Epic Amendments is not empty

begin;

Choose a random row in the Table of Epic Amendments;

say "Vergil mutters softly to himself: '[amendment entry]'[paragraph break]";

blank out the whole row;

end if;

end if.

Every turn during Bucolic Interlude:

if the location is Villa Peristyle and the location of Vergil is the location and the location of Madame Sosostris is the location

begin;

if Villa Peristyle is not warned_about

begin;

say "Vergil looks around and says, 'Let's have some lunch. Stiffy, can you please go find the cook and ask him about it?' Madame Sosostris nods in agreement.";

now Villa Peristyle is warned_about;

otherwise;

if the Vergilian gripe counter is 0

begin;

say "Vergil looks slightly peevish. 'I say, Stiffy, haven't you got the cook working yet?'";

end if;

if the Vergilian gripe counter is 1

begin;

say "Vergil frowns. 'I want my lunch.'";

end if;

if the Vergilian gripe counter is 2

begin;

say "Madame Sosostris stage-whispers, 'Oh, my, I'm just parched!'";

end if;

if the Vergilian gripe counter is 3

begin;

say "Vergil mutters something unkind about Gallic chefs.";

end if;

if the Vergilian gripe counter is 4

begin;

say "Vergil experimentally tries gnawing on the edge of the table. Madame Sosostris giggles.";

end if;

if the Vergilian gripe counter is 5

begin;

say "Vergil says something witty about his Gallic chef being divided into three parts.";

end if;

if the Vergilian gripe counter is greater than 5

begin;

say "Vergil and Madame Sosostris widen their eyes at you and moan pitifully in hunger, clutching their bellies and sucking in their cheeks.";

end if;

increase the Vergilian gripe counter by 1;

end if;

end if;

Every turn during Bucolic Interlude:

if the stiffycock is visible

begin;

if Madame Sosostris is in the location and a random chance of 1 in 3 succeeds

begin;

say "You catch Madame Sosostris eyeing your cock. She smiles sweetly at you.";

end if;

if Vergil is in the location and a random chance of 1 in 3 succeeds

begin;

say "Vergil tries, unsuccessfully, to pretend he wasn't just staring at your penis.";

end if;

if the French chef is in the location and a random chance of 1 in 3 succeeds

begin;

say "[The French chef] glances at your cock. '[italic type]Saucisson chaud,[roman type]' he helpfully notes[47 as a footnote], with a Gallic shrug.";

end if;

if the location encloses the scullery maid and a random chance of 1 in 3 succeeds

begin;

say "[The scullery maid] looks [if the scullery maid is boinked]affectionately[otherwise]longingly[end if] at your cock[if the scullery maid is unboinked]. 'Sure could use me some of that,' she opines[end if].";

end if;

end if.

Every turn during Bucolic Interlude:

if the location of the chestnuts is not a room, move the chestnuts to Chestnut Grove.

Every turn during Bucolic Interlude:

If the location is Villa Atrium and Villa Atrium is not warned_about

begin;

now Villa Atrium is warned_about; [ the first time you enter the Villa, if you have no toga, Vergil will give you a new toga ]

if the toga is not worn by the player and the toga is not carried by the player and the location of Vergil is the location

begin;

say "Vergil holds up a finger. 'Just a moment,' he says, and disappears into the house. He emerges soon with a freshly-laundered toga,[run paragraph on]";

unless no garment is worn by the player

begin;

repeat with G running through the garments worn by the player

begin;

try silently taking off G;

end repeat;

end unless;

if no garment is worn by the player

begin;

now the toga is worn by Stiffy Makane;

now the toga is sparkling;

remove the stiffycock from play;

say " which he helps you to don.";

otherwise;

now the toga is carried by Stiffy Makane;

now the toga is sparkling;

say " but the two of you can't figure out how to get it on over [the random garment worn by the player], so he settles for handing it to you.";

end if;

end if;

end if.

Every turn during Bucolic interlude:

if no garment is worn by the scullery maid

begin;

now the scullery maid's tits are part of the scullery maid;

now the scullery maid's pussy is part of the scullery maid;

now the scullery maid's asshole is part of the scullery maid;

otherwise;

remove the scullery maid's tits from play;

remove the scullery maid's pussy from play;

remove the scullery maid's asshole from play;

end if.

Every turn during Bucolic interlude:

if the location of the duck is Little Pond and the location is Little Pond

begin;

if the duck is warned_about

begin;

say "[The duck] contemplates the duckweed calmly and smugly.";

otherwise;

say "[The duck] lunges ravenously towards the duckweed, and then her head sharply turns to one side as if she's been slapped. '[if the moonmilk is warned_about]Damnit[otherwise]Quack[end if]!' she cries.";

end if;

end if.

Every turn during Bucolic Interlude:

if the location of the duck is the location of the French Chef

begin;

if the duck is not warned_about

begin;

say "The chef contemplates [the duck] sadly. 'She is much too skinny,' he says in a disappointed tone. 'You must fatten her up before she is worthy of being eaten.' [The duck] shakes her head disconsolately.";

otherwise;

say "'Wonderful, monsieur!' shouts the chef. He leaps toward the duck, who makes no attempt to resist. You have to look away as he quickly and expertly snaps [the duck]'s neck and then plunges her corpse into a vat of boiling water. In just a few moments, your erstwhile friend is reduced to a plucked and gutted carcass lying on the countertop.";

remove the duck from play;

move the dead_duck to the countertop;

end if;

end if.

Every turn during Bucolic Interlude:

if every chef-fetch-quest-item is on the countertop and the location is the kitchen

begin;

say "[The French chef] says 'At last I can begin. Shoo! Shoo!' He hustles you out of the kitchen into the peristyle, where you sit and wait with Vergil and Madame Sosostris as a series of ever more mouth-watering smells come from the kitchen. Shortly, crispy duck stuffed with chestnuts emerges on a platter borne by [the French chef]. He places it on the table, and as Madame Sosostris takes the first bite, there is the unmistakable smell of lilac and the whoosh of a canardic soul ascending to heaven. The meal, and the wine, are fantastic, and after the wine is drunk and the duck consumed Vergil makes arrangements for your travel back to your home in Ostia.";

remove the duck_call from play;

remove the cellar key from play;

now the toga is worn by the player;

consider the major-scene-change rule;

now the destination of the gangway is "Ostia";

repeat with N running from 1 to the number of rows in the the Table of Ports

begin;

choose row N in the Table of Ports;

now the ship-present entry is "no";

end repeat;

choose row with a port-name of "Ostia" in the Table of Ports;

now the ship-present entry is "yes";

move Bruno to Dockside;

move Palinurus to Poop Deck;

move gangway to Poop Deck;

move the player to Stiffy Love Nest;

end if.

Mantua is a region. Mantua_outdoors is a region. Villa Entrance, Little Pond, Chestnut Grove, and Field Near Cave are rooms in Mantua_outdoors. Mantua_outdoors is in Mantua. Mantua_cave is a region. Inside_the_Cavern and Cavern_Mouth are rooms in Mantua_cave. Mantua_cave is in Mantua. Mantua_indoors is a region. Villa Atrium, Villa Peristyle, and Kitchen are rooms in Mantua_indoors. Mantua_indoors is in Mantua. Mantua_cellars is a region. Pantry, Root Cellar, Shadowy Nook, Wine Cellar, and Dim Alcove are rooms in Mantua_cellars. Mantua_cellars is in Mantua.

Test to-mantua with "test to-hades / test hades / e".

Test mantua-outside with "e / e / s / get chestnuts / n / e / get duckweed / w / n / e / e".

Test mantua-indoors with "s / ask chef about lunch / get call / e / s / remove toga / remove tunic / fuck maid / ask maid about key / get key / n".

Test cellar with "unlock door with key / open door / e / e / search moonmilk / eat moonmilk / get wine / w / w / w".

Test cooking with "give wine to chef / give chestnuts to chef / n / w / w / blow call / ask duck about curse / give duckweed to anas / e / e / s".

Test mantua with "Test mantua-outside / test mantua-indoors / test cellar / test cooking".

Test through-mantua with "test to-mantua / test mantua".

Table of Sosostral Action

drunken-action
"belches delicately"
"blinks owlishly"
"wobbles blearily"
"emits a small, ladylike hiccup"
"staggers in a tight circle"
"shakes her head as if to clear it, stumbles, and nearly falls"