# Stiffy Makane: Apocolocyntosis — 60 of 235

## One of the Bruces and Drunken Bastard

Release 1

- Home page
- Beginning
- Previous
- Next

Chapter Four - "Peristyle"

The Peristyle is a room. It is north of the Tablinum. "This is the the peristyle, a large rectangular garden with a portico around the edge and a fountain in the middle. The tablinum is south, and beyond it the atrium. The triclinium is east and the exedra is west. Off to the north a [if the flimsy door is closed]closed[end if] door marks the privy."

The peristyle_scenery is scenery in the Peristyle. Understand "garden", "portico", "columns", "earth", "dirt", and "ground" as the peristyle_scenery. The description is "The garden serves as both a source of fresh vegetables and an aromatic flower-garden during much of the year. However, nothing has come up yet this year, and it's still just bare dirt."

The fountain is scenery in the Peristyle. "The fountain is a dolphin, squirting water from its mouth into a small pool." Understand "water", "dolphin", and "pool" as the fountain. The fountain can be drinkable. The fountain is drinkable. Instead of drinking the fountain, say "You prefer the water from the impluvium in the atrium." Instead of tasting the fountain, try drinking the fountain. Instead of sucking the fountain, try drinking the fountain. Instead of touching the fountain, try swimming around in the fountain. Instead of smelling the fountain, say "The water in the fountain has no real smell."

Instead of swimming around in the fountain, say "It would be rude and classless to splash around in the fountain. That's what the baths are for."

Instead of going east in the Peristyle, say "It's nowhere near a mealtime, so there's no reason to head into the triclinium." Instead of going west in the Peristyle, say "Your family is not throwing a party, so the exedra is empty and very dull."

The flimsy door is a door. It is scenery. It is north of the Peristyle and south of the privy. It is locked. It is openable. It is closed. The description is "The privy door is a flimsy wooden door with a crescent moon carved out near the top." Understand "privy", "wooden", "flimsy", "crescent", and "moon" as the flimsy door.

Before going through the closed flimsy door:

say "(first opening the door)[line break]";

silently try opening the flimsy door;

if the flimsy door is closed, stop the action.

Before going through the open flimsy door:

if the turn count is less than the festus_dump_turn

begin;

say "Festus wasn't kidding that you might want to wait a few minutes. Gagging and choking, you retreat from the horrible stench.";

stop the action;

end if.

Before opening the flimsy door:

If Cocky is not_warned_about

begin;

say "You start to push the door open, but it is slammed forcefully shut from the inside. 'Dude, I'm [italic type]busy[roman type] in here!' shouts Festus.";

stop the action;

end if.;