# Stiffy Makane: Apocolocyntosis — 14 of 235

## One of the Bruces and Drunken Bastard

Release 1

- Home page
- Beginning
- Previous
- Next

Part Four - "Scoring"

To record (T - text) as achieved:

choose row with a citation of T in the Table of Conquests;

if there is no turn entry begin;

now turn entry is the turn count;

increment the score;

end if.

Table of Conquests

Citation | turn
"Julius Caesar" | a number
"Julia" | --
"the Golden Apple" | --
"Festus" | --
"Gaius Norbanus Flaccus" | --
"Archie" | --
"Dr. Nick" | --
"Mr. Eugenides" | --
"Cleopatra" | --
"Alexander the Great's corpse" | --
"Rachel" | --
"a muskmelon" | --
"an effeminate Greek pirate" | --
"the Druidic priestess" | -- |
"Tiresias" | --
"Persephone" | --
"Ulpia" | --
"Trivia" | --

[1]

Table of Erisian Conquests

adjective | occupation | appelation | location | adjective-in-use | occupation-in-use | appelation-in-use | location-in-use
"an enthusiastic if unskilled" | "goatherd" | "called Xanthippos" | "atop a moss-grown abandoned altar in a forest" | false | false | false | false
"a haughty" | "courtesan" | "named Gygaxia" | "on Level [a random number between 1 and 38] of the Dungeons Of Dread" | false | false | false | false
"a drunken" | "satyr" | "whose name you never learned" | "in a rowboat on a pond" | false | false | false | false
"a red-faced and enraged" | "noble" | "too overawed to speak" | "in the town square in broad daylight" | false | false | false | false
"a meek" | "wandering musician" | "with a heart of gold" | "in the moonlight" | false | false | false | false
"a saucy" | "tart" | "from Clan Bledsaw" | "in an arctic wasteland" | false | false | false | false
"a wanton" | "wench" | "named Hargrave" | "in the western reaches of Arduin" | false | false | false | false
"a fumblingly amorous" | "boar hunter" | "with no name" | "in a stone tower by the sea" | false | false | false | false
"a dizzyingly proficient" | "minor deity" | "of House Arneson" | "in a cold and fast-running stream" | false | false | false | false
"a slovenly" | "trull" | "named Glaucon" | "behind an overturned tavern table" | false | false | false | false
"a brazen" | "strumpet" | "by the name of Lydia" | "in the muck of a pig-pen" | false | false | false | false |
"an extravagantly tattooed" | "gigolo" | "from Moldavia" | "on a bed of linden leaves" | false | false | false | false
"a loutish and unwashed" | "lesser godling" | "inauspiciously named Smegmathos" | "high up in a ship's rigging" | false | false | false | false
"a terrifying yet sexy" | "Bthuvian Demon Whore" | "who remained anonymous" | "in a Pleasure Prison" | false | false | false | false
"a forgetful" | "survivor of Plataea" | "called Latro" | "in a spooky graveyard" | false | false | false | false
"a cynical" | "freed slave" | "with a mysterious past" | "on the slopes of Mt. Etna" | false | false | false | false |

The global_rows_erisian_conquest_table_used is a number that varies. The global_rows_erisian_conquest_table_used is 0.

The fancy announce the score rule is listed instead of the announce the score rule in the carry out requesting the score rulebook.

The endgame summarize score rule is listed instead of the print final score rule in for printing the player's obituary.

Understand "full" or "full score" as requesting the score. The endgame score flag is a number that varies. The endgame score flag is 0.

This is the endgame summarize score rule:

now the endgame score flag is 1;

consider the fancy announce the score rule.

This is the fancy announce the score rule:

if scenery_argus is boinked, now the endgame score flag is 1;

let S be possible-points-by-summit + 1;

let R be the score;

if R > S, now R is S;

if the player is Stiffy Makane

begin;

if the location is the Lake or the location is the Battlement and the story has not ended

begin;

say "Now is not, in fact, the time to reminisce about your past conquests, many and varied though they be.";

otherwise;

say "[if scenery_argus is boinked]During your mortal life, y[otherwise]Y[end if]ou [run paragraph on]";

if the score is 0

begin;

say "[if the endgame score flag is 1]did not score[otherwise]have not scored[end if] with anyone.";

otherwise;

if the score is 1

begin;

say "[if the endgame score flag is 0]have [end if]scored once: [run paragraph on]";

otherwise;

say "[if the endgame score flag is 0]have [end if]scored a total of [the score in words] times: [run paragraph on]";

end if;

let N be 0;

repeat through the Table of Conquests in turn order

begin;

increase N by 1;

if N is R and N > 1

begin;

say "and [run paragraph on]";

end if;

say "with [citation entry]";

if N is less than R, say ", [run paragraph on]";

end repeat;

say ".";

end if;

if scenery_argus is boinked

begin;

say "[line break]And then of course there was Argus, in a category of his own.";

end if;

end if;

otherwise;

if the player is Eris

begin;

say "Your lovers have been so many and varied that it's hopeless to try to recall them all. Some particularly memorable ones: [run paragraph on]";

if Argus is boinked

begin;

say "Argus, Argus, Argus, Argus, and Argus.";

otherwise;

repeat with M running from 1 to 5

begin;

let T be true;

while T is true

begin;

choose a random row from the Table of Erisian Conquests;

let T be the adjective-in-use entry;

end while;

say "[adjective entry] [run paragraph on]";

now the adjective-in-use entry is true;

let T be true;

while T is true

begin;

choose a random row from the Table of Erisian Conquests;

let T be the occupation-in-use entry;

end while;

now the occupation-in-use entry is true;

say "[occupation entry] [run paragraph on]";

let T be true;

while T is true

begin;

choose a random row from the Table of Erisian Conquests;

let T be the appelation-in-use entry;

end while;

now the appelation-in-use entry is true;

say "[appelation entry] [run paragraph on]";

let T be true;

while T is true

begin;

choose a random row from the Table of Erisian Conquests;

let T be the location-in-use entry;

end while;

now the location-in-use entry is true;

say "[location entry][run paragraph on]";

increase global_rows_erisian_conquest_table_used by 1;

if global_rows_erisian_conquest_table_used is the number of rows in the Table of Erisian Conquests

begin;

repeat through the Table of Erisian Conquests

begin;

now the adjective-in-use entry is false;

now the occupation-in-use entry is false;

now the appelation-in-use entry is false;

now the location-in-use entry is false;

end repeat;

now global_rows_erisian_conquest_table_used is 0;

end if;

if M < 5, say ", [run paragraph on]";

if M is 4, say "and [run paragraph on]";

end repeat;

say ".";

end if;

end if;

if the player is a pumpkin

begin;

let M be the mortal score;

say "During your mortal life, you scored a total of [M] times: [run paragraph on]";

let N be 0;

repeat through the Table of Conquests in turn order

begin;

increase N by 1;

if N is M and N > 1

begin;

say "and [run paragraph on]";

end if;

say "with [citation entry]";

if N is less than M, say ", [run paragraph on]";

end repeat;

say ".";

let D be the score - M;

decrement D;

say "[line break]And then of course there was Argus, in a category of his own.[paragraph break]Finally, while you were an immortal pumpkin, you scored [D] more times.";

end if;

end if.

Note

[1]. Note the appearance of the AD&D v1 Wandering Harlot Table here with the haughty courtesan, the saucy tart, the wanton wench, the slovenly trull, and the brazen strumpet