# Stiffy Makane: Apocolocyntosis — 156 of 235

## One of the Bruces and Drunken Bastard

Release 1

- Home page
- Beginning
- Previous
- Next

Part Three - "The Priestess"

The Druidic priestess is a woman in Druidic Grove. "A Druidic priestess [if the white robe is worn by the Druidic priestess]stands solemnly in the grove[otherwise]reclines naked on the altar[end if]." The description is "The Druidic priestess is a tall, thin woman with long, straight red hair, solemn green eyes, and high, pert breasts[if the white robe is worn by the Druidic Priestess] concealed under a simple white robe[otherwise]. The curtains match the carpet. She is reclining on the crumbling stone altar[end if]." Understand "woman", "redhead", "rosemary", and "ginger" as the Druidic Priestess.

The conversation of the Druidic Priestess is the Table of Druidic Priestess's Chatter. The default reply of the Druidic Priestess is "The Druidic priestess smiles enigmatically." The Druidic Priestess has a horniness. The Druidic Priestess is unaroused. Instead of smelling the Druidic Priestess, say "She smells like rosemary and ginger." Does the player mean doing something with the Druidic Priestess: it is likely.

Instead of fucking, sucking, blowing, wanking off, touching, rubbing, kissing, or eating the Druidic Priestess, consider the flirting-with-the Druidic Priestess rule. Instead of buggering the Druidic Priestess, try fucking the Druidic Priestess's anus.

Instead of inserting something into the Druidic Priestess:

if the simple white robe is worn by the Druidic Priestess, instead say "The priestess pushes [the noun] away without a word.";

instead try inserting the noun into the Druidic Priestess's pussy.

The simple white robe is a garment worn by the Druidic Priestess. The description is "This is a simple white robe of purest linen." Understand "pure", "purest", and "linen" as the simple white robe.

Some Druidic Priestess's breasts are part of the Druidic Priestess. They are ambiguously plural. The indefinite article is "the pair of". The description is "[if the simple white robe is worn by the Druidic Priestess]Her small, high, pert breasts push against the linen of her robe.[otherwise]They're not very big, but they sure are shapely[end if]." Understand "pair of", "chest", "magnificent", "high", "pert", "nipple", "nipples", "aureole", "aureoles", "aureola", "aureolae", "aureolas", "shapely", "small", "tits", "breast", "cleavage", "tit", "hooters", and "hooter" as the Druidic Priestess's breasts. Check taking the Druidic Priestess's breasts: instead try touching the Druidic Priestess's breasts. Instead of kissing the Druidic Priestess's breasts, try sucking the Druidic Priestess's breasts. Instead of smelling the Druidic Priestess's breasts, try smelling the Druidic Priestess. They are proper-named.

The Druidic Priestess's anus is an anus. The description is "[if the simple white robe is worn by the Druidic Priestess]It's gotta be under there somewhere[otherwise]It's underneath her, and not within easy reach[end if]." Instead of kissing, rubbing, sucking, tasting, or eating the Druidic Priestess's anus, try kissing the Druidic Priestess's pussy. Instead of smelling the Druidic Priestess's anus, say "You can't get to it, which, perhaps, is just as well." Instead of inserting the stiffycock into the Druidic Priestess's anus, try fucking the Druidic Priestess's anus. Instead of inserting something into the Druidic Priestess's anus, say "The Druidic priestess grabs your wrist. 'Thanks,' she says, 'but I'd rather you actually did [italic type]not[roman type] put [a noun] in my ass.'"

Instead of buggering the Druidic Priestess's anus, try fucking the Druidic Priestess's anus. Check taking the Druidic Priestess's anus: try fucking the Druidic Priestess's anus.

Instead of fucking the Druidic Priestess's anus:

say "The Druidic Priestess lowers her hips and presses her butt to the altar. 'That's exit only, I'm afraid,' she explains.";

stop the action.

