# Stiffy Makane: Apocolocyntosis — 36 of 235

## One of the Bruces and Drunken Bastard

Release 1

- Home page
- Beginning
- Previous
- Next

Book Two - "Say, is That a Tentacle?"

Slowly drowning is a recurring scene. Slowly drowning begins when the location is the Lake. Slowly drowning ends flashbackily when the time since Slowly drowning began is 5 minutes and the current dejavuity is fresh. Slowly drowning ends hellishly when the time since Slowly drowning began is 5 minutes and the current dejavuity is familiar.

When Slowly drowning begins:

Now the coldness of Stiffy Makane is 60;

Every turn during Slowly drowning:

Now NN is NN + 1;

say "[message in row NN of the Table of Drowning Actions][paragraph break]";

The Lake is a water_room. "The lake waters are deadly cold. The craggy southern shore, upon which is perched the Gostak castle, seems impossibly far away. In all other directions, the lake stretches without visible end." Up from the lake is nowhere.

Instead of going south in the Lake: say "You paddle painfully towards shore, but make only the tiniest progress." Instead of going down in the lake when NN is 0, say "Icy spray lashes your face." Instead of going down in the lake, say "It seems likely that you'll be headed that way soon enough." Instead of going north in the lake, say "Perversely, you swim away from the shore, but don't get far in that direction either." Instead of going west in the lake, say "Swimming parallel to the shore gets you, as expected, neither closer nor farther away from dry land." Instead of going east in the lake, try going west. Instead of diving in the lake, try going down. Instead of diving into the scenery_water, try going down. Instead of jumping in the lake, say "Not likely." Instead of jumping into the scenery_water, say "Out of the frying pan into the fire, or, more accurately, from the lake to the lake. Well played."

The scenery_water is scenery in the Lake. The description is "The water is icy cold, dark, and very deep indeed." Understand "lake","water","dark","deep", "frigid", "icy", "spray", and "cold" as scenery_water. Before tasting or drinking the scenery_water, instead say "Bitter and frigid." The printed name is "lake". Instead of digging the scenery_water, say "Digging in water would be a neat trick, wouldn't it?" Instead of swimming around in the scenery_water, try swimming.

Some slimy_scenery_things are scenery in the Lake. The description is "Occasionally cold, slimy things brush against you. You can't see them, though, and you have no effort to spend on their pursuit." The printed name is "slimy things". Understand "fish", "fishes", "slimy", "denizen", "wriggly", "denizens", "thing", "things", "tentacular", "tentacle", and "tentacles" as the slimy_scenery_things. Instead of doing anything other than examining with the slimy_scenery_things, try examining the slimy_scenery_things. Before taking the slimy_scenery_things, instead try examining the slimy_scenery_things.

Check dropping something (called S) in the Lake:

if S is the Golden Banana

begin;

say "It would surely be lost forever. You will not part with it now.";

otherwise;

if S is the stiffycock

begin;

say "It's so tiny and shrunken right now that it really isn't hindering your swimming. Besides, you can't.";

otherwise;

say "[The S] vanishes beneath the icy waters with a forlorn 'bloop' sound.";

remove S from play;

end if;

end if;

stop the action.

Check kicking during Slowly drowning:

instead say "Your frantic thrashing in the water avails you naught."

Check kicking_nothing during Slowly Drowning:

instead say "Your frantic thrashing in the water avails you naught."

Check listening during Slowly drowning:

instead say "Blood roars in your ears."

Check swimming during Slowly drowning:

instead say "What did you think you were doing [italic type]before[roman type]?"

Check wanking during Slowly drowning:

instead say "In water this cold you'd be lucky even to find it."

Check pissing during Slowly drowning:

consider the gotta-pee rule;

if the rule failed, stop the action;

now the last_pissing_turn is the turn count;

say "The water becomes warm, very briefly, but it doesn't help for long.";

stop the action.

Check shitting during Slowly drowning:

instead say "The water is so cold that there's no way you can unclench."

Table of Drowning Actions

message
"The frigid water is sapping your strength."
"You hear your blood roaring in your ears as you frantically try to stay afloat."
"Something cold and wriggly brushes your foot."
"You start to slip beneath the water, but, choking, get your head above the surface again."
"Your strength is nearly exhausted."

When Slowly Drowning ends:

say "As you flounder feebly in the lake, something slimy and tentacular grabs your leg and yanks you under the surface. As the frigid waters close around you and everything goes black, the voice of the seer echoes in your ears: [italic type]Fear death by water[roman type][9 as a reference].[paragraph break]";

now the description of Stiffy Makane is "Stiffy Makane (Mentula Macanus[5 as a footnote]): perhaps not the noblest Roman of them all[3 as a reference], but certainly one of the better-hung[if Stiffy Makane is filthy]. Also one of the more-covered-in-sewage, alas[end if].";

now the coldness of Stiffy Makane is 0;

now the stiffycock is not lit;

if the current dejavuity is fresh

begin;

say "As your life passes before your eyes, your recollections pause at that fateful morning in the Forum when all your adventures, and all your troubles, began.[paragraph break][paragraph break] [paragraph break][paragraph break]";

follow the major-scene-change rule;

repeat with possession running through things held by the player begin;

if possession is not part of the player

begin;

remove possession from play;

end if;

end repeat;

move the toga to the player;

now the toga is worn by the player;

remove the stiffycock from play;

now the turn count is 1;

now NN is 1;

now the current dejavuity is familiar;

say "[banner text][paragraph break]";

consider the stating-the-license rule;

consider the tell-the-newbies rule;

consider the announcing-the-credits rule;

now the golden banana is not handled;

now the golden banana is not_warned_about;

move the golden banana to Top of the Banana Tree;

move the player to the Forum;

really have the parser notice the roman_pbs;

otherwise;

say paragraph break;

say paragraph break;

now the player is Divine Eris;

end if.