# Stiffy Makane: Apocolocyntosis — 125 of 235

## One of the Bruces and Drunken Bastard

Release 1

- Home page
- Beginning
- Previous
- Next

Book Three - "The City"

Part One - "Hotel Metropole"

Chapter One - "Lobby"

Section One - "Furnishings"

Hotel Metropole is east from the Lake Harbor. "This is a shabby hotel lobby, with sad-looking potted palms flanking the stairwell. The tile is stained, chipped, and faded." [ Instead of going outside in Hotel Metropole, try going west. ] Lake Harbor is outside from Hotel Metropole.

The scenery_lobby is scenery in the Hotel Metropole. The description is "It's not clear whether the Metropole has seen better days, or whether it started out like this. It's a grim and seedy hotel: wilted palms framing a staircase, grubby ledger chained to a battered counter, cracked and stained tile." Understand "hotel", "lobby", and "metropole" as the scenery_lobby. The printed name is "lobby".

The hotel tile is scenery in the Hotel Metropole. The description is "Cheap, shabby tile, showing tired-looking dolphins half-heartedly leaping beside a barely-seaworthy boat." Understand "cheap", "shabby", "tired", "tired-looking", "looking", "dolphins", "half", "hearted", "half-hearted", "heartedly", "half-heartedly", "barely", "seaworthy", "barely-seaworthy", "boat", "ship", "unseaworthy", "wave", "ocean", "waves", "sea", "vessel", "stuck", "floor", "dirty", "grime", "grimy", "secretion", "secretions", "glue", "stained", "cracked", "chipped", and "faded" as the hotel tile. Instead of taking the hotel tile, say "It's stuck to the floor, presumably by some sort of glue, but also by the thick layer of dried dirt, grime, and secretions atop it." Instead of tasting the hotel tile, say "Ick." Instead of smelling the hotel tile, say "Fortunately, it doesn't actually smell."

The hotel counter is scenery in the Hotel Metropole. The description is "It's just a battered wooden counter with a big staple anchoring the chain of the guest ledger." Understand "battered", "wood", "staple", "big", "anchor", and "wooden" as the hotel counter.

Some potted palms are scenery in the Hotel Metropole. They are ambiguously plural. The description is "Spindly palm trees cling to life, of a sort." Understand "dirt", "pot", "palm", "heirloom", "heirlooms", "tree", "trees", "sad", "sad-looking", "plant", and "plants" as the potted palms. Instead of doing anything other than examining the potted palms, say "You get the feeling that one touch, and the palms would crumble to dust. And then you'd have to pay for them, and it seems likely that they're famililial heirlooms, quite possibly dating back to Egypt's glory millenia."

A stairwell is scenery in the Hotel Metropole. The stairwell can be enterable. It is enterable. The description is "A dingy, reeking stairwell leads up from the lobby to the guest rooms." Understand "stair", "southern", "south", "dingy", "urine", "piss", "cat", "socks", "reeking", "reek", and "stairs" as the stairwell. Instead of entering the stairwell, try going south. Instead of smelling or tasting the stairwell, say "Urine and old socks, mostly, with an aggressive note of cat piss in the bouquet." Instead of going up in Hotel Metropole, try going south.

Before going south in the Hotel Metropole:

if the clerk is not handled and the ledger is not handled

begin;

if the number of rows in the Table of Hotel Occurrences is greater than 1

begin;

choose a random row in the Table of Hotel Occurrences;

if the description entry is not "placeholder"

begin;

say "[description entry][paragraph break]";

blank out the whole row;

otherwise;

say "You wander around upstairs for a while, but nothing exciting happens. You return to the lobby.";

end if;

stop the action;

otherwise;

say "You wander around upstairs for a while, but nothing exciting happens. You return to the lobby.";

stop the action;

end if;

otherwise;

if Eugenides is boinked or Eugenides is unaroused

begin;

say "Room 14 is locked, and no one responds to your knock. You return to the lobby.";

stop the action;

end if;

end if.

Table of Hotel Occurrences

description
"placeholder"
"Wandering around the hotel at random, you stumble into someone's room, and discover a man, a woman, and an ostrich involved in either a religious ritual or something very dirty. Or both. They glare at you; as you leave you hear the bolt clicking into place. You return to the lobby."
"A naked woman runs from one room into the hall, giggling wildly. She spots you, shrieks, and ducks back into her room. You hear the scrape of a chair being pushed against the door. You return to the lobby."
"In a hall upstairs in the hotel, three drunken revellers stagger past you, their plumes of winy vomit barely missing you."
"Behind a closed door, you can hear a woman shouting, the unmistakable sound of leather slapping flesh, and a man groaning. You return to the lobby."
"Climbing the stairs into a grubby hallway, you try a door at random. Black-robed figures, standing around a recently-demised goat, glare at you, their long knives dripping blood. You retreat to the lobby."
"In one room, six men sit hunched intently around a table, rolling dice, as stacks of money are slid back and forth between the participants. They notice you watching. 'Do you [italic type]mind[roman type]?' asks one, as their door is slammed shut and bolted. You return to the lobby."