The Druidic Priestess's pussy is a vagina. The description is "[if the gown is worn by the Druidic Priestess]It's gotta be under there somewhere[otherwise]Her pussy is concealed in a thick tangle of red pubic hair." Understand "musky", "intoxicating", "red", "pubic", "thatch", "tangle", "curly", "carpet", and "hair" as the Druidic Priestess's pussy. Instead of inserting the stiffycock into the Druidic Priestess's pussy, consider the flirting-with-the Druidic Priestess rule. Instead of fucking the Druidic Priestess's pussy, consider the flirting-with-the Druidic Priestess rule. Instead of smelling the Druidic Priestess's pussy, say "Musky and intoxicating." Check taking the Druidic Priestess's pussy: instead try fucking the Druidic Priestess. Instead of kissing, rubbing, sucking, tasting, or eating the Druidic Priestess's pussy:

if the Druidic Priestess is boinked, instead try fucking the Druidic Priestess;

say "The Druidic Priestess moans and writhes under your caresses. [run paragraph on]";

if the stiffycock is not visible, instead say "She gasps, 'Undress. I want you inside me.'";

say "She hisses, 'I want you inside me.'";

instead try fucking the Druidic Priestess.

Instead of inserting something into the Druidic Priestess's pussy:

if the Druidic priestess is boinked, instead try fucking the Druidic Priestess;

say "The Druidic Priestess stops you. 'I don't think [a noun] is what I want in there,' she says[if the stiffycock is visible], gazing at your [stiffycolor of the stiffycock]-glowing cock[end if]."

Instead of touching, rubbing, or squeezing the Druidic Priestess's breasts:

if the simple white robe is worn by the Druidic Priestess, instead say "The robe is in the way.";

consider the flirting-with-the Druidic Priestess rule.

Instead of kissing, sucking, or tasting the Druidic Priestess's breasts:

if the simple white robe is worn by the Druidic Priestess, instead try touching the Druidic Priestess's breasts;

consider the flirting-with-the Druidic Priestess rule.

Instead of fucking the Druidic Priestess's breasts:

if the gown is worn by the Druidic Priestess, instead try touching the Druidic Priestess's breasts;

if the stiffycock is not visible, instead say "You are not undressed for the occasion.";

say "Unfortunately, her breasts are too small to make this a viable course of action.";

stop the action.

This is the flirting-with-the Druidic Priestess rule:

if the Druidic Priestess is boinked

begin;

say "The Druidic priestess smiles, but says, 'I think we're done here. Go get ready for your fight.'";

stop the action;

end if;

if the stiffycolor of the stiffycock is not blue

begin;

say "The priestess points at your [stiffycolor of the stiffycock]-glowing penis. 'That color clashes unpleasantly with your woad, and it's a huge turn-off. Fix that, and I'll consider it.'";

stop the action;

end if;

if the Druidic Priestess is unaroused

begin;

say "The priestess smiles invitingly and the two of you make out for a while. Eventually she shrugs out of her robe, which falls to the forest floor, and lies back on the altar. 'Feel free.'";

really have the parser notice the Druidic Priestess;

now the Druidic Priestess is horny;

move the simple white robe to the Druidic Grove;

now the Druidic Priestess's pussy is part of the Druidic Priestess;

now the Druidic Priestess's anus is part of the Druidic Priestess;

otherwise;

say "The Druidic priestess kisses you passionately, and then helps you enter her slippery pussy. The sensations, augmented by your hallucinations, are bafflingly bizarre, but also intense and ecstatic. The act seems to take forever. She screams in orgasm time and time again, beating on your ribs with her fists and raking your back with her fingernails. When you finally ejaculate it as if you are a glowing bronze wire being drawn off a red-hot ingot.";

now the Druidic Priestess is boinked;

move ingot_trip to Druidic Grove;

record "the Druidic priestess" as achieved;

really have the parser notice the Druidic Priestess;

end if.

