# Stiffy Makane: Apocolocyntosis — 163 of 235

## One of the Bruces and Drunken Bastard

Release 1

- Home page
- Beginning
- Previous
- Next

Part Three - "Cheating"

The Stiffy Makane figurine is a figurine on the Great Table. The description is "The figurine representing Stiffy Makane lies face-down in a lake in the north of Scotland. He's dead." The name is "Stiffy Makane". Before taking the Stiffy Makane figurine for the first time, say "You glance around furtively. No one seems to be watching as you pick up the figurine." The mine of the Stiffy Makane figurine is true. After taking the Stiffy Makane figurine, now the description of the Stiffy Makane figurine is "This is a rather accurately-rendered lead miniature of Stiffy Makane; he wears a toga and clutches the Golden Banana of DIscord." Understand "toga", "banana", "gold", and "golden" as the Stiffy Makane Figurine. Does the player mean doing something other than drinking with the Stiffy Makane figurine: it is very likely. It is male.

Before inserting the Stiffy Makane figurine into something:

if the second noun is Model_hades

begin;

consider the sort-of-busted rule;

if Argus is unboinked, stop the action;

otherwise;

if the second noun is not a map_locale

begin;

continue the action;

otherwise;

if the second noun is not Model_styx

begin;

instead consider the you-are-busted rule;

otherwise;

say "Dropping Stiffy Makane into the Styx is not going to help matters.";

stop the action;

end if;

end if;

end if.

Before putting the Stiffy Makane figurine on the Great Table:

consider the you-are-busted rule;

stop the action.

After inserting the Stiffy Makane figurine into the Model_hades:

remove Argus from play;

remove the god-spooge from play;

remove the blisters from play;

now the craps-point is 0;

now the description of Divine Eris is "Eris is a slightly chunky brunette, with big black wings.";

now the description of Erisian black hair is "Eris's hair is shoulder-length and black.";

now the description of the basic black dress is "It's a basic black dress. Nothing fancy.";

now the description of the big black wings is "The wings are blue-black and covered in iridescent feathers.";

say "You carefully place the figurine of Stiffy Makane upright in the Land of the Dead, and glare at the smirking Argus.";

move Stiffy Makane to the Land of the Dead;

say paragraph break;

say paragraph break;

follow the major-scene-change rule;

say "That's odd. Just a moment ago you were drowning in an icy lake. And now, you appear to be dry and, if not exactly warm, not cold either. There's a distinct lack of water in your lungs, too.";

say paragraph break;

say paragraph break;

really have the parser notice the crystal skull;

now the player is Stiffy Makane.

This is the you-are-busted rule:

if Argus is boinked

begin;

say "Argus chuckles. 'Nice try, but you have to put him in Hades. You can set him upright if you want, though.'";

otherwise;

if Argus is warned_about

begin;

say "Argus fixes you with about thirty-five steely gazes. You stop.";

otherwise;

say "As you begin to place the figure of Stiffy Makane on the table, you hear the unmistakable sound of somone clearing his throat. [run paragraph on]";

consider the howdy-argus rule;

end if;

end if;

stop the action.

This is the sort-of-busted rule:

if Argus is boinked

begin;

say "Argus grins smugly at you but doesn't stop you.";

continue the action;

otherwise;

if Argus is warned_about

begin;

say "Argus glares at you with some considerable fraction of his eyes. You cease.";

otherwise;

say "As you begin to place the figure of Stiffy Makane in Hades, you hear the unmistakable sound of someone clearing his throat. 'I see that,' a voice calls. 'I see all. And you don't get to put him upright, even in Hades. He's dead.' [run paragraph on]";

consider the howdy-argus rule;

end if;

stop the action;

end if.

This is the howdy-argus rule:

if the last place checked is 1

begin;

say "Argus straightens up from under the table[if the Great Table is handled]. 'Oh, don't look so surprised,' he says. 'I hid there while you were checking the curtains[otherwise]. 'You really ought to pay more attention to your surroundings[end if]. [run paragraph on]";

