# Stiffy Makane: Apocolocyntosis — 52 of 235

## One of the Bruces and Drunken Bastard

Release 1

- Home page
- Beginning
- Previous
- Next

Volume Four - "Domus Macana"

Book One - "Preliminaries"

Apud Domum Macanam is a recurring scene. Apud Domum Macanam begins when the location is in Town or the location is in Domus Macana. Apud Domum Macanam ends when the location is in Shipboard.

Every turn during Apud Domum Macanam:

if no garment is worn by the player

begin;

if the location of Festus is the location and Stiffy Makane is not filthy and Festus is unboinked and a random chance of 1 in 2 succeeds

begin;

say "Festus eyes your [if the stiffycock is lit][stiffycolor of the stiffycock]-glowing [end if]cock, grins, and licks his lips.";

end if;

if the location of Festus is the location and Stiffy Makane is filthy and a random chance of 1 in 3 succeeds

begin;

say "Festus tries, unsuccessfully, to avoid wrinkling his nose in disgust.";

end if;

if the location of Cocky is the location and Cocky is not_warned_about

begin;

say "Your father glances at your nakedness, rolls his eyes, and begins to deliver his standard speech about not creating a public nuisance. Then he catches sight of the faint [stiffycolor of the stiffycock] glow coming from your penis.[paragraph break]";

now Cocky is warned_about;

say "He blinks. 'Perhaps you have a story I should hear?' So you tell him about your blessing from Jupiter, and your subsequent quest on behalf of Eris. He looks proud, but saddened too. 'Well, son, I always feared you'd have a destiny. Getting involved with divinity, that's always trouble.'[paragraph break]";

say "Shaking his head, he continues, 'I guess you'd better find out how to get that Golden Banana of Discord. Maybe the Cumean Sybil could tell you that, or perhaps you could try to look it up in the Great Library at Alexandria[24 as a footnote]. Anyway, let me know how I can help.'";

end if;

if the location of Cocky is the location and Stiffy Makane is filthy and a random chance of 1 in 2 succeeds

begin;

say "'I hear the baths are a great place for, oh, [italic type]getting clean[roman type],' announces your father pointedly.";

end if;

if the location is Ostia or the location is Dockside

begin;

if the player is filthy

begin;

say "Passers-by recoil in disgust.";

otherwise;

say "Passers-by stare at your [if the stiffycock is lit]glowing penis in wonder[otherwise]exposed penis with dismay[end if].";

end if;

end if;

end if.

Every turn during Apud Domum Macanam:

if the location is the House_Of_Glub for the first time

begin;

choose a row with a character of "Glub" in the Table of Fictional Cast Members;

now the met entry is true;

end if;

If the player is in the Tablinum for the third time and Cocky is unboinked and Cocky is not warned_about

begin;

now Cocky is boinked;

say "Your father looks up from his paperwork. 'Son,' he says, 'you're pacing like a tomcat that's just sniffed a queen in heat. You got something you want to show me?'";

end if.

Every turn during Apud Domum Macanam:

If the player is in the Tablinum and the player is not filthy and Stiffy at Sea has happened and a random chance of 1 in 3 succeeds

begin;

say "Your father glances up from his paperwork. 'Nice to see you, son, but[run paragraph on]";

if the Golden Banana of Discord is held by the player

begin;

if the Golden Banana of Discord is warned_about

begin;

say " shouldn't you be taking that banana to Eris in Olympus?'";

otherwise;

say " shouldn't you be getting that banana peeled?'";

end if;

otherwise;

say " shouldn't you be off getting that Golden Banana?'";

end if;

end if.

Every turn during Apud Domum Macanam:

if the location is the Peristyle and the location of Festus is the privy and Cocky is warned_about

begin;

say "The privy door flies open and Festus staggers out. 'Hi, Stiffy,' he grins, a little unsteadily. 'You probably don't want to go in there for a few minutes.'";

now the festus_dump_turn is the turn count + 5;

move Festus to the Peristyle;

now the flimsy door is open;

now the flimsy door is unlocked;

end if.

Every turn during Apud Domum Macanam:

if the the location of Festus is not the Privy

begin;

if the location is the Tablinum or the location is the Peristyle or the location is the Atrium or the location is the Stiffy Love Nest

begin;

if Festus is not in the location and the location of Festus is an adjacent room

begin;

let R be the best route from the location to the location of Festus, using doors;

say "Festus wanders in from [the R], grinning slyly.";

move Festus to the location;

if the location is the Tablinum, say "[line break]Festus offers a cheery wave to Cocky Makane, who replies with a curt nod.";

end if;

end if;

end if.

Every turn during Apud Domum Macanam:

if the the location is a sewer_room and the location is not Beneath the Privy and the location is not Sewer_Mouth

begin;

if a random chance of 1 in 12 succeeds, say "A gush of sewage pours from a hidden pipe somewhere overhead, splattering you with filth.";

end if.

Every turn during Apud Domum Macanam:

if the sewer_rat is in the location

begin;

follow the adjust light rule;

if the sewer_rat is visible

begin;

if the location is Beneath the Privy

begin;

say "The sewer rat peers into the dark water, snatches something gold and shiny, and scurries off to the east.";

move the sewer_rat to Sewer1;

end if;

if the location is Sewer1

begin;

say "The rat, clutching what looks like your father's signet ring in its jaws, scuttles off to the north.";

move the sewer_rat to Sewer2;

end if;

if the location is Sewer2

begin;

say "A giant toad, the size of a three-year-old-child, looms out of the darkness and swallows the rat whole. It leers at you and hops off to the west.";

move the giant toad to Sewer3;

remove the sewer_rat from play;

really have the parser notice the giant toad;

end if;

end if;

end if.

Every turn during Apud Domum Macanam:

if the giant toad is in the location

begin;

follow the adjust light rule;

if the giant toad is visible

begin;

if the location is Sewer3

begin;

say "Scattering lesser amphibians like chaff, the giant toad hops majestically to the west.";

move the giant toad to Sewer6;

end if;

if the location is Sewer6

begin;

say "The giant toad fixes you with a beady eye. It slowly winks. 'My master,' it croaks in a hideous, glutinous voice, 'requests the pleasure of your company, as he desires to effect a business deal with you, involving the return of your familial signet ring.' It squats on the bank above the channel, grunts, and, amid a stench horrible even in the context of a feces-filled sewer, shits out an iron key. 'He hopes to see you soon,' finishes the toad, and springs into the air. Turning a somersault, and pointing its limbs like a diver, it disappears down the drain.";

remove the giant toad from play;

now the signet ring is worn by Glub;

move the iron key to the location;

really have the parser notice the iron key;

end if;

end if;

end if.

Hometown is a region. Domus Macana, Sewers, and Town are regions in Hometown.

Test to-Ostia with "Test Intro / Test Rome"

Test Lovenest with "X Nightstand / Read quotations/ Read quotations / Take lamp / Remove toga/ Pour oil on cock / Get up / Wear toga".

Test Ostia with "Test Lovenest / E / N / N/ S /Test Cocky / N / Test Festus / N / Test sewers / E / E / N / N / N / Remove toga / Fuck mouth / Wear toga / N / Put token in toilet / G / Get ring / Wear ring / S / S / S / S / W / W".

Test Cocky with "Ask cocky about himself / ask cocky about ring / ask cocky about jupiter / remove toga / kiss cocky / wear toga / ask cocky about ring / ask cocky about jupiter".

Test Festus with "Ask Festus about me / ask festus about ring / ask festus about anus / ask festus about sewers ".

Test Sewers with "D / E / Remove toga / N / W/ W/ Get key / E / E / E / S / S / W / W/ W / Unlock grate with key / N / Ask Glub about ring / S / W / Wear toga / U"

Test min-ostia with "e/n/remove toga/ask cocky about ring/n/s/ask festus about ring/n/z/n/d/e/n/w/w/get key/e/e/e/s/s/w/w/w/unlock grate with key/n/ask glub about ring/s/w/wear toga/u/e/e/n/n/n/n/put token in toilet/g/get ring/wear ring/s/s/s/s/w/w".