# Stiffy Makane: Apocolocyntosis — 115 of 235

## One of the Bruces and Drunken Bastard

Release 1

- Home page
- Beginning
- Previous
- Next

Section Two - "The Librarian"

The librarian is a woman in the Great Library. She is scenery. The description of the librarian is "The librarian is an older woman with thin, tightly-pursed lips and gray hair drawn back into a severe bun. Her right arm is slightly cocked, as if ready to leap into a full-blown 'shush' at any moment. She stands behind the marble counter with an air of ineffable command." The indefinite article of the librarian is "the". The default reply of the librarian is "The librarian shushes you with icy finality." The conversation of the librarian is the Table of Librarian's Chatter. Understand "Nancy", "Pearl", "reference", "old", "older", and "woman" as the librarian.

The librarian's hair is part of the librarian. The description is "Her hair is drawn back into a tight, steely gray bun." Understand "tight", "steely", "gray", "severe", and "bun" as the librarian's hair. Instead of touching, rubbing, or kissing the librarian's hair, try kissing the librarian.

The librarian's lips are part of the librarian. The description is "It looks as though her thin lips have not varied their position, save for slight upwards or downwards twitches of the corners, in decades." Understand "lip", "thin", "tightly", "pursed", "tightly-pursed", and "mouth" as the librarian's lips. Instead of touching, rubbing, sucking, fucking, or kissing the librarian's lips, try kissing the librarian.

The librarian's arm is part of the librarian. The description is "It twitches every so often, as if ready to shush of its own accord." Understand "twitch", "twitching", "twitichy", and "right" as the librarian's arm.

The librarian's garb is worn by the librarian. The description is "The traditional drab dark blue tunic. You can't see her shoes, as they are hidden by the counter, but you're sure they are eminently sensible." Understand "traditional", "drab", "dark", "blue", "dark-blue", "tunic", and "sensible" as the librarian's garb.

Instead of touching, rubbing, sucking, fucking, blowing, buggering, kissing, or wanking off the librarian, say "The librarian merely regards you with a bone-chilling, icy glare."

Instead of giving or showing the ragged papyrus to the librarian:

say "The librarian accepts the papyrus fragment from you. 'Very well,' she says. 'I'll leave it here at the reference desk for a while, in case you want to consult it again.'";

move the ragged papyrus to the marble counter.

Instead of giving or showing the jagged papyrus to the librarian:

if the ragged papyrus is off-stage

begin;

say "The librarian peers at the papyrus. 'I think,' she says, 'we may just have the other half of that.'";

consider the getting-papyrus rule;

otherwise;

if the ragged papyrus is held by the player

begin;

say "'Yes, it's the other half of the fragment I gave to you already.'";

otherwise;

remove the ragged papyrus from play;

remove the jagged papyrus from play;

now the stained piece of papyrus is held by the player;

really have the parser notice the stained piece of papyrus;

say "The librarian deftly fits the two halves of the papyrus together and looks very pleased with herself. She hands you the repaired sheet.";

end if;

end if.

Instead of giving or showing the stained piece of papyrus to the librarian:

say "The librarian says 'I shall have a copy made forthwith.' She beckons to a black-clad slave, and in just a few minutes, she presents you with a clean copy of the rejoined papyrus fragment.";

remove the stained piece of papyrus from play;

really have the parser notice the clean piece of papyrus;

move the clean piece of papyrus to the player.

Before asking the librarian about something:

if the topic understood matches "papyrus/scroll/book/volume/ragged/jagged/piece/paper", replace the topic understood with "#fake1";

if the topic understood matches "ragged papyrus", replace the topic understood with "#fake1";

if the topic understood matches "jagged papyrus", replace the topic understood with "#fake1";

if the topic understood matches "piece of paper", replace the topic understood with "#fake1";

if the topic understood matches "piece of papyrus", replace the topic understood with "#fake1";

if the topic understood matches "Jupiter/Virilis", replace the topic understood with "#fake2";

if the topic understood matches "Jupiter Virilis", replace the topic understood with "#fake2";

if the topic understood matches "#fake2" and the librarian is warned_about, replace the topic understood with "#fake3";

if the topic understood matches "golden banana", replace the topic understood with "#fake4";

if the topic understood matches "golden banana of discord", replace the topic understood with "#fake4";

if the topic understood matches "banana/golden/discord", replace the topic understood with "#fake4";

if the topic understood matches "#fake4"

begin;

if the ragged papyrus is off-stage

begin;

if the location of the stained piece of papyrus has been a room

begin;

if the location of the clean piece of papyrus has been a room

begin;

say "The librarian says 'I already made you a copy of the rejoined papyrus[if the clean piece of papyrus is not visible]. Not my fault that you lost it[end if].'";

otherwise;

say "The librarian says 'I believe the papyrus has been rejoined.'";

end if;

stop the action;

otherwise;

say "The librarian says, 'Yes, I believe we have a fragment relating to the Golden Banana.'";

