# Stiffy Makane: Apocolocyntosis — 171 of 235

## One of the Bruces and Drunken Bastard

Release 1

- Home page
- Beginning
- Previous
- Next

Chapter Two - "Persephone"

Persephone is a woman in Persephone's Palace. "A short, yet amazingly buxom, blonde woman in a white silk garment lounges on the smaller iron throne." The printed name of Persephone is "[if Persephone is handled]Persephone[otherwise]the short woman[end if]". The conversation of Persephone is the Table of Persephone's Chatter. The default reply of Persephone is "Persephone looks at you quizzically. 'Dunno,' she says." The description of Persephone is "She's a short blonde woman, but that's not the first thing you notice about her. The first, last, and pretty near the only thing you notice is how amazingly large her breasts are. Even if she were a tall woman, they'd be huge. As it is, on her they're absolutely [italic type]enormous[roman type]. She wears a white silk pantsuit with gold piping on it[if Persephone is not handled]. She must be Persephone, Pluto's bride[end if]." Understand "woman", "buxom", "Dolly" and "Parton" as Persephone. After examining Persephone: now Persephone is handled. Rule for deciding the concealed possessions of Persephone: no. Persephone has a horniness. Persephone is unaroused. Understand "my" and "reward" as Persephone when Persephone is horny. [ "claim my reward" ]

Instead of showing the Golden Banana to Persephone, say "She smiles. 'I heard Eris was lookin' for a hero to bring it to her.'"

Instead of showing the hat to Persephone, say "'Oooh! Gimme, gimme, gimme!' she shouts excitedly."

Instead of showing the umbrella to Persephone, say "She shrugs uninterestedly.";

Instead of giving the Golden Banana to Persephone, say "She strokes the curve of the banana with one delicate finger, but then shakes her head sadly. 'I stay out of Eris's business, and she stays out of mine.'".

Instead of giving the umbrella to Persephone, say "'That's not the head covering I covet, Stiffy.'"

Instead of giving the hat to Persephone:

now the hat is worn by Persephone;

now Persephone is horny;

if Persephone is not handled

begin;

say "The woman coughs delicately. 'Maybe we oughta be on a first name basis, Stiffy. I'm Persephone. Pleased as punch ta meetcha.'[paragraph break]";

now Persephone is handled;

end if;

now the description of Persephone is "Persephone is wearing a hat, a smile, and a mostly-unbuttoned silk pantsuit that reveals truly amazing cleavage.";

say "Persephone smiles widely, unbuttons another couple buttons on her blouse, and purrs, 'Thank you. You can claim your reward any time, Stiffy.'";

The pantsuit is worn by Persephone. Understand "white", "silk", "garment", "gold", "piping", and "nudie" as the pantsuit. The description is "The white silk pantsuit, decorated with gold piping, seems mostly designed to draw attention to the wearer's cleavage."

Some Persephone's breasts are part of Persephone. They are ambiguously plural. The indefinite article is "the pair of". The description is "[if Persephone is handled]Persephone's[otherwise]The woman's[end if] breasts are simply astonishing." Understand "pair of", "tits", "chest", "hooters", "astonishing", "amazing", "huge", "enormous", "giant", "gigantic", "breast", "cleavage", "tit", and "hooter" as Persephone's breasts. Check taking the breasts: instead try touching the breasts. Instead of kissing the breasts, try sucking the breasts.

Some fingernails are part of Persephone. The description is "Persephone's nails are long and painted bright red." Understand "nail", "nails", "bright", and "red" as fingernails. Instead of touching, smelling, rubbing, kissing, blowing, sucking, or fucking the fingernails, try taking the fingernails.

Instead of smelling Persephone:

say "She smells of an intoxicating, musky perfume."

Before kissing, rubbing, touching, sucking, buggering, or fucking Persephone:

if Persephone is unaroused, instead say "Persephone considers her fingernails minutely. 'No,' she says. 'I'd reconsider if'n you did a little something for me. F'r instance, cover my head with something real nice, and I'll cover [italic type]your[roman type] head with something real nice.'";

Before smelling, rubbing, touching, sucking, or fucking the breasts:

if Persephone is unaroused, instead try fucking persephone.

Instead of kissing Persephone for the first time:

