# Stiffy Makane: Apocolocyntosis — 192 of 235

## One of the Bruces and Drunken Bastard

Release 1

- Home page
- Beginning
- Previous
- Next

Chapter Two- "Tantalus"

Tantalus is a man in the Muddy Field. "Buried almost to its chin in the mud is a human head[37 as a reference]." The description is "Other than being buried in mud to his chin, the head is reassuringly normal. His hair and mustache [italic type][bracket]sic[close bracket][roman type] are a matted brown, perhaps from genetics, perhaps from mud. Rivulets of water run down his creased face." The printed name of Tantalus is "the human head". Understand "man", "human", "head", "brown", "hair", "mustache", "moustache", "Stephen", "Granade", and "Stephen Granade" as Tantalus. The conversation of Tantalus is the Table of Tantalus's Chatter. The default reply of Tantalus is "The head [if Tantalus is unboinked]glares sullenly[otherwise]blinks owlishly[end if] at you." Tantalus has a virginity. Tantalus is unboinked.

The Tantalus-taunt-counter is a number that varies. The Tantalus-taunt-counter is 0.

After examining Tantalus:

if Tantalus is unboinked

begin;

Increase the Tantalus-taunt-counter by 1;

if the Tantalus-taunt-counter is 1

begin;

say "'Come to gloat?' the man says. 'Why not? After all, you put me here.' How odd. Did you? Anyway, you're pretty sure this is Tantalus.";

now Tantalus is handled;

now the printed name of Tantalus is "Tantalus";

end if;

if the Tantalus-taunt-counter is 2, say "'That's right, try to deny it. If it weren't for you, I'd still be safe.'";

if the Tantalus-taunt-counter is 3, say "The man laughs softly. 'Not long now.' He grins sarcastically. 'An interesting end, don't you think? Jiminy Cricket never had such an exit scene.'";

if the Tantalus-taunt-counter is 4, say "Resignation and more than a little bitterness fill the man's face. 'Go on,' he says. 'You've work to do, pieces to recover.' He pauses, then yells, 'Go on, I said!' Then, muttered, 'You've ignored me too long to do anything about it now.'";

end if.

Instead of kicking or attacking Tantalus for the first time, say "A pointed rumble of nearby thunder dissuades you."

Instead of kicking or attacking Tantalus:

say "The head's eyes widen as you draw your foot back. 'Stiffy, no, please, oh gods you can't[emdash]' His cries are cut short as your foot slams into him. With the sound of eggshells cracking, the head fragments into countless pieces which are quickly lost in the mud.";

remove Tantalus from play;

say "[paragraph break][paragraph break]Suddenly you sink into the mud yourself. Up to your neck, in fact. It's a long few centuries until someone kicks your own head in.";

end the story saying "You have been enmired".

Instead of pulling Tantalus:

say "You lean over him, place your hands over his ears, and pull. He shrieks in pain, eyes squeezed shut. You quickly determine that he cannot be pulled free of the mud. When you let go the man's ears are bright red."

Instead of pushing Tantalus:

say "You lean over him, place your hands on his forehead, and push. Hard. He screams, eyes squeezed shut, as you bear down on his head. When you stop you see that you have left a fiery red handprint on his forehead which is slow to fade."

Instead of digging Tantalus:

say "You kneel and begin scooping mud from around the head with both hands. As fast as you remove the mud, more mud and water return. 'Forget it,' the man says gruffly. 'It's too late now.' He seems strangely touched by your attempt, however."

Check taking Tantalus:

instead say "You grab hold of his ears, but before you can pull, the head says, 'It's no good now. I'm done for.' His eyes narrow at you. 'The least you can do is feel guilty.'"

Instead of kissing, fucking, sucking, rubbing, touching, wanking off, or blowing Tantalus, say "The mud coating him makes you think twice."

Instead of showing or giving the umbrella to Tantalus when Tantalus is unboinked, say "The man snarls, 'I'm not going to hold it in my teeth.'"

Instead of showing the hat to Tantalus when Tantalus is unboinked, say "The man sneers. 'Yee-haw. Do I look like a cowboy to you?'"

Instead of giving the hat to Tantalus when Tantalus is unboinked, say "The hat slips down over the head's eyes, and the head bellows imprecations at you until you retrieve it."

Instead of giving or showing the wineskin to Tantalus when Tantalus is unboinked, say "The head spits. 'Hey, some diabetic harpy called. She wants her menses back.'"; [1]

Instead of showing the fine Falernian wine to Tantalus, say "The head glares at you. 'Nice. It's not enough to put me here, now you have to taunt me. Blow me.'"

Instead of pouring the fine Falernian wine on Tantalus, try giving the wine to Tantalus.

Instead of giving the fine Falernian wine to Tantalus:

now Tantalus is boinked;

remove the fine Falernian wine from play;

really have the parser notice the jug of vinegar;

say "You hold the bottle to the head's lips and pour. He guzzles the wine greedily. After the last drop is consumed, you drop the bottle into the mud, where it disappears. [paragraph break]'Whoa, thanks,' says the man. He smacks his lips and belches. 'Take the vinegar if you want it. I don't care.'".

Instead of showing or giving something to Tantalus:

if Tantalus is boinked

begin;

say "The head rolls its eyes blearily. 'Don't care.'";

otherwise;

say "The man rolls his eyes. 'Is that the best you can think of?'";

end if.

Instead of asking Tantalus about anything when Tantalus is boinked, say "The head drunkenly chants 'La-la-la! I can't hear you; I've got mud in my ears! La-la-la!'".

Table of Tantalus's Chatter

topic | reply | summary | turn stamp
"himself/man/head" | "'I'm Tantalus. Stuck in the mud forever. Somehow your fault. Can't get a drink. Sucks.'" | "he is Tantalus, and would really like a drink" | a number
"Terry/Stephen/Granade/smoking/cigarette/cigarettes/nicor/cessation" or "stephen granade" | "'Oh, aren't we clever,' sneers the head, 'with our oh-so-precious interextuality and our encyclopedic knowledge of classic post-Infocom interactive fiction. You really are a dickhead, you know.'" | "he didn't appreciate your metagame referentiality" | --
"drink/wine/bottle" or "bottle of wine" | "The head groans, 'Oh, could I ever use a drink.'" | "he's really thirsty" | --
"mud/rain" | "He says, 'If only the rain would stop...'" | "he's tired of the rain" | --
"umbrella" | "'Can't hold it. Assjack.'" | "he has no way to hold an umbrella" | --
"vinegar/jug" or "jug of vinegar" | "'Only there to taunt me.'" | "the jug of vinegar taunts him" | --
"wineskin/rotgut" | "'Pflgh!'" | "he's particular about his wine" | --
"Syra" | "'Dirty slut! Wish she were here.'" | "he'd like Syra to visit" | --

Note

[1]. Too bad we can't actually ever get here.