# Stiffy Makane: Apocolocyntosis — 134 of 235

## One of the Bruces and Drunken Bastard

Release 1

- Home page
- Beginning
- Previous
- Next

Volume Twelve - "Darkest Africa"

Jungly Africa is a region. Jungle Slope, Canyon's Edge, Narrow Chasm, East Side of Chasm, West Side of Chasm, Waterfall Overlook, Rocky Ford, Palm Grove, Melon Patch, Cane Field, and North Shore of the Lake are rooms in Jungly Africa.

African Lake is a region. The North End of the Lake and the Middle of the Lake are water_rooms in African Lake.

Up a Tree is a region. Halfway up the Banana Tree and Top of the Banana Tree are rooms in Up a Tree.

Instead of dropping something (called S) in African Lake:

if S is the Golden Banana, instead say "It would surely be lost forever. You will not part with it now.";

if S is the stiffycock, instead say "It really isn't hindering your swimming. Besides, you can't.";

if S is a jungle yummy or S is the clean piece of papyrus or S is the jagged papyrus or S is the ragged papyrus

begin;

say "[The S], fortunately, is buoyant.";

move S to the location;

otherwise;

say "[The S] vanishes beneath the waters with a forlorn 'bloop' sound.";

remove S from play;

end if.

Instead of dropping something (called S) in Up a Tree:

if S is the Golden Banana, instead say "It would surely be lost forever. You will not part with it now.";

if S is the stiffycock, instead say "You can't. It's quite firmly attached.";

say "[The S] vanishes from sight, tumbling into the jungle beneath you.";

remove S from play.

Darkest Africa is a region. High on a Hillside, Precarious Ledge, Mountain Pass, Spit of Land, Rocky Streambed, and Plateau are rooms in Darkest Africa. Jungly Africa is in Darkest Africa. African Lake is in Darkest Africa. Up a Tree is in Darkest Africa.

Dense Jungle is a backdrop in Jungly Africa. The description is "The jungle is dense, deep, and dark. It's almost impenetrable in the absence of a preexisting path. Trees, thickets, and undergrowth form an almost-solid mass." Instead of touching or rubbing the Dense Jungle, say "You reach out and poke a bush at random." Instead of tasting or sucking the Dense Jungle, say "The leaf you select tastes just like a leaf." Instead of taking the Dense Jungle, say "As well carry off the Tiber in a teaspoon." Understand "impenetrable", "briar", "briars", "underbrush", "thick", "tree", "trees", "vines", "vine", "thicket", "vast", "deep", "dark", "forest", "woods", "trackless", "undergrowth", "bush", "bushes", "solid", "almost-solid", and "almost-impenetrable" as Dense Jungle. Dense Jungle can be enterable. It is enterable. Does the player mean doing something with the Dense Jungle: it is unlikely.

Instead of fucking the Dense Jungle:

if the stiffycock is not visible, instead say "You are not undressed for the occasion.";

say "In this respect, the jungle actually [italic type]is[roman type] impenetrable."

Instead of entering the Dense Jungle for the first time:

say "The jungle is vast and trackless. You pause, wondering if it's really a good idea to go crashing through it.";

Instead of entering the Dense Jungle:

choose a random row in the Table of Jungle Demises;

say "[narrative entry].";

now JDM is the death-message entry;

end the story saying "[JDM]".

Table of Jungle Demises

death-message | narrative
"You have fallen to your death" | "You soon lose the trail in the insanely thick underbrush. Struggling and forcing your way through thickets, you finally shove through a particularly vicious briar patch into open air, and plummet several hundred feet to a painful, but mercifully quick, demise"
"You have been eaten by beasts" | "Within minutes of pushing into the jungle you are hopelessly lost. Shoving your way through briars, you stagger aimlessly for hours. Eventually, night falls. It's unclear whether your assailants are grues or some other kind of beasts, but in any event, their teeth are sharp enough"
"You have been poisoned by a viper" | "Struggling through the bush, you reach out to steady yourself on a convenient vine. Alas, it is no vine, but a viper, and takes a dim view of your groping"
"You have been brained by a chimpanzee" | "As you push through the forest, you feel eyes watching you, but try as you might, you can't see anything. The farther you go, the deeper the woods get, and you think you begin to see black, hairy shapes swinging through the branches at the corners of your vision. Finally you pause exhausted by a large tree. There is a terrible hooting, and something drops from the canopy in front of you. Your last impression is of black hair, long yellow teeth, and a long arm swinging a thighbone into your skull"

Dark Africa is a region. Hidden Valley is a room in Dark Africa. Darkest Africa is in Dark Africa.

African_sky_scenery is sky_scenery in Dark Africa. The description is "A bright yellow sun beats down from an azure sky. In the distance you can see huge, puffy thunderclouds." Understand "sky", "blue", "azure", "sun", "yellow", "bright", "huge", "puffy", "cloud", "clouds", "thundercloud", and "thunderclouds" as the African_sky_scenery. The printed name is "sky".