otherwise;

say "Argus steps from behind one of the green curtains[if the heavy curtains are handled]. 'I hid there while you were looking under the table, silly[otherwise]. 'As if those curtains were there for any other reason[end if]. [run paragraph on]";

end if;

say "How very, very naughty, Eris,' he gloats. 'Cheating. Cheating at the Great Game. Why, that's the sort of thing that could get you in real trouble with your fellow deities. I bet they'd be very, very angry to hear about this. Maybe there's some way,' he leers at you, 'that we could negotiate some deal so I don't tell them about it.' From between two of his many eyes, an erect penis suddenly protrudes. Argus gestures at it, and raises some of his eyebrows.";

now Argus's erection is part of Argus;

now Argus's eyes are part of Argus;

move Argus to the Game Room;

Now the description of Argus is "Hundred-eyed Argus watches you from twenty or thirty of them. An incongruous penis protrudes from between two of his eyes.";

now Argus is warned_about.

Some all_figurines are scenery_figurines on the Great Table. Understand "figurines" and "figurine" as all_figurines. The printed name is "figurines". The description is "Many figurines dot the table. You can see [if the Stiffy Makane figurine is enclosed by the Great Table]Stiffy Makane, [end if][if the Julius Caesar figurine is on the Great Table]Julius Caesar, [end if]Baldanders, a hippo, and the Mweru Bird, among others." Does the player mean doing something with the all_figurines: it is likely. They are male. Check drinking the all_figurines: instead say "Fortunately for all concerned, the ambient temperature in the Game Room is still far below the melting point of lead."

The Julius Caesar figurine is a scenery_figurine on the Great Table. The description is "Caesar lies crumpled on the Forum steps." The printed name is "Julius Caesar". The name is "Julius Caesar". It is proper-named. Understand "crumpled", "Gaius", "Gaius Julius Caesar" as the Julius Caesar figurine.

The Syra figurine is a scenery_figurine on the Great Table. The description is "You eventually find Syra entertaininga troupe of horsemen in Mongolia." The printed name is "Syra". The name is "Syra". Check taking the Syra figurine: instead say "You shudder to think of all the diseases you might catch from that figure." It is female. It is proper-named.

A hippopotamus figurine is a scenery_figurine on the Great Table. The description is "The hippopotamus is actually a small blue stuffed toy about eight inches long. It's a plush version of an Egyptian ceramic original." Understand "hippo", "William", "blue", "faience", "ceramic", "plush", "stuffed", and "toy" as the hippopotamus figurine. The printed name is "hippopotamus". The name is "hippopotamus". Check taking the hippopotamus figurine when the player is Divine Eris: instead say "You figure you've given the hippo a hard enough day already." The mine of the hippopotamus figurine is true.

Some horsemen are scenery_figurines on the Great Table. The printed name is "some random horseman". Understand "hun", "huns", "troupe", "horseman", "mongol", "mongols", "horde", "pony", and "ponies" as the horsemen. They are male.

A Mweru bird figurine is a scenery_figurine on the Great Table. The description is "At one point, there was a very impressive lead figurine of the Mweru Bird, which used to look more classically roc-like and vulture-ish. Somehow, it got lost, so now the bird is represented by a somewhat threadbare stuffed canary." Understand "canary", "threadbare", "stuffed", "vulture", "roc", and "parakeet" as the mweru bird figurine. Check taking the mweru bird figurine when the player is Divine Eris: instead say "The less you handle it, the better; one of the legs is going to fall off any day now, and you don't want to be responsible for having to put it back on." The printed name is "Mweru bird". The name is "Mweru bird". The indefinite article is "the". The mine of the Mweru bird figurine is true.

The Baldanders figurine is a scenery_figurine on the Great Table. The description is "Baldanders, the giant kilt-clad Gostak chief, brandishes his mace." Understand "huge", "kilt", "kilt-clad", "Gostak", "chief", and "mace" as the Baldanders figurine. It is male. The printed name is "Baldanders". The name is "Baldanders". It is proper-named