# Stiffy Makane: Apocolocyntosis — 56 of 235

## One of the Bruces and Drunken Bastard

Release 1

- Home page
- Beginning
- Previous
- Next

Section Two - "Furnishings"

The green shag carpet is scenery in the Stiffy Love Nest. The description is "Sexy and sophisticated, if maybe a little stained." Understand "floor", "musk", "sweat", "semen", "wine", "vomit", "shit", "stained", and "rug" as the carpet. Instead of smelling the carpet, say "Musk. Sweat. Semen. Wine. Also, er, some vomit. And shit. In fact, it's probably a good idea to stop smelling it right about now." Instead of eating or tasting the carpet, say "Yes, yes, that's a good little rugmuncher." Instead of rubbing the carpet, say "Ahhhh, the luxurious richness of shag." Instead of sucking the carpet, try tasting the carpet. Check taking the carpet: instead try rolling the carpet. Instead of rolling the carpet, say "It's actually glued to the floor." Instead of looking under the carpet, say "It's glued to the floor, but you made sure there were no trap doors under it before you fastened it down."

The nightstand is scenery in the Stiffy Love Nest. It is a supporter. The description is "This Persian nightstand is made of an exotic dark wood. It is carved with all manner of erotic scenes: men on women, women on women, men on men, men on gazelles, gazelles on hermaphrodites, gazelles and hermaphrodites on men-in-women's-clothing, and so on. Really, this is one of the finest things you own." Understand "smooth", "sensuous", "exotic", "erotic", "dark", "wood", "scenes", "men", "women", "hermaphrodites", "gazelles", "carved", "carven", "carving", "carvings", and "Persian" as the nightstand. Instead of fucking the nightstand, say "You're demented. Is it the years of depravity finally catching up to you, or is it the lead water pipes?" Instead of rubbing the nightstand, say "The dark wood is smooth and sensuous." Instead of tasting the nightstand, say "It tastes like olive oil." Instead of smelling the nightstand, say "The nightstand reeks of olive oil."

The small oil lamp is a thing on the nightstand. The description is "This is a small oil lamp, which Festus keeps full of fresh sweet oil for you. Not that you ever use it for lighting, but the oil comes in plenty handy." Understand "olive" and "sweet" as the oil lamp. Check taking the oil lamp: instead say "No. There's a very good reason the oil lamp is beside your bed. Hint: not for light." Instead of smelling or tasting the oil lamp, say "The lamp is full of sweet olive oil." The small oil lamp can be drinkable. The small oil lamp is drinkable. Instead of drinking the oil lamp, try taking the oil lamp. Instead of burning the oil lamp, say "You prefer to use the oil it contains for other activities." Instead of pouring the oil on the stiffycock, try wanking. Instead of pouring the oil on something, say "Don't waste it!" Instead of putting the oil on the stiffycock, try wanking. Instead of putting the oil on something, say "Don't waste it!" Instead of searching the oil lamp, try tasting the oil lamp.

The bed is a supporter in the Stiffy Love Nest. It is enterable. It is scenery. The description is "Your bed is covered in red velvet, and is the scene of innumerable conquests." Understand "red" and "velvet" as the bed. Instead of smelling the bed, say "Perfume. Musk. Semen. Olive oil. Mostly olive oil." Instead of tasting the bed, say "You would swiftly get pubic hair caught in your teeth, and no one wants that." Instead of rubbing the bed, say "Mmmm. Velvet." Check taking the bed: instead try pushing the bed. Instead of pushing the bed, say "The bed is fine where it is." Instead of looking under the bed, say "The mere thought of all the cumrags you've tossed under the bed dissuades you."

The quotations are scenery in the Stiffy Love Nest. Instead of examining the quotations:

choose a random row in the Table of Catullus Quotations;

say "Your eye lights on a quotation at random: '[quotation entry]' Sexy stuff!".

Understand "Catullus", "Catullan", "quote", "quotes", "wall" and "walls" as quotations.

Table of Catullus Quotations

quotation
"Tam gratum est mihi quam ferunt puellae / pernici aureolum fuisse malum, / quod zonam soluit diu ligatam[45 as a reference]."
"Bononiensis Rufa Rufulum fellat, / uxor Meneni, saepe quam in sepulcretis / uidistis ipso rapere de rogo cenam, / cum deuolutum ex igne prosequens panem / ab semiraso tunderetur ustore[46 as a reference]."
"Mentula conatur Pipleium scandere montem: / Musae furcillis praecipitem eiciunt[47 as a reference]."
"Mentula moechatur. Moechatur mentula? Certe. / Hoc est quod dicunt: ipsa olera olla legit[48 as a reference]."
"Da mi basia mille, deinde centum, / dein mille altera, dein secunda centum, / deinde usque altera mille, deinde centum [49 as a reference]."

Instead of wanking in the Stiffy Love Nest:

if the stiffycock is not held by the player

begin;

say "Out of sight, out of mind.";

otherwise;

let X be the turn count minus the last_wanking_turn;

if X is less than 50 and the last_wanking_turn is greater than 0

begin;

say "You give your schlong a few half-hearted tugs, but you're not really in the mood.";

otherwise;

say "With the economy of long practice, you pour a little olive oil from the lamp into your hand, [if the player is not on the bed]perch on the bed, [end if]and quickly rub one out. Ahhhh.";

now the last_wanking_turn is the turn count;

if the small oil lamp is not warned_about

begin;

now the small oil lamp is warned_about;

set note style;

say "[line break][bracket]Your score has not gone up. Masturbation doesn't count.[close bracket] [line break][paragraph break]";

set normal style;

end if;

if the player is not on the bed, now the player is on the bed;

end if;

end if.

The plain wooden door is east of the Stiffy Love Nest and west of the Atrium. The plain wooden door is a door. It is closed. It is scenery. Before going through the closed plain wooden door:

say "(first opening the door)[line break]";

silently try opening the plain wooden door;

if the plain wooden door is closed, stop the action.

Instead of going outside when the location is the Stiffy Love Nest, try going east.

Does the player mean doing something with the plain wooden door: it is likely.