Doctor Mentula I Presume is a recurring scene. Doctor Mentula I Presume begins when the location is in Dark Africa. Doctor Mentula I Presume ends when the location is not in Dark Africa.

Every turn during Doctor Mentula I Presume:

if the location is the Hidden Valley for the first time

begin;

choose a row with a character of "Hippopotamus" in the Table of Fictional Cast Members;

now the met entry is true;

end if;

if the location is the Middle Of The Lake for the first time

begin;

choose a row with a character of "Lake Guardian" in the Table of Fictional Cast Members;

now the met entry is true;

end if;

if the blue hippo is in the location

begin;

if the blue hippo's mouth is closed

begin;

say "The blue hippo yawns hugely, displaying a charmingly-decorated interior.";

now the blue hippo's mouth is open;

move the hippo_scenery2 to the location;

otherwise;

say "With a snap, the blue hippo shuts its jaws.";

now the blue hippo's mouth is closed;

remove the hippo_scenery2 from play;

end if;

end if;

[ if you drop the coconut, muskmelon, or cane, and leave, something eats it...but a new one grows ]

let L be the location;

repeat through the Table of Treats

begin;

let T be the thingy entry;

let H be the home entry;

let P be the holding pen entry;

let N be the noise entry;

let M be the location of T;

if M is not L and M is not H and M is not the Plateau

begin;

repeat with the way running through directions

begin;

let Q be the room the way from L;

if M is Q and M is a room, say "You hear a [N] chewing noise from [the way].";

end repeat;

now T is not handled;

move T to P;

end if;

end repeat;

if the banana clock is greater than zero, now the banana clock is one plus the banana clock;

if the froghemoth clock is greater than zero, now the froghemoth clock is one plus the froghemoth clock;

if the baboon clock is greater than zero, now the baboon clock is one plus the baboon clock;

if the nudity clock is greater than zero, now the nudity clock is one plus the nudity clock;

if the stiffycock is visible and the baboons are unboinked and the nudity clock is 0

begin;

if the location is the Plateau or the location is Halfway Up the Banana Tree or the location is Top of the Banana Tree

begin;

if the baboon clock is greater than zero

begin;

say "As you disrobe, the baboons cease their petty squabbles. [run paragraph on]";

now the baboon clock is zero;

remove the baboon disputation item from play;

end if;

now the baboons are boinked;

now the nudity clock is 1;

end if;

end if;

if the froghemoth clock is greater than 50

begin;

now the froghemoth clock is zero;

move the lake guardian to the North End of the Lake;

if the location is the North End of the Lake, say "With a splash, the horrible frog-thing bobs to the surface of the water, and rests there regarding you with its awful red eyes.";

end if;

if the baboon clock is greater than zero

begin;

if the baboon clock is five

begin;

now the baboon clock is zero;

remove the baboon disputation item from play;

if the location is the Plateau or the location is Halfway up the Banana Tree or the location is Top of the Banana Tree

begin;

say "One of the baboons manages to wrest control of [the baboon disputation item] long enough to devour it. With their squabble finished, they again turn to regard you with sullen hostility.";

end if;

end if;

if the location is the Plateau or the location is Halfway Up the Banana Tree or the location is Top of the Banana Tree

begin;

if the baboon clock is one, say "A big male baboon snatches [the baboon disputation item] and then immediately drops it as a smaller female bites him in the groin.";

if the baboon clock is two, say "A knot of baboons tumble about the plateau, trying to sieze control of [the baboon disputation item].";

if the baboon clock is three, say "One of the baboons tries to split another's skull with [if the baboon disputation item is not the muskmelon][the baboon disputation item][otherwise]a handy rock[end if], but misses.";

if the baboon clock is four, say "A general fracas over [the baboon disputation item] rages, with no clear frontrunner.";

end if;

end if;

if the banana clock is greater than one

begin;

if the banana clock is two

begin;

say "The blue dot nears the apex of its rise. You're fairly sure it's the blue hippopotamus, soaring through the air.[paragraph break]";

remove the scenery_hippo_dot from play;

move the scenery_hippo_far to the location;

really have the parser notice the scenery_hippo_far;

end if;

if the banana clock is three

begin;

say "The hippo[emdash]for such it is[emdash]begins its descent. A shadow passes across the sun. Glancing up, you see the Mweru bird, stooping in a power dive, aiming for the hippopotamus.[paragraph break]";

move the scenery_mweru_stooping to the location;

end if;

if the banana clock is four

begin;

say "The hippopotamus falls towards you, its mouth agape. It's going to pass just below the tree in a matter of seconds.[paragraph break]";

remove the scenery_hippo_far from play;

move the scenery_hippo_near to the location;

really have the parser notice the scenery_hippo_near;

end if;

