# Stiffy Makane: Apocolocyntosis — 188 of 235

## One of the Bruces and Drunken Bastard

Release 1

- Home page
- Beginning
- Previous
- Next

Part Thirteen - "The Circular Ruins"

Chapter One - "The Circular Ruins"

The Circular Ruins is north of the Northern_riverbank. The description is "You stand within the center of a circle of collapsing arches. A gate of ivory towers to your west, and a gate of horn to your east. To the south you can see the bank of the Styx, and to the north the land rises to an olive grove that's seen better days." Instead of going up in the Circular Ruins, try going north.

The scenery_grove is scenery in the Circular Ruins. The description is "Twisted, bare olive trees rise from a small hill." The printed name is "olive grove". Understand "tree", "trees", "olive", "olives", "twisted", and "bare" as the scenery_grove.

The Gate of Ivory is scenery in the Circular Ruins. The Gate of Ivory can be enterable. It is enterable. Instead of entering the Gate of Ivory, try going west. The description is "The Gate of Ivory is made from a pair of enormous elephant tusks, resting on their bases, their tips barely crossing some nine feet above the ground." Instead of searching the Gate of Ivory, say "Through the gate you can see a wooded landscape." Understand "elephant", "tusk", "tusks", "arch" and "archway" as the Gate of Ivory.

The Gate of Horn is scenery in the Circular Ruins. The Gate of Horn can be enterable. It is enterable. Instead of entering the Gate of Horn, try going east. Understand "elk", "antler", "antlers", "arch", "archway","hornéd", and "horned" as the Gate of Horn. "The Gate of Horn is constructed of hundreds of elk antlers, assembled into an arch about nine feet high." Instead of searching the Gate of Horn:

if Apeneck Sweeny is unboinked

begin;

say "You find it difficult to see around the man lounging in front of the archway.";

otherwise;

say "You can see bucolic green fields through the arch.";

end if.

Instead of going west in the Circular Ruins for the first time:

if Apeneck Sweeny is unboinked

begin;

say "'Ever read any Borges?' inquires [if Apeneck Sweeny is handled]Sweeny[otherwise]the red-haired man[end if]. 'Look at the room name. Now, what's the epigraph of that story? What's it about? I'm just sayin[apostrophe][11 as a footnote].'";

otherwise;

if the location of Madame Sosostris is the location

begin;

say "Madame Sosostris clears her throat. 'I don't think that's a very good idea, dear.'";

otherwise;

say "You hesitate as an uneasy chill passes through your body.";

end if;

end if.

Before going west from the Circular Ruins for the second time:

if Apeneck Sweeny is unboinked

begin;

say "'It's your funeral,' mutters [if Apeneck Sweeny is handled]Sweeny[otherwise]the red-haired man[end if][if the location of Madame Sosostris is the location]. Madame Sosostris shakes her head dolefully[end if].";

otherwise;

if the location of Madame Sosostris is the location, say "'Well, it certainly was nice knowing you, dear,' says Madame Sosostris.";

end if.

Instead of going west in the Circular Ruins:

say "You step into the gate. [If the location of Madame Sosostris is the Circular Ruins]Madame Sosostris tearfully waves her hanky at you. [end if]Blackness engulfs you.[paragraph break][paragraph break][paragraph break]";

follow the major-scene-change rule;

move the player to End_Of_Road.

Instead of going east in the Circular Ruins:

if Apeneck Sweeny is unboinked

begin;

say "Sweeny guards the hornéd gate[36 as a reference].";

otherwise;

if the Golden Banana of Discord is not held by the player

begin;

say "The thought crosses your mind that you'd better not leave without the Golden Banana.";

otherwise;

say "You take Madame Sosostris by the hand and step through the portal. There is a sudden jolt; you twitch and your heart flutters as if you had just awoken from the falling dream...";

move Madame Sosostris to Inside_the_Cavern;

follow the major-scene-change rule;

move the player to Inside_the_Cavern;

end if;

end if.