Ingot_trip is a grove_trip. The description of ingot_trip is "That was just a simile." Understand "draw", "drawn", "bronze", "wire", "glow", "glowing", "wound", "wind", "winding", "red", "hot", "ingot", and "red-hot" as the ingot_trip.

Instead of showing the stiffycock to the Druidic Priestess:

if the stiffycolor of the stiffycock is not blue

begin;

say "The Druidic priestess glares at you. 'Your woad is blue. Your cock is [stiffycolor of the stiffycock]. This is a major fashion [italic type]faux pas[roman type]. Please address this issue at your earliest convenience.";

otherwise;

say "The Druidic priestess smiles. 'Blue is much better. It looks very good on you.'";

end if;

The Druidic Priestess's green eyes are a part of the Druidic Priestess. Understand "limpid" as the Druidic Priestess's green eyes. They are ambiguously plural. The description is "Her eyes are green and limpid." They are proper-named.

The Druidic Priestess's pink lips are part of the Druidic Priestess. The description is "Her thin pink lips are delicately curved." Understand "delicately", "thin", "delicate", "mouth", and "curved" as the Druidic Priestess's pink lips.

The Druidic Priestess's red hair is part of the Druidic Priestess. The description is "Her straight red hair flows down her back." Understand "straight", "long", "back", "flows", "flow", and "flowing" as the Druidic Priestess's red hair. It is proper-named.

Instead of fucking the Druidic Priestess's lips:

if the stiffycolor of the stiffycock is not blue, instead try fucking the Druidic Priestess;

if the Druidic Priestess is boinked, instead try fucking the Druidic Priestess;

say "You clamber onto the altar and kneel over the priestess. She lifts her head and takes you into her mouth, dragging her lower teeth along the underside of your cock. When you're painfully hard, she disengages, and growls, 'I want you inside me.'[paragraph break]";

instead try fucking the Druidic Priestess.

Table of Druidic Priestess's Chatter

topic | reply | summary | turn stamp
"woman/herself/priestess/druidic/name" | "'I am a priestess of the Old Faith; you and your friends are going to liberate our Pictish tribe from the tyranny of the Gostaks.'" | "you and the vikings were going to free her people from their subjugation by the Gostaks" | a number
"Syra" | "'An eagle's beak; a goat's libido.'" | "Syra was a memorable encounter" | --
"me/myself/Mentula/Macanus/Stiffy/Macane/Lucius" or "Stiffy Makane" or "Mentula Macanus" or "Lucius Macanus Mentula" | "'I hear you're a lover, not a fighter.'" | "your reputation precedes you" | --
"Pict/Picts/Pictish/tribe" | "'Our people are brutally oppressed by the Gostaks. We hope you are able to overthrow the Gostak chief.'" | "she hopes you can defeat the Gostaks" | --
"Gostak/Gostakia/chief/chieftan/Baldanders/sorceror/wizard/Gostaks/castle" | "'The Gostaks are led by a terrifying sorcerous giant, who lives in yonder castle.'" | "the Gostak chief is both a sorceror and a giant" | --
"viking/vikings" | "'Overthrow the Gostak chief and keep whatever you can take. We just want him out, and are happy for you and your Viking friends to do the job.'" | "she expects you and the Vikings to overthrow the Gostak chief and pillage his castle" | --
"old/faith/druids/druid/druidism/altar/oak/oaks/tree/trees/forest/holly" | "She spreads her hands, encompassing, it seems, the whole forest. 'The Old Faith.'" | "Druidism calls itself the Old Faith" | --
"woad/hallucinogen/hallucination/tripping/balls/dye/paint" | "'Woad is somewhat hallucinogenic. It's probably kicking in by now.'" | "woad is a hallucinogen" | --
"lake/loch/ness/nessie/monster/tentacle/tentacular" | "'Oh, yes, the monster of the lake is real enough. I've seen her.'" | "she has seen a monster in the lake" | --