# Stiffy Makane: Apocolocyntosis — 141 of 235

## One of the Bruces and Drunken Bastard

Release 1

- Home page
- Beginning
- Previous
- Next

Part Four - "Western Ridge and Lakeshore"

West Side of Chasm is a room. It is west of the footbridge. "A faint path leads away from the chasm into the jungle to the west, climbing sharply. The jungle presses in from the north and south. To the east, a rickety footbridge spans the canyon." Instead of going down in West Side of Chasm, consider the stream-warning rule. Instead of going up in West Side of Chasm, try going west. Instead of going north in West Side of Chasm, try entering the dense jungle. Instead of going south in West Side of Chasm, try going north. Before going east in West Side of Chasm, say "You gingerly tiptoe across the bridge, holding on to the handrail cable for dear life."

Before going west in West Side of Chasm, say "After a long and exhausting climb through dense forest, and then a perilous scramble up a talus slope, you finally attain the summit of the pass."

Mountain Pass is west of West Side of Chasm. "From here, the landscape falls away to east and west. East of you is a valley, with a stream plummeting through a ravine, and beyond that, another ridge. At a pass at the top of that ridge, you can just make out the whitened ribcage of a colossal elephant. To the west, the path descends to a spit of land protruding into a large lake perhaps a quarter mile across and a mile long. Sheer craggy cliffs form the ridgeline north and south." Instead of going north in Mountain Pass, try going south. Instead of going south in Mountain Pass, say "You can't see any way to climb the peaks." Instead of going down in Mountain Pass, say "The path descends to both the east and the west."

The scenery_ridge_2 is a backdrop in Mountain Pass. It is in the Plateau. It is in Up a Tree. The description is "Far away to the east, you can see a ridge, a winding path, and at the summit, a white dot that you know to be a weathered elephant's ribcage." The printed name is "ridge". Understand "ridge", "path", "winding", "windy", "summit", "dot", "ribcage", "elephant", "elephant's", "weathered", and "pass" as the scenery_ridge_2.

The adventurer's skeleton is a thing in Mountain Pass. "A skeleton, probably the remains of a luckless adventurer[76 as a reference], bleaches in the sun here." The description is "The skeleton stares with sightless eyes, [if the rusty machete is not handled]its bony fingers still clutching a rusty machete[otherwise]mutely accusing you of the theft of its machete[end if]." Check taking the skeleton: instead say "You don't really have a use for the adventurer's skeleton." Understand "dead", "skull", "eyes", "sightless", "bleached", "sun-bleached", "bleaching", "bleachy", "remains", "luckless", "fingers", "bones", "bone", and "corpse" as the adventurer's skeleton. Instead of smelling or tasting the adventurer's skeleton, say "Nothing but sun-bleached bones." Instead of rubbing or touching the adventurer's skeleton, say "The bones are smooth." Instead of wanking off, blowing, or sucking the adventurer's skeleton, say "Not that sort of bone."

The rusty machete is a thing in the Mountain Pass. "The skeleton's fingers clutch a rusty machete." The description is "The machete has seen better days, but it still has an edge of sorts, and could probably be used to do some chopping." Understand "knife", "chopper", and "sword" as the rusty machete. Before taking the rusty machete for the first time, say "You carefully pry the dead adventurer's fingers from the machete."

The Palm Grove is west of the Mountain Pass. "You stand in a grove of coconut palms. A spit of land extends out into the lake farther to the west, and an obvious trail leads north and south." Instead of going up in the Palm Grove, say "You can't get a good grip on the slick bark of any of the trees."

The scenery_coconut_palms are scenery in the Palm Grove. The description is "Ten or so palms grow here. None of their coconuts seem ripe yet." Understand "tree", "trees", "coconuts", "palm", "palms", "slick", "bark", "tough", "scratchy", and "ten" as the scenery_coconut_palms. The printed name is "coconut palms". Instead of touching or rubbing the scenery_coconut_palms, say "The bark is tough and scratchy, but fairly slick." Instead of climbing the scenery_coconut_palms, try going up. Instead of climbing in the Palm Grove, try going up. Instead of pushing or pulling the scenery_coconut_palms, say "You shake a tree, but no coconuts fall down."

The coconut is a jungle yummy in the Palm Grove. The initial appearance is "A brown, hairy coconut lies on the ground under the palm trees." The description is "It's a brown and hairy coconut, about the size of two fists together." Understand "brown", "husk", "rough", and "hairy" as the coconut. Instead of smelling the coconut, say "The husk doesn't smell like much of anything." Instead of attacking the coconut with the rusty machete:

say "You split the coconut open with the machete, drink the delicious coconut water, eat the succulent coconut flesh, and toss away the husk.";

