# Stiffy Makane: Apocolocyntosis — 48 of 235

## One of the Bruces and Drunken Bastard

Release 1

- Home page
- Beginning
- Previous
- Next

Part Five - "The Artist's Hut"

The Artist's Hut is a room. It is east of the Twisty Little Alley. The Twisty Little Alley is outside from the Artist's Hut. The description of the Artist's Hut is "This is a hovel of the sort classically frequented by artists. The exit is west. A sign on the wall reads: 'Portraits 1 aureus. Bring your own canvas.'"

The artist_other_thing is a thing that varies. The artist_other_thing is the aureus.

The artist_other_text is text that varies. The artist_other_text is "first".

Before asking the artist about "work/painting", instead say "The artist gestures with his goatee at the sign."

The artist is a man in the Hut. "An insufferable-looking artist sits behind an easel." The description is "The artist is a young man with a small goatee. If eyeglasses had been invented yet, he would have little rectangular ones with heavy black frames[4 as a footnote]." The indefinite article of the artist is "the". The default reply of the artist is "The artist is much too hip to talk to the likes of you." Instead of fucking the artist, try sucking the artist. Instead of blowing the artist, try sucking the artist. Instead of kissing the artist, try sucking the artist. Instead of eating the artist, try sucking the artist. Instead of sucking the artist, say "The artist haughtily points out that he's consecrated to his art. You take this to mean that he masturbates so much that he doesn't have anything left for you." Instead of rubbing or wanking off the artist, say "You're quite sure he gets enough of that already." After examining the artist: now the artist is handled. The artist is unspeakable. Understand "goatee", "young", "small", and "hipster" as the artist.

Instead of attacking the artist, say "Although violence is sometimes the answer, and although you really would like to punch the artist right in his goatee, nothing would be gained by this course of action."

The eyeglasses are scenery in the Hut. Understand "glasses", "eyeglasses", "little", "rectangular", "heavy", "black", "frame", and "frames" as the eyeglasses. Instead of doing anything with the eyeglasses, say "The hipster glasses are entirely notional."

Instead of giving the stiffycock to the artist, try fucking the artist.

Instead of giving something to the artist:

if the noun is the toga

begin;

say "The artist rolls his eyes. 'I don't do murals[7 as a footnote], dude.'";

stop the action;

end if;

if the noun is not the aureus and the noun is not the bag

begin;

say "The artist haughtily refuses [the noun].";

otherwise;

if the noun is the aureus

begin;

now the artist_other_thing is the bag;

now the artist_other_text is "second";

say "The artist bites down on the coin, then flinches. 'You coulda told me it was one of Big Julie's, eh? Dude, that's totally been in his butt. Nasty, man. Nasty.' [paragraph break]";

otherwise;

now the artist_other_thing is the aureus;

now the artist_other_text is "first";

end if;

if the artist_other_thing is not held by the Artist

begin;

say "The artist takes [the noun] from you and indicates the [artist_other_text] sentence of the sign with a small twitch of his goatee in its direction.";

move the noun to the Artist;

otherwise;

say "'Hmmm,' says the artist. 'A bag. Kinky.' He rolls his eyes. 'Guess you're wanting it to put over someone's head, to make him...her?...more alluring, huh? Yeah, I get a lot of these...So. Guy? Girl? Eh, it doesn't matter. I'll put one on each side. That way, if it's a girl, you can do her from the front and then flip her over and do her up the butt and it'll be like doing a guy. Only a guy with a broken neck. But some people like that, you know? [paragraph break]'Anyway, so, yeah. Interesting olive color, velvety texture. Reminds me of this totally hot MILF I knew named Syra. Wow. She was like riding one of the mares of Diomedes...Hey, there's a hole over here already for the mouth. Cool. Tell you what, I'll cut a matching slit on the other side for [italic type]that[roman type] picture too, so you can kiss him...or her, hey, whatever floats your boat, man...or, you know, receive oral.' [paragraph break]In a few minutes, he paints a portrait of an attractive, if not very young, woman on one side of the bag, and an attractive young man on the other. He hands you the bag and lapses again into sullen silence.[paragraph break]";

move mask to player;

move the noun to the Artist;

remove bag from play;

remove aureus from play;

really have the parser notice the mask;

end if;

end if;

The sign is scenery in the Artist's hut. The description is "'Portraits 1 aureus. Bring your own canvas.'"

The artist's easel is scenery in the Artist's hut. The description is "It's just an artist's easel."

The mask is a container. The description is "The velvet bag is painted with a portrait of Syra on one side, some hot young thing on the other." Instead of wearing the mask, say "But then you couldn't see!" Understand "velvet" and "bag" as the mask. Instead of fucking the mask, say "I think you have misunderstood the purpose of the mask." Instead of inserting something into the bag, say "The mouth holes in the mask make this unlikely to work very well for very long." Instead of touching or rubbing the bag, say "It's a lovely velvety texture." Instead of searching the bag, say "The interior of the mask is dark and velvety. There's nothing in it, because, you know, there are two big holes in it."

Test artist with "x artist/ Ask artist about easel/ Give aureus to artist/ Give bag to artist"