# Stiffy Makane: Apocolocyntosis — 182 of 235

## One of the Bruces and Drunken Bastard

Release 1

- Home page
- Beginning
- Previous
- Next

Chapter Two - "Agamemnon"

Agamemnon is a man in the Bloody Wood. "An older man in a burial shroud stands here. [if the umbrella is held by Agamemnon]He twirls an umbrella cheerily over his head, deftly deflecting a rain of nightingale guano, and whistling happily if tunelessly[otherwise]He moodily glares at his feet, shrieking each time a gobbet of nightingale crap impacts on him, which is quite often indeed[end if]." The conversation of Agamemnon is the Table of Agamemnon's Chatter. The default reply of Agamemnon is "'I'm sorry, I couldn't quite catch that. I think it's all the nightingale guano in my ears.'" The printed name is "the man in the burial shroud". The description is "[Agamemnon] stands here[if the umbrella is held by Agamemnon], whistling happily under his umbrella[otherwise] moodily attempting, not very sucessfully, to dodge the occasional barrages of nightingale guano[end if]." Understand "man", "ear", "ears", "old", "older", "burial", and "shroud" as Agamemnon.

Instead of touching, rubbing, sucking, fucking, blowing, kissing, or wanking off Agamemnon, say "You have absolutely no desire to get down and dirty with a birdshit-covered old man in a burial shroud. Especially not after Tiresias."

Instead of examining Agamemnon the first time:

say "Oh. This must be Agamemnon:[paragraph break]

[italic type]The nightingales are singing near[line break]

The Convent of the Sacred Heart.[paragraph break]

And sang within the bloody wood[line break]

When Agamemnon cried aloud,[line break]

And let their liquid siftings fall[line break]

To stain the stiff dishonoured shroud[roman type][32 as a reference].[line break]";

now Agamemnon is handled;

move the convent_scenery to the Bloody Wood;

now the printed name of Agamemnon is "Agamemnon".

Instead of showing something to Agamemnon:

if the noun is not the umbrella

begin;

say "Agamemnon shrugs.";

otherwise;

say "Agamemnon's face lights up when he sees the umbrella. 'Please, please, please let me have it,' he implores you.";

end if.

Instead of giving something to Agamemnon:

if the noun is not the umbrella

begin;

say "Agamemnon waves [the noun] away.";

otherwise;

now the umbrella is held by Agamemnon;

say "Agamemnon gratefully accepts the umbrella. He [if the umbrella is closed]snaps it open and [end if]brandishes it over his head. 'Take that, you damned nightingales!' he yells.[paragraph break]";

now the umbrella is open;

say "Agamemnon reaches into his shroud and pulls out a bottle of fine Falernian wine. 'It's the least I can do,' he explains, as he hands it to you.";

now the fine Falernian wine is held by the player;

really have the parser notice the fine Falernian wine;

end if.

Table of Agamemnon's Expletives

epithet | body part
"Yuck" | "head"
"Ick" | "right shoulder"
"Augh" | "left shoulder"
"Ugh" | "left foot"
"Blast" | "right foot"
"Gross" | "back"
"Ewww" | "chest"

Table of Agamemnon's Chatter

topic | reply | summary | turn stamp
"Agamemnon/himself/man/old/older/him" or "old man" or "older man" | "'You sacrifice [italic type]one[roman type] daughter for a favorable wind, and you get shit on by birds for all eternity. Is that justice? Is that proper[43 as a reference]?'" | "he feels put-upon by his punishment" | --
"Iphigeneia/daughter/sacrifice/wind/favorable" or "favorable wind" | "'Hey, it worked, didn't it? Who won the war?'" | "he's not remorseful about sacrificing his daughter" | --
"nightingale/nightingales/bird/birds/guano/shit/crap/birdshit/liquid/siftings" or "liquid siftings" | "He sighs in exasperation. 'Fuckin[apostrophe] birds.'" | "he's not a fan of the nightingales" | --
"war/Trojan" or "Trojan war" | "'Yeah, well, we won, but what a mess.'" | "he's ambivalent about the Trojan war" | --
"Achilles/wrath" or "wrath of Achilles" | "[Agamemnon] rolls his eyes and makes the universal gesture for masturbation. 'What a wanker.'" | "he thinks Achilles was a wanker" | --
"Clytemnestra/wife" | "'I still can't belive that bitch fucking [italic type]killed[roman type] me,' he grumbles." | "being killed by his wife still rankles" | --
"Helen" or "Helen of Troy" | "'Hot, yes. Hot enough to justify [italic type]that[roman type]? Hell no.'" | "Helen was not hot enough to justify the Trojan War" | --
"Menelaus" | "'Family's family. Even when they're being fucking dumbasses.'" | "he had to come to Menelaus's aid, but he's bitter about it" | --
"blood/wood/bloody" or "bloody wood" | "'Nasty, isn't it?'" | "he thinks the Bloody Wood is pretty nasty" | --
"convent/sacred/heart" or "sacred heart" or "convent of sacred heart" or "convent of the sacred heart" | "'Yeah,' he gestures vaguely, 'I hear it's around here somewhere.'" | "he doesn't seem to really know much about the convent" | --
"Syra" | "'After my time, but I've heard stories.'" | "although Syra was after his time, he's heard of her" | --