# Stiffy Makane: Apocolocyntosis — 70 of 235

## One of the Bruces and Drunken Bastard

Release 1

- Home page
- Beginning
- Previous
- Next

Chapter One - "Ostia"

Ostia is a room. It is south of the Atrium. "The main street of Ostia heads west to the docks. Your house is north. The baths are to the east." Ostia is outside from the Atrium.

The scenery_house is scenery in Ostia. The printed name is "house". The description is "Your family's house is a well-appointed Roman townhouse, neither the biggest nor the smallest on the block." Understand "your", "family's", "house", "villa", "townhouse", and "apartment" as the scenery_house. The scenery_house can be enterable. It is enterable. Instead of entering the scenery_house, try going north.

Before going east in Ostia for the first time, say "I bet you were expecting a big, elaborate implementation of the baths, with assignations to be had, intrigues to be performed, and loving and careful descriptions of the various parts of a Roman bath. Sorry about that."

Instead of going east in Ostia:

say "You duck into the baths and freshen yourself up[if the toga is visible]; while you're at it you drop off your toga to be laundered and receive a freshly-cleaned one in its stead[end if].";

now Stiffy Makane is sparkling;

if Glub is warned_about and Glub is unaroused

begin;

say "[line break]You also find Fatty Norbanus, and, with a little oral persuasion, you cajole him into surrendering an invitation token to his party.";

now the invitation token is held by Stiffy Makane;

really have the parser notice the invitation token;

now Glub is horny;

record "Gaius Norbanus Flaccus" as achieved;

end if;

if the toga is visible

begin;

now the toga is cleanish;

if the toga is not worn, try wearing the toga;

end if.

The invitation token is a thing. The description is "This is a small brass token: one one side it reads 'ADMIT ONE' and on the other 'G. Norbanus Flaccus' is embossed." Understand "brass" and "small" as the invitation token. Instead of rolling the invitation token, say "There would be no point in doing so." Instead of tasting the invitation token, say "What would be the point?" Instead of smelling the invitation token, try tasting the invitation token.

Some pbs1 are men in Ostia. They are ambiguously plural. The printed name is "passers-by". They are scenery. The description of the pbs1 is "Passers-by rush to and fro on inscrutable business of their own." Understand "man", "woman", "men", "people", "passer", "passers", "passerby", "passer-byes", "passers-by", and "women" as pbs1. The default reply of the pbs1 is "They pay you no attention." Instead of attacking the pbs1, say "The thought of your father's displeasure, should you begin assaulting the people of Ostia, dissuades you." Instead of fucking the pbs1, say "Your father would not look kindly upon your rape of the people of Ostia." The pbs1 are unspeakable.