# Stiffy Makane: Apocolocyntosis — 214 of 235

## One of the Bruces and Drunken Bastard

Release 1

- Home page
- Beginning
- Previous
- Next

Book One - "Summit"

Summit is a room in Olympus. It is west of Perilous Ledge and north of Skala. The description is "You stand at the summit of Olympus. This small meadow is bright, warm and sunny, although a roiling cloudbank lies below you. A bridge of crystal stretches into the sky towards the north, rising into what appears to be a collection of palaces floating, incredibly, in the sky. A steep path descends to the south, and an almost vertical gully to the east." Before going east in Summit:

consider the spurning-the-goddess rule;

if the walking stick is not held by the player

begin;

say "No sooner do your feet encounter the icy stones at the edge of the cloudbank than you lose your footing and plummet, screaming, to your death.";

end the story saying "You have fallen to your death";

otherwise;

say "With the aid of your trusty walking stick you descend into the clouds.";

end if.

Before going south in Summit:

if the walking stick is not held by the player, instead try going east;

consider the spurning-the-goddess rule;

say "With the aid of your walking stick, you pick your way down the treacherous talus slope."

Instead of going up in Summit, try going north. Instead of going down in Summit, say "Paths descend both to the south and east."

The scenery_cloudbank is scenery in Summit. The printed name of scenery_cloudbank is "cloudbank". Understand "storm", "stormcould", "stormclouds", "cloud", "clouds", "gray", "grey", "roiling", "bank", and "cloudbank" as the scenery_cloudbank. The description is "Below you, gray stormclouds roil." Instead of doing anything other than examining with the scenery_cloudbank, say "The cloudbank is too far away."

The scenery_castle is scenery in Summit. The printed name is "floating city". Understand "floating", "city", "ornate", "palace", "palaces", "olympus", "incredible", "gods", "god", "flying", and "castle" as the scenery_castle. The description is "Impossibly, a city of ornate palaces floats suspended in the air off to the north."

Some eskimos are scenery_figurines on the Great Table. The name is "some random Siberian hunters". Understand "siberian", "random", "hunter", "hunters", "eskimo", "eskimos", "esquimaux", "tribe", and "inuit" as the eskimos. They are male.

Test olympus with "e / give banana to eris / ask eris about argus / w / w / ask anas about argus / x mosaic / g / e / n / x caesar / ask caesar about himself / ask caesar about rome / ask caesar about argus / kiss caesar / wear sunglasses / n".