# Stiffy Makane: Apocolocyntosis — 229 of 235

## One of the Bruces and Drunken Bastard

Release 1

- Home page
- Beginning
- Previous
- Next

Book Six - "The Grand Palace"

The Grand Palace is a room in Olympus. It is north of the Palace Steps. "[if the sunglasses are worn by the player]This is, far and away, the biggest building you've ever been in. It's a huge circular room with a terrifically high domed ceiling, with something that looks, even through your sunglasses, like the sun, floating in the center of the dome. Columns and niches ring the space. The gods themselves stand in groups scattered about the floor, conversing with one another[otherwise]It is blindingly bright. You are likely to be netae by an eurg[end if]." Instead of going down in the Grand Palace, try going south.

The scenery_hideyholes are scenery in the Grand Palace. The scenery_hideyholes are ambiguously plural. Understand "column", "columns", "niche", "niches", "perimeter", "outside", "outer", "place", "statue", "statues", "hiding", and "ring" as the scenery_hideyholes. The description is "The edge of the room is made up of decorative columns and niches, many populated with statues of gods or depictions of great divine deeds."

Palatial_sky_scenery is sky_scenery. It is in the Grand Palace. The description is "A small, but very intense, sun hangs in the center of the caerulean dome." Understand "sky", "sun", "yellow", "brilliant", "hanging", "sun", "blue", "vivid", "electric", "caerulean", "dome", and "hot" as palatial_sky_scenery.

The palace_floor is a floor_scenery in the Grand Palace. The description is "White marble covers the floor and walls, and reflects the brilliant sunlight." The printed name is "marble". Understand "marble", "floor", "wall", "walls", and "white" as the palace_floor. Does the player mean doing something with the palace_floor: it is unlikely.

Rule for printing the name of the Grand Palace:

if the sunglasses are worn by the player

begin;

say "Grand Palace";

otherwise;

say "Brightness";

end if.

Every turn when the location is Grand Palace:

now Argus is unboinked;

if the sunglasses are worn by the player

begin;

now the Grand Palace is not_warned_about;

otherwise;

if the Grand Palace is warned_about

begin;

say "Before you can do anything, you hear a nasty chuckle behind your left ear, and there is very brief, but excruciating, pain.";

end the story saying "You have been netae by an eurg";

end if;

now the Grand Palace is warned_about;

end if.

Instead of going south when the location is the Grand Palace and the sunglasses are not worn by the player:

say "You stagger blindly back down the steps.";

now the Grand Palace is not_warned_about;

move the player to the Palace Steps.