consider the getting-papyrus rule;

stop the action;

end if;

end if;

end if.

Table of Librarian's Chatter

topic | reply | summary | turn stamp
"Syra" | "'One of the most well-travelled, as it were, women of her[emdash]or indeed any[emdash]age." | "Syra gets around" | a number
"librarian/herself/nancy/pearl/reference" or "nancy pearl" or "reference librarian" | "'I am the reference librarian currently on duty. It is my sacred trust to answer questions the library's patrons might have, and to keep the peace within its walls.'" | "she will answer questions from library patrons" | --
"#fake1" | "'We have,' she points out, 'quite a few volumes here. Could you perhaps suggest a topic?'" | "you need to be more specific when asking her about a scroll" | --
"Scotland/Gostakia/Gostak/Hibernia" | "'A cold, bare, and barren land of rain and snow.'" | "Scotland is cold and barren" | --
"Baldanders" | "'A great chief of the Gostak people.'" | "Baldanders is a Gostak chief" | --
"Rome" | "'The seat of temporal power. Caesar's home, and close to yours.'" | "Rome is the center of political power" | --
"Ostia" | "'Ostia is your family's hometown. It is the principal port of Rome.'" | "Ostia is your hometown and Rome's port" | --
"Julia" | "'She's a well-born child of a good Roman family.'" | "Julia is high-born" | --
"#fake2" | "'The god Jupiter, in his aspect as Inseminator and Progenitor.'" | "Jupiter Virilis is the Inseminator" | --
"Caesar/Julius/Gaius" or "Gaius Julius Caesar" or "Julius Caesar" | "'Probably the most powerful man in the word right now.'" | "Caesar is the most powerful man in the world" | --
"#fake4" | "NOTSAID" | "she gave you a papyrus fragment referring to the banana." | --
"Eris/Discordia" | "'Goddess of strife.'" | "Eris is the Goddess of strife" | --
"date" | "The librarian lets the corners of her mouth turn up the tiniest bit. 'Is your arm broken? Get it yourself[75 as a reference].'" | "she suggested you beat off rather than date her" | --
"copy" | "'If you provide us with a new document, we'll give you a copy of the original for no charge.'" | "if you give a document to the library, you get a copy." | --
"mweru bird" or "roc/mweru" | "'The Mweru bird and the roc are the same thing: a giant bird large enough to eat whales and elephants. Contrary to popular belief, it resembles a canary more than a vulture or an eagle'" | "the Mewru bird and the roc are identical, and enormous" | --
"oracle/prophet/sybil/cumae/cumaean" or "cumaean sybil" | "'The Cumaean Sybil is the best-known, best-respected, and most beloved of the oracles. It is said that she was granted everlasting life without accompanying youth, and now exists only as a withered thing in a bottle.'" | "the Cumaean Sybil is the best-respected of the prophets" | --
"#fake3" | "'Jupiter the Inseminator favors you.'" | "you are favored by Jupiter Virilis" | --
"Madame/Sosostris/fortuneteller/fortune-teller" or "Madame Sosostris" | "'Madame Sosostris is a famous clairvoyante who practices in Carthage; she's also said to be a raging alcoholic.'" | "Madame Sosostris is a fortune-teller in Carthage who drinks too much" | --
"me/myself/Mentula/Macanus/Stiffy/Macane/Lucius" or "Stiffy Makane" or "Mentula Macanus" or "Lucius Macanus Mentula" | "'As the Delphic Oracle might say, [italic type]know thyself[roman type],' she smiles." | "she either told you that you needed to discover your own nature, or she told you to go fuck yourself, and you don't know which" | --
"Cleopatra/queen/pharoah/Cleo" | "'Cleopatra has proven a wise and benevolent ruler, who has graciously funded the Great Museum.'" | "Cleopatra has funded the Museum well" | --
"Alexander/mummy" or "Alexander the Great" | "'Alexander is interred in the Soma Mausoleum in the palace. Her Majesty can grant you a viewing of his mummy, if approached with the proper deference.'" | "Alexander is buried in the palace; Cleopatra controls access to the tomb" | --
"tallis" | "'The tallis is the traditional prayer shawl of the Jews.'" | "a tallis is a prayer shawl" | --
"mezuzah" | "'A mezuzah is a case, traditionally affixed on door-posts, containing the [italic type]Shema Israel[roman type] prayer, and providing protection for the inhabitants.'" | "the mezuzah is affixed to entryways to protect the inhabitants" | --
"klaf" | "'The klaf is the parchment inside the mezuzah on which the prayer is written.'" | "a klaf is the parchment on which the prayer inside the mezuzah is written" | --
"Glub" | "'Ooh, that's a tricky one,' the librarian says, smiling broadly. 'Glub is a minor, possibly apocryphal, deity, said to live in the sewers of Ostia. His portfolio is, basically, sewage.'" | "Glub is known to her as a sewage god in Ostia" | --
"Serapis" | "'Serapis is one of the patron gods of Alexandria. He's often identified with Pluto, god of the underworld. There's a big temple to him in our Greek quarter. You should visit it if you have not already.'" | "Serapis is often identified with Pluto, and his temple in Alexandria is a major one" | --
"Lighthouse/Pharos" or "Great Lighthouse" or "Pharos Lighthouse" | "'The Pharos Lighthouse is one of the wonders of the world. The view from the top is spectacular.'" | "the lighthouse is worth a visit" | --
"Jorge/Luis/Borges" or "Jorge Luis Borges" | "'I think he's one of the librarians in Babel. He doesn't work here.'" | "Borges works for the Library of Babel" | --
"Babel" | "'Babel? I don't know anything about Babel,' the librarian claims, looking shifty. 'Maybe you mean Babylon.'" | "she doesn't want to talk about Babel" | --
"Babylon" | "'Babylon's a long way to the east. Not much happening there this century.'" | "nothing much is happening in Babylon this century" | --
"Nineveh" | "'Nineveh was destroyed centuries ago.'" | "Nineveh has been ruins for centuries" | --
"Tarshish" | "'No one knows where Tarshish is or was.'" | "Tarshish's location is unknown" | --
"Jonah" | "'One of the Jews' holy writings is about a man called Jonah. Their god[emdash]Yahweh[emdash]told him to go to Nineveh and preach its destruction, Jonah attempts to flee instead, Yahweh calls up a storm, the crew tosses him overboard, he's swallowed by a whale. He repents for his disobedience, the whale vomits him up onto dry land, and he goes and preaches as he was supposed to.'" | "Jonah and attempted disobedience to Yahweh and was eaten by a whale" | --
"whale/leviathan/whales/leviathans" | "'Whales are said to be among the favored foods of the Mweru Bird, along with hippos. Also, Yahweh had Jonah swallowed by one.'" | "the Mweru Bird eats whales; Yahweh caused Jonah to be swallowed by a whale" | --
"hippo/hippopotamus/hippopotami" | "'The Mweru Bird is said to enjoy eating hippopotami nearly as much as it likes eating whales.'" | "the Mweru Bird eats hippopotami" | --
"Archimedes" | "'Archimedes was one of the greatest engineers of the Hellenistic world; he was a great geometer and a prolific inventor. Unfortunately, one of your soldiers struck him down more than a century and a half ago.'" | "Archimedes was a great engineer, killed by the Romans" | --
"pirate/pirates/piracy" | "The Mediterranean, alas, is infested with pirates, who make travel hazardous." | "the Mediterranean is full of pirates" | --
"Mediterranean" or "Mediterranean Sea" or "Mare Nostrum" | "The Mediterranean is the glue that binds the Roman world." | "the Roman world is held together by the Mediterranean" | --
"Vergil/Virgil/Publius/Vergilius/Maro" or "Publius Vergilius Maro" | "She smiles slightly. 'A minor poet, of very little repute, living near Mantua.'" | "Vergil is a minor Mantuan poet" | --
"Eugenides" or "Mr Eugenides" or "smyrna merchant" or "Mister Eugenides" | "The librarian looks disapproving. 'Eugenides is a lecherous merchant from Smyrna; he deals largely in dried fruit.'" | "Eugenides is a fruit-trader from Smyrna" | --
"hotel/Metropole" or "Hotel Metropole" | "'The Metropole pretends to be a grand resort, but it is a fleabag.'" | "the Metropole is a very shabby hotel" | --
"Library/Museum/Great/Alexandria/Egypt" or "Great Library" or "Great Museum" | "'Although the city may have declined in recent centuries, it is still,' she preens, 'home to the greatest collection of knowledge assembled in the world.'" | "Alexandria is not what it once was, but still boasts the Great Library" | --
"Thessalonica" | "'Ugh. Provincial town full of rustics and yokels.'" | "she bears no love for Thessalonica" | --
"Olympus" or "Mount Olympus" or "Mt Olympus" | "'The gods live atop Olympus; the ascent is steep and frigid. Not recommended for the non-suicidal.'" | "the ascent of Olympus is hard and cold" | --
"Litochoro" | "'Litochoro is a tiny town at the foot of Olympus.'" | "Litochoro is a hamlet at the base of Mt. Olympus" | --
"Cerberus" | "'The three-headed dog that guards the underworld, about the size of an elephant.'" | "Cerberus guards the underworld and is the size of an elephant" | --
"Carthage" | "'Carthage has not recovered from the Punic Wars. Sad, really.'" | "Carthage has never recovered from its crushing defeat" | --

This is the getting-papyrus rule:

if the ragged papyrus is not off-stage, stop the action;

choose row with reply of "NOTSAID" in the Table of Librarian's Chatter;

if there is no turn stamp entry, now turn stamp entry is the turn count;

say "She turns to a black-clad slave, says something, and the man scurries up a ladder, nimble as a monkey, returning with a scrap of paper. She glances at it, smiles, and hands it to you.";

move the ragged papyrus to the player.