# Stiffy Makane: Apocolocyntosis — 17 of 235

## One of the Bruces and Drunken Bastard

Release 1

- Home page
- Beginning
- Previous
- Next

Chapter Three - "New Commands"

Understand the command "poncy" as something new. Understand "poncy" as setting_poncy. Understand "poncy on" as setting_poncy. Understand "poncy off" as unsetting_poncy. Understand "unponcy" as unsetting_poncy.

Setting_poncy is an action out of world applying to nothing. Report setting_poncy:

Now the current ponciness is poncy;

say "Stiffy Makane: Apocolocyntosis is now in its 'unbearably poncy' mode, which has a distressing tendency to lard even the most apparently innocent sentences [6 as a footnote] with irrelevant and tweedy footnotes, as well as suggesting possibly-perilous courses of hermeneutic adventure."

Unsetting_poncy is an action out of world applying to nothing. Report unsetting_poncy:

Now the current ponciness is philistinic;

Say "Stiffy Makane: Apocolocyntosis now displays merely quotidian ponciness."

Understand the command "bibliography" as something new. Understand "bibliography" as setting_bibliography. Understand "bibliography on" as setting_bibliography. Understand "bibliography off" as unsetting_bibliography.

Setting_bibliography is an action out of world applying to nothing. Report setting_bibliography:

Now the current referentiality is referential;

say "Stiffy Makane: Apocolocyntosis will now display intertextual references."

Unsetting_bibliography is an action out of world applying to nothing. Report unsetting_bibliography:

Now the current referentiality is mum;

Say "Stiffy Makane: Apocolocyntosis now embraces unattributed plagiarism."

Understand the command "feed" as something new. Understand "feed [something preferably held] to [something]" as feeding it to. Understand "feed [something] [something preferably held]" as feeding it to (with nouns reversed).

Feeding it to is an action applying to two things.

Carry out feeding it to:

if the second noun is not a person, instead try inserting the noun into the second noun;

if the second noun is the player, instead try eating the noun;

instead try giving the noun to the second noun.

Understand "arise" as arising. Understand "rise" as arising.

Arising is an action applying to nothing.

Report arising:

if the player is not the pumpkin

begin;

say "That's not a verb I recognize.";

stop the action;

otherwise;

if the player is not warned_about

begin;

say "Can't do that...yet[65 as a reference]!";

stop the action;

otherwise;

if the player is boinked

begin;

say "You have missed your opportunity.";

stop the action;

otherwise;

say "Majestically, you rise from the Van Pelt pumpkin patch, lambent with a hellfire-orange glow. Your gruesome visage fills[emdash]or so it seems to your terrified worshippers[emdash]half the sky, and they prostrate themselves before you, grovelling in the vines. Your shell splits horribly in a toothy grin, your razor-sharp fangs dripping venom. Your two eye sockets rip open, revealing the burning coals of hatred within. A deep, shrieking, ululating cackle erupts from somewhere within your unspeakable vegetal bowels, as, at long last, the milennia-old curse melts from you, and your ability to act suddenly returns. You wheel in the sky, glaring towards the horizon, as your thoughts turn to Olympus....and revenge.";

end the story finally saying "APOCOLOCYNTOSIS";

end if;

end if;

end if.

Understand "credits" as rolling-the-credits.

Rolling-the-credits is an action applying to nothing.

Report rolling-the-credits:

say "[credits]";

To say credits:

say "[italic type]Mentula Macanus: Apocolocyntosis[roman type] would not have been possible without the help of my playtesters. The first wave:[paragraph break]";

say "Marnie Parker, Robb Sherwin, Gin Rosenkranz, Amy Horton, Tracy Jo Barnwell, Andrew Plotkin, Tomasz Pudlo, and S. John Ross.[paragraph break]";

say "The second wave:[paragraph break]";

say "Jonathan Goodwin, Martin McGreal, Mark Oates, and Jason Warchol.";

