# Stiffy Makane: Apocolocyntosis — 114 of 235

## One of the Bruces and Drunken Bastard

Release 1

- Home page
- Beginning
- Previous
- Next

Chapter Two - "The Great Library"

Section One - "The Room"

The Great Library is east from the Museum Antechamber. "The Library is a high-ceilinged, airy structure[38 as a footnote], filled with immensely tall cabinets of cubbyholes, accessible via ladders, wheeled at the top, which roll along rails atop each cabinet. In each cubbyhole rests a papyrus scroll. Greek slaves scurry up and down the ladders, retrieving and replacing scrolls for the scholars working at tables below. A huge curved marble counter is directly in front of you. Behind it stands an older woman wearing the traditional garb of the librarian, overseeing the hustle and bustle of the researchers with a tight-lipped smile and an air of unshakeable competence. Galleries of wonders stretch north, east, and south; the library exit is west."

Instead of going east in the Great Library, try going north. Instead of going south in the Great Library, try going north. Instead of going north in the Great Library:

say "You wander for some time amidst the cabinets and cases of the library, seeing wonders,[run paragraph on]";

if the number of rows in the Table of Roman Occurrences is greater than 1

begin;

choose a random row in the Table of Wonders;

if the description entry is not "placeholder"

begin;

say " including [description entry],[run paragraph on]";

blank out the whole row;

end if;

end if;

say " before eventually returning exhausted to the reference desk."

Instead of going up in the Great Library, say "The librarian freezes you with a glance. 'The stacks are closed. Simply inquire about what you want to study, and the appropriate volume will be brought to you.'"

Some scenery_shelves are scenery in the Great Library. The printed name is "shelves". The description is "Towering stacks of cubbyholes, each with a tagged scroll inside, soar towards the ceiling. Wheeled ladders on tracks allow access to their contents, and black-clad Greek slaves with soft shoes scurry up and down in silence, fetching volumes for the scholars working below." Understand "shelf", "shelves", "stack", "stacks", "cubbyhole", "cubbyholes", "papyrus", "rail", "rails", "track", "tracks", "cabinet", "cabinets", "scrolls", "scroll", "tag", "tagged", "ladder", "ladders", "wheel", "wheels", "volume", "volumes", "bookshelf", and "bookshelves" as the scenery_shelves. Instead of climbing the scenery_shelves, try going up.

Some greek_slaves are scenery in the Great Library. They are people. The printed name is "slaves". The description is "Black-clad Greeks swarm up and down the ladders, retrieving and replacing books with ruthless efficiency." They are unspeakable. The default reply of the greek_slaves is "A slave turns toward you, opens his mouth, and indicates that his tongue has been cut out. The librarian notes, drily, 'It doesn't do to talk in libraries, you see.'" Understand "Greek", "slaves", "slave", "black", "clad", "black-clad", "soft", "soft-shoed", "shoes" and "shelvers" as the greek_slaves.

Some scenery_scholars are scenery in the Great Library. They are people. The printed name is "scholars". The description is "Ink-covered scholars work, heads-down, at dozens of tables on the library floor." Understand "scholar", "scholars", "ink", "stained", "covered", "ink-covered", "dozens", "table", "tables", and "floor" as the scenery_scholars. They are unspeakable. The default reply of the scenery_scholars is "The librarian shushes you before you can get as much as a syllable out. 'Do not disturb the scholars,' she admonishes."

Some scenery_galleries are scenery in the Great Library. The description is "Halls full of cases containing wonders stretch off to the north, east, and west." The printed name is "galleries". Understand "hall", "halls", "gallery", "galleries", "case", and "cases" as scenery_galleries.

The marble counter is scenery in the Great Library. The description is "The huge, gently-curved counter is fashioned from purple marble, polished to a mirror sheen." Understand "huge", "purple", "curved", "gently", "gently-curved", "mirror", "sheen", "shiny", and "polished", "desk", and "reference desk" as the marble counter. It is a supporter.

Before going west in the Great Library:

if the ragged papyrus is held, instead say "A delicate cough from the librarian freezes you in your tracks. 'I believe,' she says icily, 'that that ragged papyrus fragment belongs to the Library.'";

if the stained piece of papyrus is held, instead say "The librarian stops you. 'Half of that papyrus is ours. However, if you give it to me, I'll make you a copy, which will be yours to keep.'".

[1]

Table of Wonders

description
"placeholder"
"the skeleton of a two-headed elephant"
"a small geared clockwork model of the cosmos"
"stones[emdash]boulders, really[emdash]from the craw of the Mweru Bird"
"a gorgeous crystal bowl from an Assyrian empire 4000 years dead"
"a sandstone Mesopotamian sphinx, with the body of a winged lion and the bearded head of a man"
"row upon row of mummies in gaudily ornate cases"
"a collection of coins from the reign of Tarquinius Superbus"
"strange oblong leather shields carried by black-skinned warriors far up the Nile"
"coins from far away with square holes in their centers"

Note

[1]. The crystal bowl is in the Metropolitan Museum of Art in New York.