say "Persephone osculates you back with fervor."

Instead of kissing Persephone:

say "You make out with Persephone for a while, and one thing leads to another.";

try fucking Persephone.

Instead of buggering Persephone:

say "Persephone grimaces. 'My [apostrophe]roids are actin[apostrophe] up,' she explains. 'How [apostrophe]bout the front door, instead?' You acquiesce.";

try fucking Persephone.

Instead of rubbing or wanking off Persephone:

say "Persephone moans as you massage her clitoris. One thing leads to another.";

try fucking Persephone.

Instead of touching Persephone:

say "Persephone moans as you massage her clitoris. One thing leads to another.";

try fucking Persephone.

Instead of sucking or blowing or eating Persephone:

say "Persephone writhes, wriggles, and gasps as you give her head. One thing leads to another.";

try fucking Persephone.

Instead of rubbing the breasts:

say "Persephone, as it happens, has very sensitive nipples. She moans and writhes under your touch. Unable to resist, you give her breasts a firm squeeze. 'HONK HONK!'[27 as a reference] she shrieks in ecstasy, which baffles you a bit.";

Instead of touching the breasts:

say "Persephone, as it happens, has very sensitive nipples. She moans and writhes under your touch. Unable to resist, you give her breasts a firm squeeze. 'HONK HONK!' she shrieks in ecstasy[27 as a reference], which baffles you a bit.";

Instead of sucking the breasts:

say "Persephone moans as you suck her nipples. One thing leads to another.";

try fucking Persephone.

Instead of fucking Persephone:

if the stiffycock is not held by the player

begin;

repeat with item running through the garments worn by the player begin;

say "Persephone hungrily strips off [the item] and lets it fall to the floor.[paragraph break]";

move the item to the location;

end repeat;

now the stiffycock is held by the player;

end if;

say "You bend Persephone over the arm of the throne and begin thrusting away. After a bit, though, you realize that you're unlikely to encounter tits of either this quality or this quantity again any time soon, and timidly ask her if she'd...[paragraph break]";

say "'Of course you can, Stiffy!' she exclaims. 'Hell, everyone does; if I had a dick I'd want to too!'[paragraph break]";

try fucking the breasts.

Instead of fucking the breasts:

if the stiffycock is not held by the player

begin;

say "You're not undressed for the occasion.";

otherwise;

say "Persephone sucks your cock to get it good and slimy. Then she kneels in front of the throne, and you slide your dick between her luscious hooters. She moans, 'Pwoik, pwoik, pwoik,'[28 as a reference] softly as you grind away. With a groan, you ejaculate all over her breasts and neck.[paragraph break]";

record "Persephone" as achieved;

say "Persephone dabs a delicate finger into the semen coating her chest, neck and chin. She smiles. 'That was mighty nice, Stiffy. I gotta go shower now. See ya later, but...' she winks at you '...not [italic type]too[roman type] soon, I hope.'";

remove Persephone from play;

end if.

Instead of smelling the breasts:

say "Persephone clearly has anointed her cleavage with her perfume."

Before asking Persephone about something:

if the topic understood matches "pussy/kitty/kittycat/kitten", replace the topic understood with "cat";

if the topic understood matches "sausage" begin;

if the real_sausage is not handled, replace the topic understood with "nope";

if the real_sausage is not warned_about begin;

if the real_sausage is visible

begin;

now the real_sausage is warned_about;

otherwise;

replace the topic understood with "nope";

end if;

end if;

end if;

if the topic understood matches "cat" begin;

if the real_pussy is not handled, replace the topic understood with "nope";

if the real_pussy is not warned_about begin;

if the real_pussy is visible

begin;

now the real_pussy is warned_about;

otherwise;

replace the topic understood with "nope";

end if;

end if;

end if.

Table of Persephone's Chatter