say "[paragraph break]Enormous thanks are due to Amy Horton, my long-suffering wife, who has put up with a lot in the course of this game's development.[paragraph break]";

say "[italic type]In Memoriam[roman type][line break]";

say "Gin Rosenkranz[line break]";

say "Vinnie[line break]".

This is the fancy rolling the credits rule:

say "[credits]";

To say walkthrough:

say "jump. z. z. z. z. n. remove toga. fuck caesar. wear toga. n. get bag. s. s. e. e. e. give bag. give coin. w. n. give mask. s. w. w. w. w. blow nose. e. e. s. s. remove toga. fuck apple. e. n. remove toga. ask cocky about ring. n. s. ask festus about ring. n. z. n. d. e. n. w. w. get key. e. e. e. s. s. w. w. w. unlock grate with key. n. ask glub about ring. s. w. wear toga. u. e. e. n. n. n. n. put token in toilet. g. get ring. wear ring. s. s. s. s. w. w. ask palinurus about carthage. d. n. remove toga. fuck archie. wear toga. s. e. ask palinurus about carthage. d. w. s. remove toga. sit on table. show cock to doctor. get up. wear toga. n. e . n. n. e. e. ask madame about fortune. ask madame about secret. w. x gate. touch raven. touch vulture. touch crab. touch worm. n. search tombs. get weed. s. s. s. w. s. give weed. remove toga. sit on table. show cock to doctor. e. e. ask palinurus about judaea. d. e. n. s. remove toga. fuck rachel. wear toga. get coin. get mezuzah. n. e. give coin. w. w. s. s. buy disguise. get disguise. n. n. w. wear beard. wear tallis. ask palinurus about syracuse. remove toga. z. z. z. z. z. z. z. z. z. z. w. w. w. w. s. w. w. get machete. w. s. cut cane. get cane. n. w. n. n. give cane. s. s. e. get coconut. w. n. n. n. e. wear toga. n. remove beard. remove tallis. remove signet ring. give coconut. e. e. remove toga. take banana. z. z. jump. z. z. z. z. z. z. z. z. z. z. ask palinurus about jaffa. d. e. s. put banana on block. get banana. n. w. w. ask palinurus about syracuse. z. z. z. z. z. z. z. z. z. z. z. z. z. z. z. z. z. z. z. z. push oar. pull oar. push oar. pull oar. push oar. pull oar. push oar. pull oar. push oar. pull oar. pull oar. push oar. pull oar. push oar. pull oar. jump. z. z. z. z. take stiffy. put stiffy on board. fuck argus. put stiffy on hades. n. n. w. x old man. taste sausage. e. show sausage to dog. s. w. e. get umbrella. n. e. get bone. w. n. w. give umbrella. e. n. give bone. enter skiff. w. give wine. get vinegar. e. n. n. pour vinegar on tree. get olive. s. s. enter skiff. s. s. e. n. give olive. s. w. n. n. enter skiff. get wineskin. n. give wineskin to sweeny. e. e. e. s. get chestnuts. n. e. get duckweed. w. n. e. e. s. ask chef about lunch. get call. e. s. remove toga. remove tunic. fuck maid. ask maid about key. get key. n. unlock door with key. open door. e. e. search moonmilk. eat moonmilk. get wine. w. w. w. give wine to chef. give chestnuts to chef. n. w. w. blow call. ask duck about curse. give duckweed to anas. e. e. s. e. s. w. w. ask palinurus about thessalonica. d. w. get cloak. wear it. w. get blade. cut tree. get stick. w. n. n. w. n. e. give banana to eris. w. w. ask anas about banana. e. n. ask caesar about banana. wear glasses. n. fuck argus with banana. z. z. z. z. z. z. z. z. z. z. z. z. z. z. z. z. z. z. z. z. z. z. z. z. z. z. z. z. z. z. z. z. z. z. z. z. z. arise."

