# Stiffy Makane: Apocolocyntosis — 140 of 235

## One of the Bruces and Drunken Bastard

Release 1

- Home page
- Beginning
- Previous
- Next

Part Three - "East Bank of Stream"

The far_away_stream is a backdrop. It is in Canyon's Edge, East Side of Chasm, West Side of Chasm, Narrow Chasm, and Precarious Ledge. The description is "Far below, the silver thread of a stream winds through the canyon." Understand "stream", "silver", "thread", "silvery", "creek", "water", "fast", "fast-moving", "ravine", "defile", "chasm", and "canyon" as the far_away_stream. The printed name is "stream". The far_away_stream can be enterable. It is enterable.

Instead of entering the far_away_stream, try jumping into the far_away_stream.

Instead of diving into the far_away_stream, try jumping into the far_away_stream.

Instead of swimming around in the far_away_stream, try jumping into the far_away_stream.

Instead of jumping over the far_away_stream:

if the location is not Precarious ledge, instead say "The stream is much too wide to jump.";

try jumping over the scenery_western_bank.

Instead of jumping into the far_away_stream for the first time, say "You're aware that's suicide, right?"

Instead of jumping into the far_away_stream:

say "You leap into the stream and break yourself fatally on its rocks.";

end the story saying "You have jumped from a great height into a shallow stream".

This is the stream-warning rule:

say "The only way down would be to jump into the stream."

Instead of doing anything other than examining, entering, swimming around in, diving into, jumping over, or jumping into with the far_away_stream, say "The stream is too far away."

Instead of entering the far_away_stream, try jumping into the far_away_stream.

Canyon's Edge is a room. It is west of Jungle Slope. "The trail from the mountain pass ends here at the edge of a canyon. Far below you you can see a stream rushing from south to north through a narrow defile. The other edge of the chasm is perhaps fifty feet to the west, certainly too far to jump. A ridge rises across the stream to the west." Instead of going down in Canyon's Edge, consider the stream-warning rule. Instead of going west in Canyon's edge, consider the stream-warning rule.

East Side of Chasm is a room. It is south of Canyon's Edge. "A rickety footbridge[emdash]really, little more than flimsy-looking boards laid across twisted vines[emdash] spans the canyon to the west, swaying sickeningly in the breeze. Farther on across the stream, a ridge rises steeply from south to north, jungle covering most of its height, but with a talus slope ascending to sheer obsidian cliffs. A faint set of switchbacks can be seen climbing the slope to a gap in the cliffs. The ridge terminates in a knife-edge plummet far to the north. To the south, a path follows the canyon's edge, and thick jungle rises to your east." Instead of going up in East Side of Chasm, try going east. Instead of going east in East Side of Chasm, try entering the dense jungle. Instead of going down in East Side of Chasm, consider the stream-warning rule. Before going west in East Side of Chasm, say "Closing your eyes, you step gingerly onto the bridge. Thousands of tiny, heart-palpitating, shuffling steps later, your fingers are arthritic and sore from your death-grip on the handrail, but you step off onto the western bank of the chasm."

The footbridge is a door. It is west of East Side of Chasm. It is scenery. It is open. It is not openable. It is unlocked. It is not lockable. The description is "The footbridge spans the chasm to the [if the location is East Side of Chasm]west[otherwise]east[end if]. It sways alarmingly in the wind. It appears to be made up of three cables made from twisted vines: two of the ropes support a deck made of rotten-looking planks woven together with additional vines, and the third makes a sort of handrail. The bridge is perhaps a hundred feet long." Understand "bridge", "suspension", "rickety", "rocking", "swaying", "sickening", "twisting", and "alarming" as the footbridge. Instead of touching or rubbing the footbridge, say "The bridge rocks under your touch." Instead of tasting or smelling the footbridge, say "Vines. Wood. What did you expect?" Instead of attacking the footbridge, try attacking the scenery_ropes. Instead of cutting the footbridge, try cutting the scenery_ropes. Instead of burning the footbridge, try burning the scenery_ropes. Instead of attacking the footbridge with something, try attacking the scenery_ropes with the second noun. Check taking the footbridge: instead say "The footbridge is much too large to simply pick up."

Some scenery_ropes are a backdrop in East Side of Chasm. They are in West Side of Chasm. "The cables are made of twisted vines, and on further inspection actually seem sound and quite strong." The printed name is "ropes". Understand "twisted", "rope", "ropes", "cable", "cables", "vine", "sturdy", "strong", "vines", "three", and "two" as the scenery_ropes. Instead of touching or rubbing the scenery_ropes, say "The ropes are quite sturdy." Instead of tasting or smelling the scenery_ropes, try smelling the footbridge.

