# Stiffy Makane: Apocolocyntosis — 175 of 235

## One of the Bruces and Drunken Bastard

Release 1

- Home page
- Beginning
- Previous
- Next

Chapter Two - "Tiresias"

Tiresias is a man in Little Thebes. "A naked old blind man sits against the wall." Instead of examining Tiresias for the first time:

say "A naked old blind man sits below the wall. At least you think it's a man; he (?) seems to have withered female breasts, but also a stubbly white beard. On closer inspection, yes, he does seem to possess both a sausage and a pussy. This seems familiar....ah. Of course. It must be Tiresias.";

now Tiresias is handled.

The description of Tiresias is "Tiresias is an old, old man. Actually a hermaphrodite[if the pussy is held by Tiresias and the sausage is held by Tiresias], as he has both a pussy and a sausage[end if]." Understand "old", "naked", "blind", "woman", "hermaphrodite", "teirisias", "morphodite", and "man" as TIresias. The conversation of Tiresias is the Table of Tiresias's Chatter. The default reply of Tiresias is "'Eh? What? Speak up, sonny!'"

Rule for deciding the concealed possessions of Tiresias: no.

Table of Tiresias's Chatter

topic | reply | summary | turn stamp
"TIresias/himself/hermaphrodite/morphodite/blind/him" | "'I, Tiresias, have foresuffered all[line break]Enacted on this same divan or bed[line break]I, who have sat by Thebes below the wall[line break]And walked among the lowest of the dead[22 as a reference].'" | "his life as a hermaphrodite has inured him to most experiences" | a number
"Doug/Dougs/dug/dugs/wrinkled" | "'I, Tiresias, old man with wrinkled dugs[line break]Perceived the scene, and foretold the rest[23 as a reference].'" | "the Dougs have something to do with his prophecy."
"pussy" | "'You want my pussy, just take it.'" | "he has invited you to take his pussy" | --
"sausage" | "'You want my sausage, just take it.'" | "he has invited you to take his sausage" | --
"Cerberus/Ursa/Vinnie/Golem/dog" | "'Like any dog, he likes pussy and sausage.'" | "the dog likes pussy and sausage" | --
"Cerebus/Dave/Sim" or "Dave Sim" | "Dave Sim is in for quite a shock when he arrives" | "he thinks Dave Sim is going to have quite a time in Hades." | --
"Thebes/Little" or "Little Thebes" | "'Thebes always kinda sucked.'" | "he doesn't like Thebes a lot" | --
"Syra" | "'Heh. Hope she comes to see me when she gets here.'" | "he awaits Syra's arrival with eagerness" | --

Tiresias's pussy is a vagina held by Tiresias. The description is "It's an old woman's pussy. Need I say more?" Instead of tasting, eating, or smelling Tiresias's pussy, try smelling Tiresias. Instead of fucking Tiresias's pussy, try taking Tiresias's pussy.

Tiresias's anus is an anus. It is part of Tiresias. The description is "It's an old man's anus. Need I say more?" Instead of touching, tasting, eating, or smelling Tiresias's anus, say "Ugh." Instead of fucking or buggering Tiresias's anus, try buggering Tiresias. Instead of inserting the stiffycock into Tiresias's anus, try buggering Tiresias. Instead of inserting something into Tiresias's anus, say "Tiresias yelps and hops away. Apparently he doesn't want [the noun] shoved up his ass."

The sausage is a thing held by Tiresias. The description is "It's an

old man's sausage. Need I say more?" Check smelling the sausage: instead try smelling Tiresias.

Some wrinkled dugs are part of Tiresias. The description is "They're an old woman's wrinkled dugs. Need I say more?" Understand "chest", "breasts", "breast", "dug", and "floppy" as the wrinkled dugs. Instead of touching, tasting, eating, or smelling the dugs, say "Ugh."

The real_pussy is a female animal. The description is "She's an adorable little orange kitten." The printed name is "pussy". Understand "pussy", "orange", "little", "adorable", "kitten", "cat", and "kitty" as the real_pussy. The default reply of the real_pussy is "'Meow.'" Instead of rubbing the real_pussy, instead say "The kitten mews plaintively and arches her back adorably." Instead of sucking the real_pussy, say "Kinky, but no." Instead of touching the real_pussy, try rubbing the real_pussy. Instead of fucking the real_pussy:

if the stiffycock is held by the player, instead say "Kinky, but no."

Check dropping the real_pussy:

if Cerberus is in the location, instead say "Not when that big mean dog will just gobble her up.";