topic | reply | summary | turn stamp
"woman/goddess/Persephone/Dolly/Parton/herself" or "Dolly Parton" | "'Ain't it something? A little girl like me from Pigeon Forge, an[apostrophe] now I'm the Queen of the Dead!'" | "she feels she's come quite a way in life. Er, unlife" | a number
"Cerberus/dog/Vinnie/Ursa/Golem" | "'Aw, he ain't so bad. Likes food and chasing cats, like any dog. Vinnie's the left head. She's kind of a suckup. Golem's the middle head. Now, I know he seems scary, but really, he's very sweet. Watch out for all that slobber, though. And Ursa's the right head. Smarter[apostrophe]n hell, but kind of psychotic.'" | "she thinks Cerberus is a sweetie" | --
"Cerebus" | "'That's an aardvark. Am I ever gonna have fun with Dave Sim when he gets here. I think you mean [italic type]Cerberus[roman type], hon.'" | "she's not much of a Dave Sim fan (who can blame her?)" | --
"hat/Stetson's" | "'Stetson's hat sure is fine. I'd do almost [italic type]anything[roman type] for someone who got it for me.'" | "she covets Stetson's hat" | --
"Tiresias/hermaphrodite/morphodite/blind" | "'Aw. Poor ol' Tiresias.'" | "she pities Tiresias" | --
"Stetson" | "'Stetson's got a nice garden, but he's kind of a jerk. And that hat's way too good for him.'" | "she doesn't like Stetson, but does like his hat" | --
"umbrella/umbrellas" | "'Can't say as I ever gave the umbrellas a lot of thought.'" | "umbrellas are not an exciting topic for her" | --
"Graham/Grahams" | "'Poor lost souls.'" | "she pities the Grahams" | --
"Doug/Dougs" | "'Yuck!'" | "she finds the wrinkled Dougs revolting" | --
"banana" or "golden banana" or "Golden Banana of Discord" | "'It's pretty, all right. You'd best get it to Eris as soon as you can.'" | "she thinks the Golden Banana is pretty, and should be delivered to Eris promptly" | --
"breast/breasts/tit/tits/hooter/hooters" | "'Ain't they something?'" | "she's (justifiably) proud of her breasts" | --
"Pluto/husband" | "'He's always travelling on business. A girl gets lonely, ya know?'" | "Pluto's travelling a lot and she feels neglected" | --
"Hades/Hell/Underworld/City/Unreal" or "Unreal City" | "'What the hell, it's home[26 as a reference].'" | "she is ambivalent about her residence" | --
"Charon/ferryman/skeleton" | "'Charon? Poor guy has arthritis something fierce.'" | "Charon suffers from arthritis" | --
"Sosostris/Madame/Auntie/Mame/Sybil/Fawlty" or "Madame Sosostris" or "Auntie Mame" or "Sybil Fawlty" | "'She's a mean drunk old lady and I don't know why she hates me so much.'" | "she doesn't know why Madame Sosostris dislikes her" | --
"Sweeny/Apeneck/redhead" or "red-haired man" or "Apeneck Sweeny" | "'He's a hard worker.'" | "the red-haired man works hard" | --
"Agamemnon" | "'Pretty harsh, what happened to him.'" | "she thinks Agamemnon was treated harshly" | --
"Tantalus" | "She rolls her eyes. 'Pardon my French, but what an asshole!'" | "she intensely dislikes Tantalus" | --
"Gate of Horn" or "Hornéd Gate" or "Horned Gate" or "Horn Gate" or "horn" | "'True dreams leave Hades through the hornéd gate. Sweeny ain't gonna let you by, though" | "the Gate of Horn is how true dreams get out into the world; Sweeny guards it" | --
"Gate of Ivory" or "Ivory Gate" or "ivory" | "'That gate's how false dreams get into the world; not a good idea to go there.'" | "false dreams go through the Gate of Ivory, and you shouldn't go through it" | --
"throne/thrones" or "iron throne" or "iron thrones" | "She shakes her head ruefully. 'They look nice, but they give you [italic type]terrible[roman type] [apostrophe]roids.'" | "the iron throne has given her hemorrhoids" | --
"Eris/Discordia/Jove/Jupiter/Virilis/Zeus" or "Jupiter Virilis" | "'I don't get up to Olympus much.'" | "she's not very tuned into the other gods' gossip" | --
"Syra" | "'Oh, even [italic type]I've[roman type] heard of her and her nose. I will enjoy meeting her.'" | "Syra's reputation precedes her" | --
"sausage" | "'Smells pretty pungent.'" | "she thinks the sausage smells pungent" | --
"cat" | "'Awwww!'" | "she thinks the kitten is cute" | --