# Stiffy Makane: Apocolocyntosis — 211 of 235

## One of the Bruces and Drunken Bastard

Release 1

- Home page
- Beginning
- Previous
- Next

Volume Nineteen - "Stiffy Storms Heaven"

Book One - "Mechanisms"

Olympic Slopes is a region in Macedonia. A mountain room is a kind of room. A mountain room has a number called the chill factor. The chill factor of a mountain room is usually 15.

Stiffy Storms Heaven is a recurring scene. Stiffy Storms Heaven begins when the location is in Olympic Slopes. Stiffy Storms Heaven ends when the location is not in Olympic Slopes.

When Stiffy Storms Heaven begins:

now the coldness of Stiffy Makane is 0.

When Stiffy Storms Heaven ends:

if the coldness of Stiffy Makane is greater than 0, say "Warmth seeps back into your bones, and your chill soon evaporates.";

now the coldness of Stiffy Makane is 0.

Every turn during Stiffy Storms Heaven:

increase the coldness of Stiffy Makane by the chill factor of the location;

repeat with G running through garments worn by Stiffy Makane

begin;

decrease the coldness of Stiffy Makane by the warmth of G;

end repeat;

let C be the coldness of Stiffy Makane;

if C > 0 and C < 50, say "You're a little bit chilly.";

if C > 49 and C < 100, say "Your teeth are chattering, and you are shivering with the cold.";

if C > 99 and C < 150, say "Your extremities are numb with the cold, and every motion is torment.";

if C > 149 and C < 190, say "You are staggering and stumbling with the cold. Your frozen brain manages to point out to you that you are in an extremely dangerous predicament.";

if C > 189, end the story saying "You have frozen to death."

Olympic_cloud_scenery is sky_scenery. It is in Olympic Ridge, Saddle, Southern Peak, Skolio, Scala, Cirque, and Perilous Ledge. The description is "Dense cloud shrouds everything in icy white fog. Frigid wind knifes through you, chilling any exposed skin." Understand "sky", "clouds", "cloud", "dense", "icy", "fog", "frigid", "cold", "wind", and "white" as Olympic_cloud_scenery. The printed name is "cloud".

Snowcover is a backdrop. It is in Olympic Ridge, Saddle, Southern Peak, Skolio, Scala, Cirque, and Perilous Ledge. The description is "Treacherous patches of ice and snow crunch and crackle underfoot." Understand "ice", "snow", "cover", "treacherous", "patches", "crunch", "cruncy", "crackle", "crackly", and "ground" as snowcover. The printed name is "snow cover".

Test climbing with "n / n / w".