if Cerberus is intrigued, instead say "Not with that dog on the prowl.";

instead say "After what you had to do to get it? Not likely."

Check taking the real_pussy:

if the real_pussy is enclosed by the player

begin;

instead say "You are already carrying the kitten.";

otherwise;

instead say "You scoop up the cute little kitten. She mews plaintively.";

end if.

The real_sausage is a thing. The printed name is "sausage". The description is "It's a juicy sausage, about six inches long, dripping grease, and smelling of hot peppers and garlic." Understand "sausage", "juicy", "grease", "greasy", "pepper", "peppers", and "garlic" as the real_sausage. Instead of eating the real_sausage, say "A premonition that this sausage will be important to your progress prevents you from eating it." Instead of smelling the real_sausage, say "It smells of hot peppers[25 as a reference]. Also, garlic. Yum!" Instead of sucking the real_sausage, say "The hot grease tastes tantalizingly of garlic and peppers."

Check dropping the real_sausage:

if Cerberus is in the location, instead say "If you do that, the dog will just eat it, and then where will you be?";

if Cerberus is intrigued, instead say "Not with that dog on the prowl.";

instead say "After what you had to endure to get it? No."

Check fucking Tiresias: instead try taking Tiresias's pussy. Check sucking the sausage: instead try sucking Tiresias. Check touching the sausage: instead try rubbing the sausage. Check rubbing the sausage:instead try wanking off Tiresias. Check blowing the sausage: instead try sucking Tiresias. Check tasting the sausage: instead try sucking Tiresias. Check buggering Tiresias: instead say "It really seems like it'd be a better idea to take advantage of his, er, [italic type]unusual[roman type] characteristics. Besides: nasty."

Instead of kissing or smelling Tiresias, say "Yuck."

Taking Tiresias's pussy is being tricked. Taking the sausage is being tricked.

Instead of being tricked:

if Tiresias is warned_about, instead say "You're not falling for that one again.";

if the stiffycock is not held by the player, instead say "You aren't undressed for the occasion.";

now Tiresias is warned_about;

remove the noun from play;

if the noun is the pussy

begin;

say "Grimacing, you remind yourself that worse things happen at sea, yank yourself to full hardness, and ram it in. Tiresias whoops in delight. After a few minutes, you, closing your eyes and thinking of lissome Greek pirates rather than disgusting old men, have your orgasm and withdraw.[line break]";

say "Tiresias smiles, exposing his two remaining teeth, and says 'That was very nice, young[apostrophe]un. But hell, I[apostrophe]d[apostrophe]a just given you the kitty cat anyway. I'm allergic and they make me sneeze.' He hands you an adorable little kitten.";

move the real_pussy to the player;

really have the parser notice the real_pussy;

otherwise;

say "Grimacing, you spit on your fingers and lube up your rectum. A little manipulation brings Tiresias to a surprisingly large and robust erection. You guide it into your anus, and he begins humping away enthusiastically. After what seems like hours, he grunts, ejaculates into your colon, and withdraws. He wipes his dick with his hands and then wipes his hands in your hair.[line break]";

say "Tiresias mops his brow and grins, showing his two remaining teeth. 'Damn, young feller, that was mighty fine. But hell, I[apostrophe]d[apostrophe]a given you the sausage anyway. Garlic makes me gassy.' He hands you a greasy sausage.";

move the real_sausage to the player;

really have the parser notice the real_sausage;

end if;

record "Tiresias" as achieved.

Instead of sucking or blowing Tiresias:

if Tiresias is warned_about, instead say "You're not falling for that one again.";

now Tiresias is warned_about;

say "Grimacing, you drop to your knees. A few tugs brings Tiresias to a surprisingly large and robust erection. He whoops enthusiastically. Suppressing your gag reflex manfully, you bob up and down on his cock. After what seems like hours, he squirts thick gobs of sour-tasting semen into your mouth and withdraws. He wipes his dick with his hands, and then wipes his hands with your hair.[paragraph break]";

say "Tiresias grins, exposing both his remaining teeth. 'That was mighty fine, young feller. But hell, I[apostrophe]d[apostrophe]a given you the sausage anyway. Garlic makes me gassy.' He hands you a greasy sausage.";

move the real_sausage to the player;

really have the parser notice the real_sausage;

record "Tiresias" as achieved.

Instead of touching, rubbing or wanking off Tiresias:

say "Tiresias slaps your hand away. 'Hands off my majosha[33 as a reference]!' he snaps. 'I can do that m'self any time. Put a little effort into it, or just don't bother.'"