[ 421 commands; close to minimal, if not exactly minimal; contains at least three extraneous moves to open the cemetery gates. ]

Spoiled walkthrough is a number that varies. Spoiled walkthrough is 0.

Understand "walkthrough" as requesting the walkthrough.

Requesting the walkthrough is an action out of world applying to nothing.

Carry out requesting the walkthrough:

if spoiled walkthrough is 0

begin;

now spoiled walkthrough is 1;

say "Are you sure you want to do that? Repeat the command if you really want to spoil the game with the walkthrough.";

otherwise;

say "Here is the minimal walkthrough for [italic type]Mentula Macanus: Apocolocyntosis[roman type]:[paragraph break]";

say "[walkthrough]";

end if.

Understand "leap" as jumping.

Understand the command "dive" as something new.

Understand "dive" as diving. Understand "dive into [something]" as diving into. Understand "dive in [something]" as diving into.

Understand "jump into [something]" as jumping into. Understand "jump in [something]" as jumping into.

Understand "leap into [something]" as jumping into. Understand "leap in [something]" as jumping into.

Understand "jump over [something]" as jumping over. Understand "jump [something]" as jumping over.

Understand "leap over [something]" as jumping over. Understand "leap [something]" as jumping over.

Understand "join [something] to [something]" as putting it on. Understand "join [something] with [something]" as putting it on.

Understand "reach into [something]" as searching.

Understand "put hand in/into [something]" as searching.

Check searching a person:

if no garment is worn by the noun

begin;

say "It seems unlikely that [the noun] wants to be frisked.";

otherwise;

let G be a random garment worn by the noun;

say "Although there could be something hidden under [the G], it is unlikely that [the noun] wants to be frisked.";

end if;

stop the action.

Understand "put [something preferably held] on" as wearing.

Exiting something is an action applying to one thing.

Understand "exit [something]" as exiting something. Understand "get out of [something]" as exiting something.

Carry out exiting something:

if the noun contains the player, instead try exiting;

say "You don't seem to be in [the noun], so exiting it makes no sense."

Understand the command "earn" as something new. Understand "earn [something]" as earning.

Earning is an action applying to one thing. Report earning:

say "You will have to be more specific about how you want to earn [the noun]."

Diving is an action applying to nothing. Report diving:

say "Dive into what, exactly?"

Diving into is an action applying to one thing. Report diving into:

say "It is not clear how you would dive into [the noun]."

Jumping into is an action applying to one thing. Report jumping into:

say "It is not clear how you would jump into [the noun]."

Jumping over is an action applying to one thing. Report jumping over:

if the noun is not a direction, instead say "It is not clear how you would jump over [the noun].";

if the location is a water_room, instead say "A porpoise you are not.";

say "In general, if you can't walk [noun], you can't jump there either, and if you can walk there, then jumping there makes you look like an idiot."

Understand the command "undress" as something new.

Understand the command "disrobe" as something new.

Understand "undress" as stripping_down. Understand "disrobe" as stripping_down.

Understand "undress for the occasion" as stripping_down.

Stripping_down is an action applying to nothing. Carry out stripping_down:

If no garment is worn by the player, instead say "You are already unclothed.";

repeat with G running through the garments worn by the player

begin;

try taking off G;

if G is worn, stop the action;

end repeat.

Understand "undress [someone]" as stripping_off. Understand "disrobe [someone]" as stripping_off.

Stripping_off is an action applying to one thing. Carry out stripping_off:

if no garment is worn by the noun, instead say "[The noun] is not wearing anything to begin with.";

repeat with G running through the garments worn by the noun

begin;

try taking G;

if G is worn by the noun, stop the action;

end repeat.

Understand "consider [something]" as examining. [1]

Understand "munch [something]" as tasting. [2]

Understand "dress" as wearing_stuff.

Wearing_stuff is an action applying to nothing. Carry out wearing_stuff:

If no garment is held by the player, instead say "You aren't carrying any garments to wear.";

repeat with G running through the garments held by the player

begin;

try wearing G;

stop the action;

end repeat.

After wearing something:

if the noun is a garment and the noun is filthy

begin;

say "[if the player is filthy]You are already filthy, so putting on [the noun] doesn't get you any dirtier, anyway[otherwise]As [the noun] is filthy, so too now are you[end if].";

now the player is filthy;

end if;

if the player is filthy and the noun is a garment and the noun is not filthy

begin;

say "As you put on [the noun], you get it thoroughly filthy.";

now the noun is filthy;

end if;

if the noun is a garment and the player is Stiffy Makane

begin;

remove the stiffycock from play;

remove the greenish pus from play;

end if;

continue the action.

After taking off something:

if no garment is worn by the player and the player is Stiffy Makane, move the stiffycock to the player;

if the stiffycock is diseased, now the greenish pus is part of Stiffy Makane;

continue the action.

Understand the command "kiss" as something new.

Understand "kiss [something]" as kissing. Understand "osculate [something]" as kissing.

Check kissing the player: say "Pointless, and not much fun."

Check kissing a person: say "I don't suppose [the noun] would care for that."

Check kissing: say "You osculate [the noun], to no real effect."

Understand the command "flirt" as something new.

understand "flirt with [something visible]" as telling it about.

Understand the command "talk" as something new.

Understand "talk [something visible]" as telling it about.

Understand "talk to [something visible]" as telling it about.

Understand the command "ask [something visible] for [text]" as something new.

Understand "ask [something visible] for [text]" as telling it about.

Check telling:

say "All conversations in [italic type]Mentula Macanus: Apocolocyntosis[roman type] are of the form ASK [bracket]SOMEONE[close bracket] ABOUT ";

say "[bracket]SOMETHING[close bracket].";

stop the action.

Check answering it that:

say "All conversations in [italic type]Mentula Macanus: Apocolocyntosis[roman type] are of the form ASK [bracket]SOMEONE[close bracket] ABOUT ";

say "[bracket]SOMETHING[close bracket].";

stop the action.

Understand "# [text]" as a mistake ("Noted.").

Understand "attack [something] with [something preferably held]" as attacking it with.

Understand "stab [something] with [something preferably held]" as attacking it with.

Understand "cut [something] with [something preferably held]" as attacking it with.

Understand "stab [something]" as cutting.

Understand "slap [something]" as attacking.

Understand "defeat [something]" as attacking.

Understand "defeat [something] in combat" as attacking.

Understand "swim" as swimming.

Understand "swim [something]" as swimming around in.

Understand "swim in [something]" as swimming around in.

Swimming is an action applying to nothing.

Carry out swimming:

if the location is a water_room

begin;

say "You splash around gaily for a while.";

otherwise;

say "Swim in what, exactly?";

end if;

Swimming around in is an action applying to one visible thing.

Carry out swimming around in:

if the noun is not a direction, instead say "You can't swim in [the noun].";

if the location is not a water_room, instead try swimming;

try going the noun.

Filling is an action applying to one thing. Report filling: say "You can't fill [the noun]."

Understand "fill [something]" as filling.

Digging is an action applying to one thing.

Report digging: if the noun is a person

begin;

say "I don't suppose [the noun] would care for that.";

otherwise;

if the noun is enclosed by the player

begin;

say "Since you are holding [the noun], you find this topologically confusing, and give up.";

otherwise;

say "You find [the noun] too hard to dig in.";

end if;

end if.

Understand "dig [something]" as digging. Understand "dig in [something]" as digging.

Understand "pet [something]" as rubbing. Understand "pat [something]" as rubbing. Understand "fondle [something]" as rubbing. Understand "finger [something]" as rubbing. Understand "tickle [something]" as rubbing.

Knocking is an action applying to one thing. Report knocking:

If the noun is a person, instead try attacking the noun;

if the noun is a door, instead say "You knock on [the noun]. There is no reply.";

say "You rap your knuckles smartly against [the noun], to no real effect."

Understand "knock [something]" as knocking. Understand "knock on [something]" as knocking.

Understand the command "board" as something new.

Understand "board [something]" as entering.

Understand the command "blow" as something new.

Understand "blow [something]" as blowing. Understand "give nose job to [someone]" as blowing. Understand "give nosejob to [someone]" as blowing. Understand "give [someone] nose job" as blowing. Understand "give [someone] nosejob" as blowing. Understand "give a nose job to [someone]" as blowing. Understand "give a nosejob to [someone]" as blowing. Understand "give [someone] a nose job" as blowing. Understand "give [someone] a nosejob" as blowing.

Blowing is an action applying to one thing. Report blowing: say "You puff some air towards [the noun]."

Sanity-check eating:

if the noun is a person, instead try sucking the noun.

Sucking is an action applying to one thing. Report sucking: say "You can't seem to get [the noun] into your mouth."

Understand "suck [something]" as sucking. Understand "give head to [something]" as sucking. Understand "lick [something]" as sucking. Understand "eat [someone]" as sucking. Understand "fellate [something]" as sucking. Understand "irrumate [something]" as sucking.

Understand "bite [something]" as tasting.

Understand "roll [something]" as pushing.

Understand the command "shit" as something new.

Understand "shit" as shitting. Understand "crap" as shitting. Understand "poop" as shitting. Understand "poo" as shitting. Understand "defecate" as shitting.

Shitting is an action applying to nothing. Report shitting:

say "You were raised better than that."

This is the gotta-poop rule:

let X be the turn count minus the last_shitting_turn;

if X is less than 50 and the last_shitting_turn is greater than 0

begin;

say "Your bowels are already empty.";

rule fails;

otherwise;

rule succeeds;

end if.

Understand the command "shit on" as something new. Understand "shit on [something]" as shitting on. Understand "crap on [something]" as shitting on. Understand "poop on [something]" as shitting on. Understand "poo on [something]" as shitting on. Understand "defecate on [something]" as shitting on.

Shitting on is an action applying to one thing. Report shitting on:

instead try shitting.

Understand the command "piss" as something new.

Understand "piss" as pissing. Understand "pee" as pissing. Understand "whiz" as pissing. Understand "urinate" as pissing. Understand "tinkle" as pissing [3].

Pissing is an action applying to nothing. Report pissing:

say "[if the stiffycock is diseased]OW! OW! OW! You abandon the idea.[otherwise]There is no need to mark your territory.[end if]".

Understand the command "piss on" as something new.

Understand "piss on [something]" as pissing on. Understand "pee on [something]" as pissing on. Understand "whiz on [something]" as pissing on. Understand "urinate on [something]" as pissing on. Understand "tinkle on [something]" as pissing on.

Pissing on is an action applying to one thing. Report pissing on:

instead try pissing.

This is the gotta-pee rule:

let X be the turn count minus the last_pissing_turn;

if X is less than 50 and the last_pissing_turn is greater than 0

begin;

say "Your bladder is already empty.";

rule fails;

otherwise;

rule succeeds;

end if.

A person can be enterable. A person is enterable. Check entering a person: instead try fucking the noun.

Check an actor taking (this is the taking-people-is-fucking rule):

if the noun is a person, instead try fucking the noun.

Check an actor getting off (this is the fancy-getting-off rule):

if the actor is on the noun, continue the action;

if the actor is carried by the noun, continue the action;

if the noun is a person, instead try wanking off the noun.

Check an actor exiting (this is the fancy-cannot-exit rule):

let the local room be the location of the actor;

if the container exited from is the local room

begin;

if the player's command matches "get off" and the actor is the player, instead try wanking;

stop the action with library message exiting action number 1 for the actor;