Instead of burning the scenery_ropes, say "You have no source of fire."

Instead of cutting the scenery_ropes:

if the rusty machete is held by the player, instead try attacking the scenery_ropes with the rusty machete;

say "Your best karate chop has no effect on the ropes."

Instead of attacking the scenery_ropes, try cutting the scenery_ropes.

Before attacking the scenery_ropes with something:

if the second noun is the rusty machete

begin;

say "You wind up and take a swing at one of the cables with the machete. It parts with a loud snap, and recoils directly into your face. Blinded, you stagger and topple over the edge into the chasm.";

end the story saying "You have been a victim of your own enthusiasm";

stop the action;

end if;

say "Saw as you might, [the second noun] just doesn't make an effective knife.";

stop the action.

Instead of taking the scenery_ropes, say "The ropes are much too big to take."

The scenery_deck is a backdrop in East Side of Chasm. It is in West Side of Chasm. "The deck of the bridge is made of wooden planks, which, on closer inspection, are less rotten than they at first appear." Instead of touching or rubbing the scenery_deck, say "The wood seems surprisingly sound." Instead of attacking the scenery_deck, try attacking the scenery_ropes. Instead of attacking the scenery_deck with something, try attacking the scenery_ropes with the second noun. Instead of burning the scenery_deck, try burning the scenery_ropes. Instead of cutting the scenery_deck, try cutting the scenery_ropes. Instead of tasting or smelling the scenery_deck, try smelling the footbridge. Understand "deck", "board", "plank", "planks", "boards", "flimsy", "flimsy-looking", "rotten", "sound", "wood", "wooden", and "rotting" as the scenery_deck. Instead of taking the scenery_deck, say "It's firmly secured by vines."

The scenery_breeze is a backdrop in East Side of Chasm. "A breeze comes up off the stream far below." The printed name is "breeze". Understand "wind", "breeze", and "gust" as the scenery_breeze. Instead of tasting the scenery_breeze, try smelling the scenery_breeze. Instead of smelling the scenery_breeze, say "It smells of fast-moving water." Instead of doing anything other than examining, smelling, or tasting the scenery_breeze, say "The breeze is insubstantial."

Waterfall Overlook is a room. It is south of East Side of Chasm. "A narrow path winds through dense jungle near a cliff edge. Here you can peer over the drop and see, just to the west, the stream tumbling down several cascades, in a waterfall some two hundred feet high. Beyond the stream rises a ridge. To the south, it looks like the stream becomes more or less level with the path." Instead of going east in Waterfall Overlook, try entering the dense jungle. Instead of going up in Waterfall Overlook, try going east. Instead of listening when the location is Waterfall Overlook, try listening to the scenery_waterfall.

The scenery_waterfall is scenery in Waterfall Overlook. The description is "The waterfall is about two hundred feet, top to bottom, in several cascades." The printed name is "waterfall". Instead of listening to the scenery_waterfall, say "The waterfall booms and roars." Instead of doing anything other than examining, listening, swimming around in, jumping into, diving into, jumping over, or entering with the scenery_waterfall, say "The waterfall is too far away." Understand "waterfall", "falls", "cascade", "cascades", "boom", "booming", "roar", "roaring" as the scenery_waterfall. The scenery_waterfall can be enterable. It is enterable. Instead of jumping over the scenery_waterfall, say "It's much too wide to jump." Instead of entering the scenery_waterfall for the first time, say "Trying to swim in the waterfall would be a quick death, at least." Instead of jumping into the scenery_waterfall, try entering the scenery_waterfall. Instead of swimming around in the scenery_waterfall, try entering the scenery_waterfall. Instead of diving into the scenery_waterfall, try entering the scenery_waterfall. Instead of entering the scenery_waterfall:

say "The crushing force of the water kills you before you can drown.";

end the story saying "You have been crushed by a waterfall".

Rocky Ford is a room. It is south of Waterfall Overlook. "The path widens somewhat as it descends to the stream, which here looks like it's little more than four or five feet deep, although fast-moving and full of sharp and slippery rocks. The land rises steeply on the other side of the creek. To the south the path vanishes in mucky marshland." Instead of swimming in Rocky Ford, try swimming around in the scenery_stream.

