# Stiffy Makane: Apocolocyntosis — 200 of 235

## One of the Bruces and Drunken Bastard

Release 1

- Home page
- Beginning
- Previous
- Next

Part Seven - "Inside Building"

Inside_Building is east of End_of_Road. The printed name is "Inside Building". The description is "You are inside a building, a well house for a large spring." Outside from Inside_Building is End_of_Road. Instead of going north in Inside_Building, try going east. Instead of going south in Inside_Building, try going east. Instead of going east in Inside_Building, say "The stream flows out through a pair of 1 foot diameter sewer pipes. The only exit is to the west." Instead of going inside in Inside_Building, say "The pipes are too small."

Some kentucky_keys are things in Inside_Building. "There are some keys here." The printed name is "set of keys". The kentucky_keys unlock the kentucky_grate. The description is "It's just a normal-looking set of keys." Understand "keys", "key", "keyring", "set of keys", and "bunch" as the kentucky_keys. [ Instead of counting the keys, say "A dozen or so keys." ]

Some tasty food is a thing in Inside_Building. "There is tasty food here." It is edible. After eating the tasty food, say "Delicious!" The description is "Sure looks yummy!" Understand "ration", "rations", "tripe", "yummy", "delicious", and "scrumptious" as the tasty food.

The shiny brass lamp is a device in Inside_Building. "There is a shiny brass lamp nearby." The shiny brass lamp can be lit. It is unlit. The description is "It is a shiny brass lamp [if the lamp is lit], glowing brightly[otherwise]. It is not currently lit[end if]." Understand "headlamp", "headlight", "light", and "lantern" as the shiny brass lamp. Instead of burning the lamp, try switching on the lamp.

Carry out switching on the lamp:

now the lamp is lit.

Carry out switching off the lamp:

now the lamp is unlit.

Instead of rubbing the lamp, say "Rubbing the electric lamp is not particularly rewarding. Anyway, nothing exciting happens."

The advent_bottle is a container in Inside_Building. "There is an empty bottle here." Understand "bottle", "jar", and "flask" as the advent_bottle. The printed name is "small bottle". Instead of filling the advent_bottle:

if the advent_bottle encloses something, instead say "The bottle is full already.";

if the stream_scenery is in the location

begin;

say "The bottle is now full of water.";

move water_in_bottle to advent_bottle;

end if.

Water_in_bottle is a thing. The description is "It looks like ordinary bottled water to me." Understand "water", "bottled", and "h2o" as water_in_bottle. The printed name is "bottled water". Instead of drinking the water_in_bottle:

remove the water_in_bottle from play;

say "You have taken a drink from the stream. The water tastes strongly of minerals, but is not unpleasant. It is extremely cold."

The scenery_spring is scenery in Inside_Building. The scenery_spring can be enterable. It is enterable. The description is "The stream flows out through a pair of 1 foot diameter sewer pipes." The printed name is "spring". Understand "spring" and "large" as the scenery_spring. Instead of entering the scenery_spring, try entering the scenery_pipes.

Some scenery_pipes are scenery in Inside_Building. Some scenery_pipes can be enterable. They are enterable. They are ambiguously plural. The description is "Too small. The only exit is to the west." The printed name is "pipes". Understand "pipes", "pipe", "one", "foot", "diameter", "sewer", "sewer-pipes" as the scenery_pipes. Instead of entering the scenery_pipes, say "The stream flows out through a pair of 1 foot diameter sewer pipes. It would be advisable to use the exit."