# Stiffy Makane: Apocolocyntosis — 127 of 235

## One of the Bruces and Drunken Bastard

Release 1

- Home page
- Beginning
- Previous
- Next

Section Three - "The Young Man Carbuncular"

The hotel clerk is a man in the Hotel Metropole. "A spotty clerk slouches sullenly behind a battered counter adorned with a greasy ledger, regarding you and the lobby with a bored bovine calm." Understand "dull", "unambitious", "placid", "terminally", "young", "fat", "pustular", "spotty", "sullen", "bovine", "bored", "calm", "pimply", "man", and "carbuncular" as the hotel clerk. The description of the hotel clerk is "The clerk is a fat young man, with the placid expression of the terminally-dull-and-unambitious. He has a rather magnificent collection of zits, carbuncles, and pustules adorning his otherwise unremarkable features." Instead of touching, rubbing, sucking, fucking, blowing, kissing, or wanking off the hotel clerk, say "Although you have been known to take on fixer-upper projects in your time, well, [italic type]really[roman type]." The conversation of the hotel clerk is the Table of Clerk's Chatter. The default reply of the hotel clerk is "The clerk stares ruminatively into space. Finally, after a long pause, he mutters, 'Dunno.'"

Before asking the clerk about something:

if the topic understood matches "Eugenides/Mr/Mister/merchant/Smyrna", replace the topic understood with "#fake1";

if the topic understood matches "Mr Eugenides", replace the topic understood with "#fake1";

if the topic understood matches "Mister Eugenides", replace the topic understood with "#fake1";

if the topic understood matches "#fake1"

begin;

if Eugenides is not horny and the ledger is not handled

begin;

say "The horrible realization that you are about interrogate the clerk based on knowledge you can't possibly have, except perhaps from another life, freezes your tongue within your mouth.";

stop the action;

otherwise;

now the clerk is handled;

end if;

end if.

Table of Clerk's Chatter

topic | reply | summary | turn stamp
"clerk/himself" | "'Don[apostrophe] ask me. I jus[apostrophe] work here.'" | "he isn't much for conversation" | a number
"zit/zits/carbuncle/carbuncles/spot/spots/pustule/pustules/boil/boils/blister/blisters/pus" | "The clerk meditatively pokes one of his pustules, which sloshes alarmingly, and shrugs." | "he seems resigned to his skin condition" | --
"#fake1" | "The clerk blinks at you and glances at the ledger. 'Room 14,' he mumbles, jerking a thumb at the stairs." | "Mr. Eugenides is in Room 14" | --
"Syra" | "The spotty youth cracks a ghastly grin. 'My zits weren't the only thing spraying sticky white fluid that night!'" | "he has apparently encountered Syra" | --
"currant/currants/bag/pocket" or "bag of currants" | "'Ugh. Can't stand 'em.'" | "he doesn't like currants" | --
"room/hotel/metropole" or "Hotel Metropole" | "'Sorry, no vacancy,' grunts the clerk, contriving to suggest that he's not sorry in the least." | "the hotel is full" | --
"ostrich/goat/naked/dice/gambling" or "naked woman" | "'What my guests do is their own business.'" | "he doesn't care what happens in his rooms" | --
"Alexandria/Alexander/Alex/Cleo/Cleopatra/Museum/Library/Lighthouse" or "Great Lighthouse" or "Alexander the Great" | "'Do I look like a tour guide?'" | "he's not a tour guide" | --

Some carbuncles are part of the hotel clerk. They are ambiguously plural. The description is "Pus-filled boils and carbuncles wobble alarmingly, giving the distinct impression of imminent detonation." Instead of pulling, pushing, attacking, rubbing, touching or squeezing the carbuncles, say "Although you have done many revolting things in your life, you will not, in fact, do that." Understand "zit", "zits", "carbuncle", "pustule", "pustules", "boil", "boils", "blister", "blisters", "pus", "pus-filled", "pussy", "wobbly", "wobbling", "spot", "spots", "pimple", "magnificent", "collection", and "pimples" as the carbuncles.