really have the parser notice the machete;

remove the coconut from play.

Instead of eating the coconut:

if the rusty machete is held by the player, instead try attacking the coconut with the rusty machete;

say "You lack the teeth that would be necessary to split the coconut so you can eat it."

Instead of rubbing or touching the coconut, say "The coconut is rough and hairy."

Instead of tasting the coconut, say "The husk is flavorless."

The Melon Patch is north of the Palm Grove. "This is a small clearing in the jungle, overgrown with melon vines; a path leads back to the coconut grove to the south; the lake is to your west, and jungle surrounds you to the north and east." Instead of going east in the Melon Patch, try going north. Instead of going north in the Melon Patch, try entering the dense jungle.

Some scenery_melon_vines are scenery in the Melon Patch. The description is "The vines twist and tangle[if the muskmelon is in the location and the muskmelon is not handled], almost concealing a ripe melon[end if]." Understand "vine", "melon", "vines", "twist", "tangle", "twisted", and "tangled" as the scenery_melon_vines. The printed name is "vines". Instead of taking the scenery_melon_vines, say "You have no real desire to start uprooting the vines." Instead of attacking the scenery_melon_vines with the rusty machete, say "[if the muskmelon is in the location and the muskmelon is not handled]You can just take the melon, you know; no need to cut the vines to do so[otherwise]You have no real desire to hack up the vines[end if]." Instead of tasting, smelling or eating the scenery_melon_vines, say "The vines themselves have no real odor or flavor." Instead of searching the scenery_melon_vines, say "[if the muskmelon is in the location and the muskmelon is not handled]Well, there's a ripe melon on the vines[otherwise]No more ripe melons are readily apparent[end if]."

The muskmelon is a jungle yummy in the Melon Patch. The initial appearance is "Nestled among the vines, you spy a ripe muskmelon." The description is "This is a ripe muskmelon, about the size of a human head[if the muskmelon is warned_about] with a small hole from which juice dribbles[end if]." Understand "ripe", "delicious", "musk", "musky", "cantaloupe", "honeydew", and "melon" as the muskmelon. It has a virginity. It is unboinked. Instead of eating the muskmelon:

say "You [if the rusty machete is held by the player]slice[otherwise]bash[end if] the melon open and greedily gobble its contents. It's delicious.";

remove the muskmelon from play;

remove the muskmelon_hole from play;

remove the muskmelon_juice from play;

Instead of attacking the muskmelon with the rusty machete:

if the muskmelon is not warned_about

begin;

say "You cut a small hole out of the muskmelon. Juice dribbles out.";

now the muskmelon is warned_about;

now the muskmelon_hole is part of the muskmelon;

now the muskmelon_juice is part of the muskmelon;

otherwise;

now the muskmelon is not_warned_about;

remove the muskmelon from play;

remove the muskmelon_hole from play;

remove the muskmelon_juice from play;

say "You hack the muskmelon into hundreds of tiny pieces in a frenzy of chopping.";

end if.

Before cutting the muskmelon:

if the rusty machete is held by the player, instead try attacking the muskmelon with the rusty machete.

Instead of attacking the muskmelon:

if the rusty machete is held by the player, instead try attacking the muskmelon with the rusty machete;

if the muskmelon is not warned_about

begin;

say "You punch a small hole out of the muskmelon with your thumb. Juice dribbles out.";

now the muskmelon is warned_about;

now the muskmelon_hole is part of the muskmelon;

now the muskmelon_juice is part of the muskmelon;

otherwise;

now the muskmelon is not_warned_about;

remove the muskmelon from play;

remove the muskmelon_hole from play;

remove the muskmelon_juice from play;

say "You bash the muskmelon into hundreds of tiny pieces in a frenzy of violence.";

end if.

Before fucking the muskmelon:

if the muskmelon is warned_about, instead try fucking the muskmelon_hole.

Does the player mean doing something with the muskmelon: it is likely.

Instead of smelling the muskmelon, say "Musky. Hence the name."

The muskmelon_hole is a thing. The printed name is "hole". Understand "hole" as the muskmelon_hole. The description is "A small hole, a little larger than your thumb, pierces the melon."

Check taking the muskmelon_hole: instead try fucking the muskmelon_hole.

Instead of fucking or buggering the muskmelon_hole:

if the stiffycock is not visible, instead say "You are not undressed for the occasion.";

if the muskmelon is boinked, instead say "While a tremendously rewarding experience, fucking one melon was plenty.";

say "You begin thrusting into the hole you have made into the muskmelon. The heat of the sun-warmed melon flesh against your cock is magnificent, and the sticky, syrupy wetness of the melon only adds to the ecstasy of the moment. Finally you ejaculate with a convulsive shudder, and crush the melon to pieces between your hands as you do so.";