if the banana clock is five

begin;

say "The hippopotamus sails some thirty feet beneath the tree, rolling its eyes despairingly at you as it passes. The Mweru bird passes just overhead, and you have to grab the tree to avoid being buffeted off by the wind from its wings. A couple hundred feet above the jungle canopy, it grabs the hippopotamus, and, beating its enormous wings, pulls out of the dive and flaps northwards, the hapless hippo clutched in its talons.[paragraph break]";

remove the scenery_hippo_near from play;

remove the scenery_mweru_stooping from play;

end if;

end if;

if the nudity clock is greater than zero

begin;

if the nudity clock is one, say "The baboons shriek and gibber, gesticulating wildly at your bared buttocks, baring their yellow fangs, and shaking their fists.[paragraph break]";

if the nudity clock is two, say "The baboons shriek and howl at you as they mass at the base of the tree.[paragraph break]";

if the nudity clock is three

begin;

say "The baboons scream in rage as they grimly ascend the tree.[paragraph break]";

move the baboons to Halfway Up the Banana Tree;

end if;

if the nudity clock is four, say "The baboons howl imprecations. One particularly brave one begins to inch up the tree towards you.[paragraph break]";

if the nudity clock is five

begin;

say "The baboons swarm up to the top of the tree, screeching and hooting.[paragraph break]";

move the baboons to Top of the Banana Tree;

end if;

end if;

if the baboons are in the location

begin;

if the stiffycock is visible or the baboons are boinked

begin;

if the location is the plateau

begin;

say "The baboons are enraged at [if the stiffycock is visible] seeing[otherwise] having seen[end if] your naked buttocks, and [if the baboon clock is greater than zero]drop their squabble over [the baboon disputation item] in order to [end if]fly into a starkly insensate rage. They swarm over you, beating you mercilessly, until your ass-cheeks are as red and blue as theirs. Then, hooting maniacally, they proceed to repeatedly sodomize you, and while they do, they begin tearing at and devouring your still-living flesh.";

end the story saying "You have been beaten, raped, murdered, and eaten by baboons";

stop the action;

end if;

if the location is Halfway Up the Banana Tree

begin;

say "The snarling baboons grab you and rend you limb from limb, showering your blood and entrails down into the endless void below.";

end the story saying "You have been dismembered by baboons";

stop the action;

end if;

if the location is the Top of the Banana Tree

begin;

say "The lead baboon scampers up the trunk to you. It grins horribly, and, slapping at your [if no garment is worn by the player]exposed [end if]buttocks, effortlessly launches you into the yawning void beneath.";

end the story saying "You have been cast to your death by a baboon";

stop the action;

end if;

end if;

end if.

Table of Treats

thingy | home | holding pen | noise
coconut | Palm Grove | Palm Grove | "dry crunching"
muskmelon | Melon Patch | Melon Patch | "wet splattering"
sugar cane | Cane Field | Limbo | "nasty splintering"

This is the jungle encumbrance rule:

let T be 0;

let S be 1;

let E be 0;

let I be Brandon Van Every;

If the player has the toga, now T is 1;

repeat with P running through things enclosed by the player

begin;

if P is not worn

begin;

if P is not the stiffycock and P is not the rusty machete and P is not the toga

begin;

if P is not a jungle yummy and T is 0

begin;

now E is E plus one;

now I is P;

end if;

if P is a jungle yummy

begin;

now E is E plus one;

now I is P;

end if;

end if;

end if;

end repeat;

if E > 1

begin;

say "There's a bit of a problem with that plan: you don't have enough hands. [run paragraph on]";

if anything is worn by the player, say "Anything you're wearing presents no problem. [run paragraph on]";

if T is 1, say "You can carry small items [if the toga is worn]in the folds of your[otherwise]twisted up in the[end if] toga[if the toga is not worn], which you can wrap around your arm[end if]. [run paragraph on]";

if the player has the rusty machete, say "You can carry the machete between your teeth like a pirate. [run paragraph on]";

say "However, about the time you get to [the I], you no longer have a hand free for [encumbered action].";

rule fails;

otherwise;

rule succeeds;

end if.

Test to-shrine with "test to-shipboard / test sb1 / test sb2 /test sb3 / test sbwhale".

Test africa1 with "w/w/w/w/s/w/w/get machete/w/n/get melon".

Test africa2 with "cut melon with machete/fuck melon/s/s/cut cane/get cane/n/w/n/n/give cane".

Test africa3 with "s/s/e/get coconut/w/n/n/n/e/wear toga/n/remove beard/remove tallis/remove signet ring/give coconut/e/e".

Test africa4 with "remove toga/take banana/z/z/jump".

Test africa with "test africa1/test africa2/test africa3/test africa4".

Test min-africa with "w/w/w/w/s/w/w/get machete/w/s/cut cane/get cane/n/w/n/n/give cane/test africa3/test africa4".