# Stiffy Makane: Apocolocyntosis — 168 of 235

## One of the Bruces and Drunken Bastard

Release 1

- Home page
- Beginning
- Previous
- Next

Part Three - "Stetson's Garden"

Chapter One - "Garden"

The Garden is west of the Unreal City. The description is "This is a charming little English garden, surrounded by a white picket fence, with a little enamelled cast-iron bench[if the stone snail is in the garden] next to a statue of a snail[end if]. A bed of roses flanks a riot of chrysanthemums. [if Cerberus is not infighting]A lilac bush blooms from a small raised mound[otherwise]Scattered earth is strewn about the garden[end if]. The Unreal City lies back to the east." Instead of going outside in the Garden, try going east. Instead of digging in the Garden:

if Stetson is in the Garden, instead say "Stetson smacks you upside the head before you can dig. 'Don't be diggin[apostrophe] up my garden, bwah!' he shouts.";

say "Cerberus growls at you. If there are any more bones in the garden, he seems to imply, they're also his. You stop."

Some roses are scenery in the garden. The description is "Several rose bushes in various shades of red and white." Understand "garden", "flowers", "flower", "rose", "red", "bush", and "bushes" as the roses. Instead of taking the roses, say "The thorns look sharp, and you have no particular desire to vandalize the garden."

Instead of smelling the roses: say "The roses smell just like roses. What did you expect, lilacs?" Instead of digging the roses, try taking the roses.

Some mums are scenery in the garden. The description is "Crysanthemums blossom, a profusion of gold and orange." Understand "garden", "riot", "mums", "flowers", "mum", "flower", "crysanthemum", "chrysanthemums", "profusion", "chrysanth", "chrysanthema", "gold", "orange", and "yellow" as the mums. Instead of smelling the mums: say "The chrysanthemums don't really smell like much." Instead of taking the mums, say "The crysanthemums are fine just where they are." Instead of digging the mums, try taking the mums.

The stone snail is scenery in the garden. The description is "It's a statue of a snail, about two feet high, made from some sort of greenish stone." Understand "snail", "statue", "sculpture", "stone", "green", "speedy", and "greenish" as the stone snail.

Instead of taking the snail: say "Yes, because what every hero needs is a fifty-pound stone snail to carry around. Did I say yes? I meant no."

Instead of rubbing the stone snail: say "You stroke the snail. [if Stetson is in the location]Stetson glares at you suspiciously, but says nothing. [end if]Nothing much happens."

It is a supporter. It is enterable. Before entering the stone snail:

if Stetson is in the location, instead say "'I dunno about where you're from, bwah,' drawls Stetson, 'But around [italic type]here[roman type] you ask a man afore ploppin[apostrophe] your butt on his snail. And don't bother. Answer's no.'".

The cast-iron bench is a supporter in the garden. It is scenery. The description is "A functional, but unremarkable, enamelled cast-iron bench. It is cheery and white." Understand "little", "small", "white", "iron", "cast-iron", "enamel", and "enamelled" as the cast-iron bench. It is enterable.

The lilac bush is scenery in the garden. The description is "The lilacs are in bloom, springing from a small raised mound." After examining the lilac bush for the first time, say "Stetson fidgets nervously." Understand "garden" and "lilacs" as the lilac bush. Instead of taking the lilac bush: say "Leave the lilacs where they are." Instead of smelling the lilac bush for the first time, say "The lilacs smell just like lilacs. What did you expect, roses? Although, oddly, there's a hint of something else. Stetson coughs." Instead of smelling the lilac bush for the second time, say "The lilacs smell like lilacs, but there's a definite stench of rotting flesh mixed in with them. Yuck. A tuneless humming comes from Stetson's direction." Instead of smelling the lilac bush for the third time, say "You know, it's really hard to enjoy the scent over all the rotting meat. Stetson suddenly kicks the leg of the cast-iron bench, with a clanging noise." Instead of smelling the lilac bush: say "You'd really rather not, at this point." Instead of digging the lilac bush, try taking the lilac bush.

The mound is scenery in the garden. The description is "A small raised mound supports the lilac bush." After examining the mound for the first time, say "Stetson fiddles with the snail statue." Instead of smelling the mound for the first time, say "Ugh. You're pretty sure something's buried under there. A strange choking noise comes from Stetson." Instead of smelling the mound, say "You really would prefer not." Understand "grave" as the mound.

The dead arm is scenery. The description is "This is a moldering corpse's right arm, detached at the bicep." Instead of doing anything other than examining with the arm:

If Cerberus is in the location

begin;

say "The dog seems to have a better claim on it than you do.";

otherwise;

say "Ew.";

end if. Understand "moldering", "corpse", "bicep", and "corpse's" as the dead arm.

The scattered earth is scenery. The description is "Scattered earth is strewn about the garden." Understand "mud" and "dirt" as scattered earth. Instead of digging the scattered earth, say "There's not much point."