end if.

The taking-people-is-fucking rule is listed instead of the can't take other people rule in the check taking rulebook.

The can't take yourself rule is not listed in the check taking rulebook.

The fancy-getting-off rule is listed instead of the can't get off things rule in the check getting off rulebook.

The fancy-cannot-exit rule is listed instead of the can't exit when not inside anything rule in the check exiting rulebook.

Fucking is an action applying to one thing. Report fucking:

if the player is Stiffy Makane

begin;

if the stiffycock is not held by the player

begin;

say "You aren't undressed for the occasion.";

otherwise;

say "You aren't quite sure where to begin.";

end if;

otherwise;

say "That would be indecorous.";

end if.

Understand the command "fuck" as something new.

Understand the command "screw" as something new.

Understand "fuck [something]" as fucking. Understand "score with [something]" as fucking. Understand "screw [something]" as fucking. Understand "bone [something]" as fucking. Understand "bang [something]" as fucking. [ Understand "take [someone]" as fucking. ]Understand "do [something]" as fucking. Understand "love [something]" as fucking. Understand "bone [something]" as fucking. Understand "rape [something]" as fucking. Understand "ravish [something]" as fucking. Understand "penetrate [something]" as fucking. Understand "poke [something]" as fucking. Understand "hump [something]" as fucking. Understand "dick [something]" as fucking. Understand "mount [something]" as fucking. Understand "eff [something]" as fucking. [We'd like to have "f" work too, but it conflicts with "fore" and I haven't yet figured out how to make it do the right thing.] [ Understand "f [something]" as fucking when the location is not in Shipboard.] [That doesn't actually work.]

Understand "fuck [something] with [something preferably held]" as inserting it into (with nouns reversed). Understand "penetrate [something] with [something preferably held]" as inserting it into (with nouns reversed). Understand "rape [something] with [something preferably held]" as inserting it into (with nouns reversed). Understand "love [something] with [something preferably held]" as inserting it into (with nouns reversed). Understand "ravish [something] with [something preferably held]" as inserting it into (with nouns reversed). Understand "poke [something] with [something preferably held]" as inserting it into (with nouns reversed). Understand "do [something] with [something preferably held]" as inserting it into (with nouns reversed).

Understand the command "bugger" as something new. Understand "bugger [something]" as buggering. Understand "assfuck [something]" as buggering. Understand "plook [something]" as buggering. [4] Understand "bugger [something] with [something preferably held]" as inserting it into (with nouns reversed). Understand "assfuck [something] with [something preferably held]" as inserting it into (with nouns reversed).

Buggering is an action applying to one thing. Report buggering:

if the noun is not female, instead try fucking the noun;

say "[The noun] probably doesn't want to be anally violated right now."

Understand the command "snowball" as something new. Understand "snowball [something]" as snowballing.

Snowballing is an action applying to one thing. Report snowballing:

if the noun is not male, instead say "It's unclear how you'd orally extract semen from [the noun] in the first place, much less return it in a kiss.";

instead say "That's two separate actions: the oral sex, and then the kiss."

Understand the command "wank" as something new. Understand "wank" as wanking. Understand "masturbate" as wanking. Understand "Jack off" as wanking. Understand "Jerk off" as wanking. Understand "Beat off" as wanking. Understand "wank [something]" as wanking off. Understand "masturbate [something]" as wanking off. Understand "Jack off [something]" as wanking off. Understand "jerk off [something]" as wanking off. Understand "Beat off [something]" as wanking off.

Understand "get off" as wanking. Understand "get off on [something]" as fucking. Understand "get off [something]" as getting off. Understand "get off of [something]" as getting off. Understand "Get off [someone]" as wanking off.

Understand "claim [something]" as taking. Understand "score [someone]" as fucking. Understand "score [something]" as attacking.

The last_wanking_turn is a number that varies. The last_wanking_turn is 0.

The last_pissing_turn is a number that varies. The last_pissing_turn is 0.

The last_shitting_turn is a number that varies. The last_shitting_turn is 0.

The festus_dump_turn is a number that varies. The festus_dump_turn is 0.

Wanking is an action applying to nothing. Report wanking:

if the player is Stiffy Makane

begin;

if the stiffycock is not held by the player

begin;

say "Out of sight, out of mind.";

otherwise;

if the stiffycock is diseased

begin;

say "It hurts way too much to touch.";

otherwise;

say "You give your schlong a few half-hearted tugs, but you're not really in the mood.";

end if;

end if;

otherwise;

say "That would be indecorous.";

end if.

Wanking off is an action applying to one thing. Report wanking off:

if the noun is not a person

begin;

say "You aren't quite sure where to begin.";

otherwise;

if the noun is Stiffy Makane or the noun is the stiffycock

begin;

if the stiffycock is not held by the player

begin;

say "Out of sight, out of mind.";

otherwise;

say "You give your schlong a few half-hearted tugs, but you're not really in the mood.";

end if;

otherwise;

try touching the noun;

end if;

end if.

Check tasting:

if the noun is a person, instead try sucking the noun;

continue the action.

Understand "xyzzy" or "plugh" or "yoho" as casting xyzzy. Xyzzyed is a truth state that varies. Xyzzyed is false.

Casting xyzzy is an action applying to nothing.

Carry out casting xyzzy:

if the stiffycock is not lit, instead say "Nothing happens.";

abide by the priestess-cockblocking rule;

now xyzzyed is true;

let T be a random stiffycolor;

while T is the stiffycolor of the stiffycock

begin;

let T be a random stiffycolor;

end while;

now the stiffycolor of the stiffycock is T;

if the stiffycock is not held by the player

begin;

say "Nothing obvious happens.";

otherwise;

say "Something happens.";

end if;

stop the action.

Understand "y2" as casting y2. [ Remove y2 before release. ]

Understand "plover" as casting plover. [ Remove plover before release too. ]

Casting y2 is an action applying to nothing.

Carry out casting y2:

if the stiffycock is not lit, instead say "Nothing happens.";

if xyzzyed is false, instead say "Nothing happens.";

if the stiffycolor of the stiffycock is blue, instead say "Nothing happens.";

now the stiffycolor of the stiffycock is blue;

if the stiffycock is not held by the player

begin;

say "You feel a tingling in your nethers.";

otherwise;

say "Your cock flashes brilliant white for a moment, and then settles down to a soft blue glow.";

end if;

stop the action.

Casting plover is an action applying to nothing.

Carry out casting plover:

if the stiffycock is not lit, instead say "Nothing happens.";

if xyzzyed is false, instead say "Nothing happens.";

abide by the the priestess-cockblocking rule;

if the stiffycolor of the stiffycock is red, instead say "Nothing happens.";

now the stiffycolor of the stiffycock is red;

if the stiffycock is not held by the player

begin;

say "You feel a tingling in your nethers.";

otherwise;

say "Your cock flashes brilliant white for a moment, and then settles down to a soft red glow.";

end if;

stop the action.

This is the priestess-cockblocking rule:

if the location is the Druidic Grove and the stiffycolor of the stiffycock is blue

begin;

say "The priestess shushes you. 'It's the right color now. Leave it alone!'";

rule fails;

end if.

Attacking it with is an action applying to two things. Report attacking it with:

if the player is Stiffy Makane

begin;

say "You're a lover, not a fighter.";

otherwise;

say "That would be unseemly.";

end if.

Pouring it on is an action applying to two things. Report pouring it on:

say "That would be pointless."

Understand "pour [something preferably held] on [something]" as pouring it on.

Understand "pour [something preferably held] onto [something]" as pouring it on.

Understand "pour [something preferably held] in [something]" as pouring it on.

Understand "pour [something preferably held] into [something]" as pouring it on.

Understand "water [something] with [something preferably held]" as pouring it on (with nouns reversed).

Understand "kick" as kicking_nothing.

Understand "kick [something]" as kicking.

Kicking_nothing is an action applying to nothing. Report kicking_nothing:

say "You perform a short dance routine.".

Kicking is an action applying to one thing. Report kicking:

say "Violence isn't the answer to this one.".

Understand "brine [something]" as brining.

Brining is an action applying to one visible thing. Report brining:

if the vinegar is not held, instead say "With what? Your acerbic wit?";

say "[The noun] would not be improved by brining.".

Understand "roll [something]" as rolling. Understand "roll up [something]" as rolling.

Rolling is an action applying to one thing. Report rolling:

if the noun is a person, instead say "Robbery is not the answer.";

say "[The noun] doesn't seem like it would roll very well."

Understand "look up" as looking up.

Looking up is an action applying to nothing. Carry out looking up:

if the player can see a sky_scenery (called S)

begin;

instead try examining S;

otherwise;

say "You see nothing special about the ceiling.";

end if.

Understand "look down" as looking down.

Looking down is an action applying to nothing. Carry out looking down:

if the player can see a floor_scenery (called F)

begin;

instead try examining F;

otherwise;

if the stiffycock is visible, instead try examining the stiffycock;

say "You see [a random garment worn by the player].";

end if.

Understand "peel [something]" as peeling.

Understand "skin [something]" as peeling.

Peeling is an action applying to one visible thing. Report peeling:

say "It's not clear how you would peel [the noun].".

Touching is fiddling. Rubbing is fiddling. Pushing is fiddling. Pulling is fiddling. Turning is fiddling.

Understand "sail to [text]" as sailing to.

Sailing to is an action applying to one topic. Carry out sailing to:

if Palinurus is in the location, instead try asking Palinurus about the topic understood;

if the location is in Shipboard, instead say "You don't have a lot of choice about your destination.";

if the location is Riverbank or the location is Northern_riverbank

begin;

say "You throw back your head and sing a few bars of 'Come Sail Away[88 as a reference],' which seems appropriate to the location,[run paragraph on]";

if Charon is in the location

begin;

say " and, indeed Charon gives you a bony thumbs-up[run paragraph on]";

if Charon is fixed

begin;

say " and gestures to you to board.";

instead try entering the skiff;

otherwise;

instead say " but, alas, does not seem inclined to let you board.";

end if;

end if;

say " but nothing extraordinary happens.";

stop the action;

end if;

instead say "The minor flaw with this plan is that you're not in a boat."

Understand "greet [something]" as greeting.

Understand "hail [something]" as hailing.

Greeting is an action applying to one thing. Report greeting:

if the noun is a person, instead try asking the noun about "Thrazar";

say "Greeting [the noun]? That seems unlikely to provoke a response."

Hailing is an action applying to one thing. Report hailing:

if the player is not godly, instead try greeting the noun;

say "You would have to have a portfolio including weather (like Jupiter, for instance), in order for that to work. You don't."

Going northwest is going diagonally. Going northeast is going diagonally. Going southwest is going diagonally. Going southeast is going diagonally.

Instead of going diagonally for the first time, say "[bracket] Only the four cardinal directions (and up, down, in, and out) are required to play [italic type]Mentula Macanus: Apocolocyntosis[roman type]. [close bracket][paragraph break]"

Instead of going diagonally, say "You can't go that way."

Understand "climb [direction]" as going.

The block waking up rule is not listed in the check waking up rulebook.

Check waking up:

say "The dreadful truth is, this [italic type]is[roman type] a dream[emdash]but not [italic type]your[roman type] dream.";

consider the Looking-Glass-Ending rule.

Notes

[1]. I just want "consider Phlebas" to work.

[2]. Ditto for "munch rug"

[3]. cf. George Carlin

[4]. Thank you, Frank Zappa!