now the muskmelon is not_warned_about;

remove the muskmelon from play;

remove the muskmelon_hole from play;

remove the muskmelon_juice from play;

now the muskmelon is boinked;

record "a muskmelon" as achieved.

The muskmelon_juice is a thing. The muskmelon_juice can be drinkable. It is drinkable. It is edible. The printed name is "juice". Understand "juice" as the muskmelon_juice. Check taking the muskmelon_juice: instead try drinking the muskmelon_juice. Instead of tasting or drinking the muskmelon_juice, say "The juice is sweet and delicious." Instead of examining the muskmelon_juice, say "A little juice dribbles down the side of the muskmelon."

The Cane Field is south of the Palm Grove. "The ground is a little swampy here. Sugar cane grows in great profusion. The lake lies below you to the west, and jungle rises to the east and south." Instead of going east in the Cane Field, try going south. Instead of going south in the cane field, try entering the dense jungle.

The scenery_sugar_cane is scenery in the Cane Field. The description is "Stands of sugar cane grow in the swampy field. The canes rise about eight feet high, and some are three inches in diameter." Understand "sugar", "cane", "canes", "stalk", "stand", "stands", "stalks", "field", "eight", "high", "feet", "three", "inches", "diameter", "inch", "tough", and "plant" as the scenery_sugar_cane. The printed name is "stalks of sugar cane". Instead of cutting the scenery_sugar_cane:

if the rusty machete is held by the player, instead try attacking the scenery_sugar_cane with the rusty machete;

try attacking the scenery_sugar_cane.

Instead of attacking the scenery_sugar_cane with the rusty machete:

if the sugar cane is in the location, instead say "You've already cut one length of cane, and feel no immediate need for another.";

say "You hack at the sugar cane with your machete, and soon succeed in cutting five feet or so of its stalk free.";

move the sugar cane to the location.

Instead of taking, pushing or pulling the scenery_sugar_cane, try attacking the scenery_sugar_cane.

Instead of attacking the scenery_sugar_cane, say "The cane is sharp and firmly-rooted, and you come off second-best."

Instead of attacking the scenery_sugar_cane with something, say "Try as you might, [the second noun] is no match for the tough stalks of the sugar cane."

The sugar cane is a jungle yummy. The description is "This is a length of sugar cane, cut to five feet or so." It is edible. Instead of eating, tasting, or sucking the sugar cane, say "You suck on the cane a while; it is sweet and cloying, but very tasty." Does the player mean doing something with the sugar cane: it is likely. Instead of rubbing or wanking off the sugar cane, say "Stroke it as you might, you are unable to cause syrup to spurt from the cane."

The Spit of Land is west of the Palm Grove. "You stand on a peninsula extending almost to the middle of the lake, which extends to the west, north, and south. The western shore is perhaps two hundred yards distant, while the northern and southern shores are each about half a mile away." Instead of swimming around in the Spit of Land: if the noun is a direction and the noun is not east, try going the noun. Instead of swimming in the Spit of Land, say "You could swim to the north, west, or south."

Before going north in the Spit of Land:

now the encumbered action is "swimming";

consider the jungle encumbrance rule;

if rule failed, stop the action.

Before going south in the Spit of Land:

now the encumbered action is "swimming";

consider the jungle encumbrance rule;

if rule failed, stop the action.

Before going west in the Spit of Land:

now the encumbered action is "swimming";

consider the jungle encumbrance rule;

if rule failed, stop the action.

The scenery_african_lake is a backdrop in the Spit of Land. It is in the African Lake. It is in North Shore of the Lake. The printed name is "lake". The scenery_african_lake can be drinkable. It is drinkable. The description is "The water is murky, brown, and deep." Understand "lake","water","dark","deep", "murky", "muddy", and "brown" as the scenery_african_lake. Instead of tasting or drinking the scenery_african_lake, say "The water tastes slightly muddy." Instead of digging the scenery_african_lake, say "Digging in water would be a neat trick, wouldn't it?" Instead of swimming around in the scenery_african_lake, try swimming. Instead of jumping into or diving into the scenery_african_lake:

if the location is Spit of Land, instead try swimming;

say "You're soaking in it[77 as a reference]."

Instead of going south in the Spit of Land:

say "You swim blithely south, straight into the mouth of a waiting crocodile.";

end the story saying "You have been eaten by a crocodile".

Instead of going west in the Spit of Land, consider the python-gulping rule.

This is the python-gulping rule:

say "You strike out for the western shore. It's not far, and you reach it easily. As you begin to pull yourself up on some roots at the shoreline, a huge snake drops down from the trees above and engulfs you.";

end the story saying "You have been swallowed by a python".