# Stiffy Makane: Apocolocyntosis — 65 of 235

## One of the Bruces and Drunken Bastard

Release 1

- Home page
- Beginning
- Previous
- Next

Chapter Two - "Generic Sewer Rooms"

Sewer1 is a generic_sewer_room. It is east from Beneath the Privy. The description is "The sewer makes a sharp bend here, from the west to the north."

Before going west in Sewer1:

if the location of Festus is the Privy

begin;

if the sewer_rat is not warned_about

begin;

say "A gargantuan torrent of shit rains down from the west, accompanied by a hellish moaning and a truly brobdingnagian fart, vilely stinking. You cannot make headway against the stench and the wind.";

now the sewer_rat is warned_about;

otherwise;

say "A groan and a splatter of feces, combined with another gust of vile fart, remind you that venturing farther west is a bad idea at the moment.";

end if;

stop the action;

end if.

Sewer2 is a generic_sewer_room. It is north from Sewer1. The description is "The sewer makes a 'T' here: the flow comes from the east, and the downstream channel splits in two, one branch heading south and one to the west."

Sewer3 is a generic_sewer_room. It is west from Sewer2. The description is "The floor of the sewer is generally slightly higher here: the sewage forms a narrow channel between wide mud banks. Water flows in from a pipe to the north too small to fit through, and the main sewer channel continues east and west." Instead of going north in Sewer3, say "The pipe is too small for you to squeeze through[emdash]it's perhaps six inches in diameter." Before listening: if the location is Sewer3, instead say the default reply of the frogs.

The sewer_pipe is scenery in Sewer3. The printed name is "sewer pipe". The description is "It's a sewer pipe about six inches in diameter." Understand "pipe" and "sewer" as sewer_pipe.

Some frogs are animals in Sewer3. They are ambiguously plural. The description is "Thousands of frogs, or maybe they're toads, ranging in size from the nearly microscopic to the size of big cats." The initial appearance is "Thousands of frogs, or perhaps toads, blanket the muddy banks of the channel. They are croaking rhythmically." The default reply of the frogs is "'Brekekekex, ko-ax, ko-ax[52 as a reference]!'" Instead of fucking the frogs, say "The choice overwhelms you, and you don't know where to start." Instead of attacking the frogs, say "The ones you swing at leap aside into the sewer, and are swiftly replaced by others." Understand "frog", "toad", "toads", "warty", "green", "microscopic", "big", "small", and "cat-sized" as the frogs. Instead of listening to the frogs, say the default reply of the frogs. Instead of kissing the frogs, say "The odds that any of them would turn out to be a prince are, actually, not good at all." Instead of tasting or sucking the frogs, say "OH DUDE YOU'RE GETTING SO HIGH...no, not really. The frogs scatter away before you can lick them."

The giant toad is an animal. The description is "This warty monstrosity is about the size of a three-year-old child." Understand "warty", "monstrosity", "three", "year", "old", "three-year-old", and "child" as the giant toad. The default reply of the giant toad is "The toad belches contemptuously."

Sewer4 is a generic_sewer_room. It is east from Sewer2. The description is "A large drainpipe with an iron grate over the end empties into the channel flowing west. Steep, but fairly dry, steps descend to the south." Instead of going up in Sewer4, try entering the drainpipe.

The drainpipe is scenery in Sewer4. The description is "This lead pipe is about a foot in diameter, with a welded iron grate capping it. A steady flow of noisome sludge runs into the channel from it." Understand "lead", "iron", "grate", "pipe", "foot", "one-foot", "one", "welded", and "drain" as the drainpipe. The drainpipe can be enterable. The drainpipe is enterable. Instead of entering the drainpipe, say "Both the grate and the size of the drain make this impossible."

The scenery_sewer_stair is a backdrop in Sewer4. It is in sewer5. The description is "Mildewed stone stairs lead steeply down from north to south." Instead of climbing the scenery_sewer_stair in Sewer4, try going south. Instead of climbing the scenery_sewer_stair in Sewer5, try going north. Instead of going down in Sewer4, try going south. Understand "stairs", "stair", "stone", "mildew", "dry", "mildewed", "steep", "steps", and "step" as the scenery_sewer_stair.

Sewer5 is a generic_sewer_room. It is south from Sewer4. Instead of going up in Sewer5, try going north. The description is "This wide portion of the sewers is hot and steamy. A continuous cascade of warm, dirty, soapy water pours from above, and sluices off to the south. Steep stairs ascend to the north."

Sewer6 is a generic_sewer_room. It is west from Sewer3. The description is "Sewage swirls in a vortex around a drainpipe at the bottom of this circular room. The only exit is back to the east."

The scenery_vortex is scenery in Sewer6. The description is "The drainpipe appears to be about twelve inches in diameter. It is just a little too small for you to fit down, even leaving aside the fact that you'd be submerging yourself in sewage and heading down a pipe to an unknown and potentially airless destination." Understand "drain", "pipe", "drainpipe", "vortex", "whirlpool", "twelve", "inch", "inches", and "twelve-inch" as the scenery_vortex. Instead of entering the scenery_vortex, try going down. The printed name is "vortex". Instead of diving into the scenery_vortex, try going down.

The iron key is a thing. The description is "This is a rusty black iron key, about the size of your index finger." Understand "rusty", "rusted", and "black" as the iron key. Instead of smelling or tasting the iron key, say "You don't really need to, seeing as how you know it's been up a toad's ass."

Instead of going down in Sewer6 for the first time, say "You gingerly test out the edges of the drain; you really don't think you're going to fit."

Instead of going down in Sewer6:

say "With grave misgivings, you slide your feet into the drain. You drop about three feet, and then your hips get stuck. The weight of the sewage presses you farther into the drain, forming a tight seal. The level of sludge begins to rise. After an excruciatingly vile hour, your lungs fill with muck.";

end the story saying "You have drowned in sewage".

Instead of going inside in Sewer6, try going down.

Sewer7 is a generic_sewer_room. It is south from Sewer5. The description is "The heat is oppressive here; you have to duck slightly to avoid the low ceiling. The channel bends from north to west."

Sewer8 is a generic_sewer_room. It is west from Sewer7. The description is "Murky, soapy, warm sewer-water flows sluggishly from east to west along a long section of sewer pipe. The ceiling is oppressively low and you have to stoop almost double to proceed. It lowers even further to the west."

Sewer9 is a generic_sewer_room. It is west from Sewer8. The description is "You are forced to your hands and knees in the mire as you traverse this claustrophobic east-west channel."

Sewer10 is a generic_sewer_room. It is west from Sewer9. The description is "A channel of fearsomely black, fetid, viscous muck from the north flows through [if the black iron grate is closed]a closed[otherwise]an open[end if] rusty iron grate and joins the soapy flow from a cramped, low tunnel to the east here. The stream continues to the west."

The black iron grate is north of Sewer10 and south of the House_Of_Glub. The black iron grate is a door. It is closed. It is scenery. The black iron grate can be lockable. It is lockable. It is locked. The description is "The grate is huge and heavy, made of black, rusted iron. It is hinged at the walls and splits in the middle at a large lock with a keyhole in the center. The grate [if the black iron grate is open]gapes wide[otherwise]is shut[end if]. A plaque on the grate reads 'BEWARE OF GOD.'" Understand "rusty", "rusted", "lock", "plaque", "huge", and "heavy" as the black iron grate. The matching key of the black iron grate is the iron key. Before going through the closed black iron grate:

say "(first opening the grate)[line break]";

silently try opening the black iron grate;

if the black iron grate is closed, stop the action.