# Stiffy Makane: Apocolocyntosis — 37 of 235

## One of the Bruces and Drunken Bastard

Release 1

- Home page
- Beginning
- Previous
- Next

Volume Three - "SPQR"

Stiffy In Rome is a scene. Stiffy In Rome begins when Slowly Drowning ends flashbackily. Stiffy in Rome ends when the apple is boinked. When Stiffy in Rome ends:

say "Swiftly dressing, you return home to your family's house in Ostia to plan your quest for the Golden Banana of Discord...[paragraph break][paragraph break][paragraph break]";

follow the major-scene-change rule;

now the toga is worn by the player;

remove the stiffycock from play;

move sewage to Sewers;

move sewer_ceiling to Generic_Sewers;

really have the parser notice the plain wooden door;

move the player to the Stiffy Love Nest.

Populated_Rome is a region. The Forum and the Via Sacra are rooms in Populated_Rome.

Rome is a region. Populated_Rome is in Rome. The Curia Steps, the Curia Interior, the Temple of Eris, the Altar of Eris, the Temple of Jupiter Virilis, the Twisty Little Alley, the Artist's Hut, the Phallus Interior, and the Seedy Tavern are in Rome.

Every turn during Stiffy In Rome:

if the bottle of wine is off-stage, move the scenery_wine to the Seedy Tavern;

if the location is in Populated_Rome, move the roman_pbs to the location;

if the location is in Populated_Rome, move the not_really_pbs to the location;

if the location is the Phallus Interior for the first time

begin;

choose a row with a character of "Julia" in the Table of Fictional Cast Members;

now the met entry is true;

end if;

if the location is the Temple of Eris for the first time

begin;

choose a row with a character of "The Golden Apple" in the Table of Fictional Cast Members;

now the met entry is true;

end if;

if the roman_pbs are in the location and a random chance of 1 in 5 succeeds and the number of rows in the Table of Roman Occurrences is greater than 1

begin;

choose a random row in the Table of Roman occurrences;

if the description entry is not "placeholder"

begin;

say "[description entry][paragraph break]";

blank out the whole row;

end if;

end if;

if the location is the Seedy Tavern and a random chance of 1 in 4 succeeds

begin;

if a random chance of 1 in 2 succeeds, say "A drunkard begins to sing an obscene song, but can't remember the words, and lapses into besotted silence.";

otherwise say "An eructation, a whiff of sour wine, a splash, a thump, and stentorian snores signify the end of someone else's drinking evening.";

end if.

Every turn during Stiffy In Rome:

if the stiffycock is held by the player

begin;

if the player is in the Phallus Interior and Julia is on the Altar

begin;

if Julia is not_warned_about

begin;

now Julia is warned_about;

say "Julia blushes. 'Cover up that thing or I'll scream,' she warns you.";

otherwise;

say "Julia points at your exposed penis and screams, just like she said she would. Jupiter Virilis is not amused. A swift lightning bolt reduces you to a pile of greasy ash on the floor.";

end the story saying "You have been incinerated";

end if;

end if;

if the player is in the Twisty Little Alley

begin;

if the aureus is not_warned_about

begin; [There's nothing special about the aureus; it just had an unused property we could coopt]

say "Wandering around the seamier parts of the city unclothed is just begging for trouble.";

now the aureus is warned_about;

otherwise;

say "What were you told about nakedness and dark alleys?";

end the story saying "You have been raped to pieces";

end if;

end if;

if the location of the Artist is the location and a random chance of 1 in 3 succeeds, say "The artist looks at your exposed penis and rolls his eyes.";

if the location of the Priest of Jupiter Virilis is the location and a random chance of 1 in 3 succeeds, say "The priest glances at your cock and gulps hurriedly at his wine.";

if the location of Caesar's friends is the location and a random chance of 1 in 3 succeeds

begin;

let T be "Naughtius Maximus";

if a random chance of 1 in 2 succeeds, now T is "Biggus Dickus";

if a random chance of 1 in 3 succeeds, now T is "Magnus Prickus";

say "One of the sycophants[emdash][T], you think[emdash]gives you two thumbs up and an 'OK' sign.";

end if;

if the roman_pbs are in the location and a random chance of 1 in 2 succeeds, say "You notice passers-by, male and female, checking out your junk, some with approving nods, some with pursed lips and angry frowns.";

end if.

Every turn during Stiffy In Rome:

if the location is the Phallus Interior and Slutty_Julia is on the Altar and the stiffycock is not lit and a random chance of 1 in 2 succeeds

begin;

if Slutty_Julia is unboinked

begin;

say "Julia [if the stiffycock is visible]stares hungrily at your penis and [end if]whispers huskily, 'Jupiter doesn't mind if I see other people now.'";

otherwise;

if the nosejob_hints of Slutty_Julia is 0, say "Julia murmurs, 'I wonder if a girl can get a nose job around here?'";

if nosejob_hints of Slutty_Julia is 1, say "Julia taps her enormous nose ruminatively. 'How hard,' she asks of no one in particular, 'can it be, to blow a girl's nose?'";

if nosejob_hints of Slutty_Julia is greater than one, say "Julia declaims: 'Oh, Divine Jupiter, what will it take for this fool to [fixed letter spacing]GIVE A NOSE JOB TO JULIA[variable letter spacing]?'";

increase nosejob_hints of Slutty_Julia by 1;

end if;

end if.

Table of Roman Occurrences

description
"placeholder"
"A man and a woman have a brief screaming match, which escalates into a shoving match. Then they storm off in opposite directions."
"A juggler with a monkey on a leash passes through the crowd, the monkey catching coins that passers-by fling."
"Driven by a cruel-looking legionnaire with a whip, a string of miserable prisoners in chains is marched past."
"You are nudged to one side as a curtained sedan chair charges through the crowd, six gasping German slaves propelling it at a dead run towards some unknown destination."
"A small knot of arguing senators wanders past in their purple-striped togas, surrounded by menacing bodyguards with clubs."
"In the distance, a mustachioed Gaul with a despondent bear on a chain briefly coaxes it into a shambling dance. The crowd cheers."

Test Rome1 with "W/ W/ Test Julia/ E/ E/ N"

Test Rome2 with "Test Caesar/ N/ Get Bag/ S/ S/ E"

Test Rome3 with "E/ E/ Test Artist/ W/ N/ Test Priest/ S/ W/ W/ W/ W"

Test Rome4 with "Test sluttyjulia/ E/ E/ S/ S/ Test Apple"

Test Rome with "Credits / Test Rome1/ Test Rome2/ Test Rome3/ Test Rome4"

Test min-rome with "n/remove toga/fuck caesar/wear toga/n/get bag/s/s/e/e/e/give bag/give coin/w/n/give mask/s/w/w/w/w/blow nose/e/e/s/s/remove toga/fuck apple".