The scenery_marsh is scenery in Rocky Ford. The description is "South of here, the ground turns to a fetid soup of reeds and muck." Understand "reed","reeds","soft","marsh", "marshland", "muck", "mucky", "mud", "muddy", "quicksand", "swamp", "swampy", "bog", "boggy", and "marshy" as the scenery_marsh. The scenery_marsh can be enterable. It is enterable. Instead of entering the scenery_marsh for the first time, say "You hesitate. The ground seems awfully soft in that direction." Instead of entering the scenery_marsh:

say "You have gone less than twenty yards when the ground becomes liquid underneath you, and you are swallowed by a pit of quicksand. Several agonizing minutes later, you finally drown.";

end the story saying "You have succumbed to quicksand".

Before swimming around in when the location is Rocky Ford:

if the second noun is east, instead try swimming around in the scenery_stream.

The scenery_stream is scenery in Rocky Ford. The description is "The stream is about thirty feet wide and four or five feet deep here, you think, with a dangerously swift current. Jagged, slick rocks form the streambed, full of treacherous holes and hidden snares." Understand "stream", "creek", "swift", "current", "dangerous", "dangerously", "jagged", "slick", "fast", "fast-moving", "aerated", "water", "rock", "rocks", "treacherous", "hole", "holes", "hidden", "snare", and "snares" as the scenery_stream. The printed name is "stream". The scenery_stream can be enterable. It is enterable. Instead of jumping over the scenery_stream, say "It's too wide to jump". Instead of swimming around in the scenery_stream, try entering the scenery_stream. Instead of jumping into the scenery_stream, try entering the scenery_stream. Instead of tasting the scenery_stream, say "The water is clear, cold, and refreshing." Instead of smelling the scenery_stream, say "The stream smells like fast-moving, aerated water." Instead of taking the scenery_stream, say "You splash some water on yourself. It chills and refreshes you." Instead of listening to the scenery_stream, say "The creek splashes noisily, but you can hear the boom of a waterfall not far to the north." Instead of entering the scenery_stream:

say "You get about ten feet out in the stream before a rock shifts underfoot, dumping you into the current. Although you get your head above water and try to stand up and stop, the channel has become too deep, and, flailing wildly, you are carried inexorably over the waterfall.";

end the story saying "You have gone over the falls". Instead of diving into the scenery_stream, try jumping into the scenery_stream.

Instead of going east in Rocky Ford, try entering the dense jungle. Instead of going up in Rocky Ford, try going east. Instead of going down in Rocky Ford, try going west. Instead of going south in Rocky Ford, try entering the scenery_marsh. Instead of going west in Rocky Ford, try swimming around in the scenery_stream.

Narrow Chasm is a room. It is north of Canyon's Edge. Instead of going east in Narrow Chasm, try entering the dense jungle. Instead of going up in Narrow Chasm, try going west. Instead of going down in Narrow Chasm, consider the stream-warning rule. Instead of going north in Narrow Chasm, say "The descent to the north is impassable." The description is "The chasm narrows here, to a mere twenty feet or so across. Just above you, a precarious ledge juts out across the stream. It might be possible to jump from that ledge to the far bank. Dense jungle presses in on the east, and to the north the ground tumbles away in an unclimbable jumbled pile of rock."

Precarious Ledge is a room. It is west of Narrow Chasm. The description is "You are on a narrow perch of rock high above the stream. The western bank of the river is only about ten feet away, and at about the same height as your ledge. You might be able to make the leap." Instead of going west in Precarious Ledge, try jumping over the scenery_western_bank. Instead of going down in Precarious Ledge, try going east. Instead of going north in Precarious Ledge, try going south. Instead of going south in Precarious Ledge, consider the stream-warning rule.

The scenery_western_bank is scenery in Precarious Ledge. The description is "The western bank is made of crumbling clay, and is badly undercut. It looks quite unstable." Understand "west", "western", "bank", "crumbling", "clay", "undercut", "other", "side", and "unstable" as the scenery_western_bank. Instead of jumping over the far_away_stream when the location is Precarious Ledge, try jumping over the scenery_western_bank. Instead of jumping when the location is Precarious Ledge, try jumping over the scenery_western_bank. Instead of jumping over the scenery_western_bank:

say "You take a running leap and fling yourself at the western bank. You land on your belly, and grab at some vines. They pull out of the bank, bringing dirt with them. As you scrabble desperately for purchase, the rest of the overhanging bank collapses, and, with a despairing scream, you plummet onto the rocks far below.";

end the story saying "You have fallen to your doom".