# Stiffy Makane: Apocolocyntosis — 228 of 235

## One of the Bruces and Drunken Bastard

Release 1

- Home page
- Beginning
- Previous
- Next

Book Five - "Palace Steps"

Palace Steps is a room in Olympus. It is north of Olympic Plaza. The description is "Wide, white marble steps stretch from the enormous plaza to the south up to a ludicrously huge temple or palace to the north."

Before going up in Palace Steps: try going north.

Before going down in Palace Steps: try going south.

Scenery_olympic_palace_steps are a backdrop in Palace Steps. They are ambiguously plural. They are in Olympic Plaza. The printed name is "palace steps". The description is "Wide, white marble steps rise from south to north, connecting the Olympic Plaza and the huge palace of the gods." Understand "wide", "white", "step", "steps", "stair", and "stairs" as the Scenery_olympic_palace_steps. The scenery_olympic_palace_steps can be enterable. The scenery_olympic_palace_steps are enterable. Instead of entering the scenery_olympic_palace_steps:

if the location is Olympic Plaza, instead try going north;

if the location is Palace Steps, instead say "You are in the middle of the staircase, so either up or down would work."

Divine Caesar is a man in Palace Steps. "Caesar sits disconsolately on the steps, his head in his hands." The description is "Caesar looks [if Divine Caesar is unaroused]badly depressed[otherwise]less unhappy than he did when you first encountered him[end if]. He's wearing a white linen toga and a laurel wreath. He's the same handsome fellow you remember from Rome, although now he's glowing with divine radiance." The conversation of Divine Caesar is the Table of Divine Caesarean Chatter. The default reply of Divine Caesar is "Caesar [if Divine Caesar is horny]shrugs his shoulders[otherwise]sighs heavily and pretends not to have heard you[end if]." Caesar has a horniness. Caesar is unaroused. Understand "Julius", "Julius Caesar", "Gaiuis", "Gaius Julius Caesar", "handsome", and "god" as Divine Caesar.

Divine Caesar's toga is a garment. The description of Divine Caesar's toga is "A classic white linen toga, with a purple stripe around the edge." Divine Caesar's toga is worn by Divine Caesar. Understand "white", "linen", "toga", "purple", "stripe", "striped", "edge", "senator's", and "senatorial" as Divine Caesar's toga.

A laurel wreath is an ornament worn by Julius Caesar. The description is "Of all the triumphal laurel wreaths you've ever seen, this is certainly one of them. It looks just like it does on the statues, only this one is green and made of actual branches." Understand "green", "branch", "branches", "triumph", "triumphal" as the laurel wreath.

Before asking Divine Caesar about "Stiffy Makane", replace the topic understood with "me".

Before asking Divine Caesar about "Mentula Macanus", replace the topic understood with "me".

Before asking Divine Caesar about "Lucius Macanus Mentula", replace the topic understood with "me".

Before asking Divine Caesar about "myself/Mentula/Macanus/Stiffy/Macane/Lucius", replace the topic understood with "me."

Before asking Divine Caesar about "Golden Banana", replace the topic understood with "banana".

Before asking Divine Caesar about "Golden Banana of Discord", replace the topic understood with "banana".

Before asking Divine Caesar about "Argus/Eris/banana/Discord/me" when Divine Eris is warned_about:

replace the topic understood with "#fake1";

move scenery_caesar to the Grand Palace;

now Divine Caesar is warned_about.

Table of Divine Caesarean Chatter

topic | reply | summary | turn stamp
"himself/god/gods/Jupiter/Jove/Juno/Julius/Caesar/Gaius/divine/divinity" or "Divine Caesar" or "Julius Caesar" or "Gaius Julius Caesar" or "Jupiter Virilis" | "'You know what? Being a god sucks. Most of the other gods are douchebags. Especially Argus.'" | "he thinks most of the gods are unpleasant, particularly Argus" | a number
"me" | "'Yeah, we had some good times back in Rome, didn't we?'" | "he reminded you of the good times you had together in Rome" | --
"Syra" | "'I even miss [italic type]that[roman type] diseased whore.'" | "he even misses Syra" | --
"Argus" | "'Wow, what an utter fuckhead.'" | "he really doesn't care for Argus" | --
"banana/golden/Eris/Discord" | "'Eris told me to tell you she was waiting for you in the Game Room, and bring her the banana when you come.'" | "you should deliver the Golden Banana to Eris in the Game Room" | --
"Cleo/Cleopatra" | "'I miss her. I wish she'd hurry up and get here.'" | "he misses Cleopatra and hopes she arrives soon" | --
"Rome/Forum/stabbing/choking/choked/death/dying/pork/sword/dagger/daggers/dick/dicks/cock/cocks/Anthony/Tony/Marcus/Brutus/Antony/Quintus/Naughtius/Maximus/Biggus/Dickus/Magnus/Prickus/sycohphant/sycophants/gaggle/hangers-on" or "Naughtius Maximus" or "Biggus Dickus" or "Magnus Prickus" or "et tu Brute" or "pork sword" | "'To be perfectly honest, I[emdash]completely predictably[emdash]choked on cock.'" | "he met his end gagging on a pork sword" | --
"#fake1" | "'Hell yeah, Stiffy. When you move in, I'll run up and kick that fucker Argus right in the [apostrophe]nads. That should distract him long enough for you to do the deed.'" | "he will help you in your humiliation of Argus" | --
"fuck/fucking/sex/blowjob" | "'You know, I'm kinda over that for a while. Choking to death on a dick will do that to you.'" | "he is not particularly interested in sex, since that's how he died" | --

Instead of touching, rubbing, sucking, blowing, fucking, tasting, eating, or wanking off Divine Caesar, try asking Caesar about "sex".

Instead of kissing Divine Caesar:

if Cleopatra is not boinked

begin;

say "Caesar kisses you back perfunctorily and unenthusiastically. 'Sorry, Stiffy,' he says. 'My heart's just not in it today.'";

otherwise;

if Divine Caesar is not horny

begin;

now Divine Caesar is horny;

say "You plant a big, passionate kiss on Caesar, who unenthusiastically kisses you back. Growling, you grab the back of his head and shove your tongue in his mouth. He twitches in surprise, and then you feel his lips curve into a smile. He bites your tongue playfully, and as you disengage he begins to laugh. 'Awwww, man, I miss Cleopatra. Thanks for bringing me that from her, Stiffy. That's the best gift I've had in a long, long time. You don't know how much better that makes me feel. I sure wish she'd hurry her asp up and get here.'";

otherwise;

say "You and Caesar make out for a while.";

end if;

end if.